ExcelVBAゲームプログラミング？

初心者でもきっとできる！
Ｅｘｃｅｌさえ持っていれば特別なソフトは不要！
すぐにでも始められる簡単ゲームプログラミング！
今すぐ始めよう！

サンプルやゲームのダウンロードができる別館も好評運営中です。
ご意見やご質問、ゲームの感想等は掲示板までお気軽に。是非、皆さんの声を聞かせてください。運営、開発の励みになります。


各種ダウンロードはコチラ ↓ 意見・感想・質問はコチラ ↓
影倉庫 Shadow warehouse サポート掲示板
ブログの全体像はコチラ ↓ リンクのページはコチラ ↓
サイトマップ 自分本位なリンク


Ｃｈａｐｔｅｒ.６０ [ シューティングゲーム２０：いよいよ完成STG ]

■ショット関連の処理

さぁ、いよいよ今回の講座で、長かったシューティングゲームの講座も最後です。気合を入れて頑張りましょう。

それでは、前回宣言したとおり、今回はショット関連の処理を一気にやってしまいます。まずはプレイヤーキャラクターが放ったショットの処理から見ていきましょう。

Sub P_Shot_Action()

    Dim L As Long
    Dim LL As Long

    For L = 0 To 4
        With P_Shot_Data(L)
            If .Vis Then
                .Y = .Y - 6
                If .Y < -5 Then .Vis = False
                For LL = 0 To 9
                    If Enemy_Data(LL).Lif > 0 Then
                        If .X - 2 < Enemy_Data(LL).X + Enemy_Data(LL).W Then
                            If .X + 2 > Enemy_Data(LL).X - Enemy_Data(LL).W Then
                                If .Y - 2 < Enemy_Data(LL).Y + Enemy_Data(LL).H Then
                                    If .Y + 2 > Enemy_Data(LL).Y - Enemy_Data(LL).H Then
                                        .Vis = False
                                        With Enemy_Data(LL)
                                            Call Burst_Begin(.X, .Y)
                                            .Lif = 0
                                        End With
                                        Score = Score + 100
                                        Exit For
                                    End If
                                End If
                            End If
                        End If
                    End If
                Next
                If Boss_Data.Lif > 0 Then
                    If .X - 2 < Boss_Data.X + Boss_Data.W Then
                        If .X + 2 > Boss_Data.X - Boss_Data.W Then
                            If .Y - 2 < Boss_Data.Y + Boss_Data.H Then
                                If .Y + 2 > Boss_Data.Y - Boss_Data.H Then
                                    .Vis = False
                                    With Boss_Data
                                        Call Burst_Begin(.X, .Y)
                                        .Lif = .Lif - 1
                                    End With
                                    Score = Score + 50
                                End If
                            End If
                        End If
                    End If
                End If
                With UserForm1.Controls("P_Shot" & L + 1)
                    If P_Shot_Data(L).Vis Then
                        .Left = P_Shot_Data(L).X - Shot_Size
                        .Top = P_Shot_Data(L).Y - Shot_Size
                    Else
                        .Visible = False
                    End If
                End With
            End If
        End With
    Next

End Sub

ボスキャラクターは、通常のザコ敵キャラクターとは違う構造体変数を使っています。ですから、ショットとの衝突判定も独自に実装する必要があります。追加されているのは緑色で表示されている部分だけです。

実際にやっていることは、通常の衝突判定と全く同じことをしているだけです。ボスキャラクターの位置と大きさ、これを元に衝突しているかどうか計算しているのですね。

ポイントは、緑色の文字の一番最初の行の部分。ここで、ボスキャラクターが存在しているかどうか調べています。存在していないときに衝突判定を行う必要は無いので、ここでそれを判断してから衝突判定の処理に移っているわけです。


■敵キャラクターのショット

さて、次に敵キャラクターのショットまわりを修正しましょう。
前回の講座で載せたコードの中に、ボスキャラクターが放つショットの処理がありました。そこでは、ボスキャラクターが５種類のショットを撃ってくるように設計されていましたが、今現在は３種類のショットしか定義されていません。

ここでは、ショットの種類に応じて処理が分かれるように、適宜、コードの修正及び追加を行いましょう。
まずは、ショットを生成するプロシージャの修正からです。

ショットの生成段階で、ショットの種類に応じて、画像が変化するようにしてみます。

Sub E_Shot_Begin(X As Single, Y As Single, Typ As Long)
    
    Dim L As Long
    
    For L = 0 To 9
        With E_Shot_Data(L)
            If Not .Vis Then
                .X = X
                .Y = Y
                .Typ = Typ
                .Vis = True
                With UserForm1.Controls("E_Shot" & L + 1)
                    .Visible = True
                    Select Case Typ
                        Case 1, 2, 3
                            .Picture = UserForm1.E_Shot_s1.Picture
                        Case Else
                            .Picture = UserForm1.E_Shot_s2.Picture
                    End Select
                End With
                Exit For
            End If
        End With
    Next
    
End Sub

さて、緑色になっている部分が今回追加された部分ですが、何をしようとしているか、なんとなくわかりますか？

ここでは、ショットのタイプによって、画像が切り替わるように処理しています。
前々回の講座で、ユーザーフォーム上にショット用の原画となるイメージコントロールを配置しました。『E_Shot_s1・E_Shot_s2』がこれにあたります。

ショットのタイプが、１か２か３の場合には、青いショットのほうを使います。青いショットの画像はE_Shot_s1の画像を使います。
そして、それ以外の場合にはE_Shot_s2の画像を使います。今回は４番目と５番目のショットを追加しますので、そのふたつのショットはE_Shot_s2を原画として使用して表示するようになります。

このプロシージャで修正しているのはここだけです。簡単ですね。

さて問題は次です。
ショットの４番目と５番目、これがどのような動きをするのかを定義しておかなくてはいけません。それが次のコードになります。ちょっと長いですが、色つきの部分に絞って考えれば大丈夫だと思います。

Sub E_Shot_Action()

    Dim L As Long
    Dim LL As Long
    
    For L = 0 To 9
        With E_Shot_Data(L)
            If .Vis Then
                Select Case .Typ
                    Case 1
                        .Y = .Y + 4.5
                    Case 2
                        .X = .X + 0.5
                        .Y = .Y + 3.5
                    Case 3
                        .X = .X - 0.5
                        .Y = .Y + 3.5
                    Case 4
                        If .X < Player_Data.X Then
                            .X = .X + 1.5
                        Else
                            .X = .X - 1.5
                        End If
                        .Y = .Y + 2
                    Case 5
                        .Y = .Y + 6
                End Select
                If .X > 205 Then .Vis = 0
                If .Y > 205 Then .Vis = 0
                If .X < -5 Then .Vis = 0
                If .Y < -5 Then .Vis = 0
                If .X - 2 < Player_Data.X + Player_Data.W Then
                    If .X + 2 > Player_Data.X - Player_Data.W Then
                        If .Y - 2 < Player_Data.Y + Player_Data.H Then
                            If .Y + 2 > Player_Data.Y - Player_Data.H Then
                                .Vis = False
                                With Player_Data
                                    Call Burst_Begin(.X, .Y)
                                    .Lif = 0
                                End With
                            End If
                        End If
                    End If
                End If
                With UserForm1.Controls("E_Shot" & L + 1)
                    If E_Shot_Data(L).Vis Then
                        .Left = E_Shot_Data(L).X - Shot_Size
                        .Top = E_Shot_Data(L).Y - Shot_Size
                    Else
                        .Visible = False
                    End If
                End With
            End If
        End With
    Next
                
End Sub

ショットの４番目は、簡易的な追尾弾です。
プレイヤーキャラクターの現在の横位置を調べて、その方向へ移動していくようになっています。ショットの位置よりプレイヤーが左にいれば、ショットも左へ向かうという具合ですね。
追尾弾というのは、本物をやろうとすると結構大変なので、今回は簡易的な実装に留めています。横位置を調べてその方角へ移動させるだけなら、結構簡単ですからね。

５番目のショットは、単に下方向へまっすぐ進むだけです。ただし、１回のループで移動する距離が少々大きめに設定されています。これはつまり高速移動するショットということになります。

このプロシージャに追加するのはこれだけでOKです。
そして、これで修正のほぼ全てが完了したことになります。


■まとめ

いやぁ、長かった。本当に長かった。
ひとつの作品を作り上げるということは、本当に大変な労力を使います。手間も、根気も、並大抵ではありません。それだけに、大抵のプログラムというのは、途中で開発が止まってしまい、未完成に終わることが多いのです。

しかし、以前にも言いましたが、ゲームを作成する上でとても大切なことのひとつが、とりあえず完成させるということなのです。
御託をいくら並べても、ひとつの作品が出来上がらなかったら意味がありません。えらそうなことを言って、知識ばっかりたくさん持っていても、作品を仕上げられないうちは一人前とは言えません。

多少簡素なものであっても、それが完成品であるならば、それはあなたにとってとても意味のあるもののはずです。簡単なコードしか書けなくても、難しいことはわからなくても、努力の末に作品を仕上げたときには、あなたは立派なプログラマーです。
私が全てのコードを公開しているという都合上、コピーするだけでも動くゲームは出来上がります。でも、ここにどのようなエッセンスを加えていくかはあなた次第。どのように応用して生かしていくのかもあなた次第です。

何度も言いますが、私ができるのは、皆さんのお手伝い、道案内だけです。
この講座を通して得た知識で、皆さんが独自の世界を表現していくことを切に願います。

とにかく、ここまで根気強く進めてきてくださった皆さん。本当にお疲れ様でした。


最後にコードを全て掲載しておきます。講座の最後には、サンプルのページへのリンクも貼っておきます。これらを参考に、頑張ってみてください。


シューティングゲーム講座　全コード掲載
'標準モジュール先頭部分

'◆API　宣言
Declare Function GetTickCount Lib "kernel32" () As Long
Declare Function GetAsyncKeyState Lib "user32" (ByVal vKey As Long) As Integer
Declare Sub Sleep Lib "kernel32.dll" (ByVal dwMillsecounds As Long)

'■キャラクター　構造体宣言
Type Chara
    X As Single
    Y As Single
    W As Single
    H As Single
    Lif As Long
    Typ As Long
    Par As Long
End Type

'■ショット　構造体宣言
Type Shot
    X As Single
    Y As Single
    Vis As Boolean
    Typ As Long
End Type

'■汎用オブジェクト　構造体宣言
Type Obj
    X As Single
    Y As Single
    W As Single
    H As Single
    Par As Long
End Type

'●キャラクター　変数宣言
Public Player_Data As Chara
Public Enemy_Data(9) As Chara
Public Boss_Data As Chara

'●ショット　変数宣言
Public P_Shot_Data(4) As Shot
Public E_Shot_Data(9) As Shot

'●汎用オブジェクト　変数宣言
Public Burst_Data(2) As Obj

'◎その他　変数宣言
Public Shot_Interval As Long
Public Total_Count As Long 'ゲーム中のカウンタ
Public Player_Stock As Long 'プレイヤーの残機数
Public Score As Long 'ゲームのスコア
Public Boss_Begin As Boolean 'ボスが出現しているかどうか
Public Game_Mode As Long '現在のゲームモード
'０＝タイトル
'１＝ゲーム中
'２＝ゲームオーバー
'３＝ゲームクリア

'▲定数宣言
Public Const Left_Key As Long = 37 'カーソル左
Public Const Up_Key As Long = 38 'カーソル上
Public Const Right_Key As Long = 39 'カーソル右
Public Const Down_Key As Long = 40 'カーソル下
Public Const Esc_Key As Long = 27 'Ｅｓｃキー
Public Const Shot_Key As Long = 90 'Ｚキー
Public Const Player_Size As Single = 9
'プレイヤーキャラクターの実際の大きさ
Public Const Shot_Size As Single = 3
'弾各種の実際の大きさ
Public Const Enemy_Size As Single = 9
'敵キャラクターの実際の大きさ
Public Const Burst_Size As Single = 15
'爆発エフェクトの実際の大きさ
Public Const Boss_size As Single = 15
'ボスの実際の大きさ


'初期化を担当するプロシージャ

Sub Init()
    With Player_Data
        .X = 100
        .Y = 210
        .W = 3
        .H = 3
        .Lif = 1
        .Typ = 0
        .Par = 1
    End With
    With Boss_Data
        .X = 0
        .Y = 0
        .W = 0
        .H = 0
        .Lif = 0
        .Typ = 0
        .Par = 0
    End With
    Erase P_Shot_Data
    Erase E_Shot_Data
    Erase Enemy_Data
    Erase Burst_Data
    Shot_Interval = 0
    Total_Count = 0
    Player_Stock = 2
    Score = 0
    Game_Mode = 0
    Boss_Begin = False
    With UserForm1.Player
        .Visible = True
        .Top = 200
    End With
    UserForm1.Lab_Score.Caption = "00000000"
End Sub


'メインプロセスを担当するプロシージャ

Sub Main()

    Dim Flg As Boolean
    Dim Stm As Long
    
    Init
    
    Flg = False
    
    Do Until Flg
        Stm = GetTickCount
        Total_Count = Total_Count + 1
        Select Case Game_Mode
            Case 0
                Call Tytle_Action
            Case 1
                Call Stage_Count
                Call Player_Action
                Call Enemy_Action
                Call P_Shot_Action
                Call E_Shot_Action
                Call Burst_Action
                If Boss_Begin Then Boss_Action
                UserForm1.Lab_Score.Caption = Format(Score, "00000000")
            Case 2
                MsgBox "Game Over!!"
                Flg = True
            Case 3
                MsgBox "Clear!!"
                Flg = True
        End Select
        DoEvents
        Do
            Call Sleep(1)
        Loop Until GetTickCount - Stm > 30
        If GetAsyncKeyState(27) < 0 Then Flg = True
    Loop

End Sub


'タイトルのアクションを管理するプロシージャ

Sub Tytle_Action()

    With UserForm1
        .Lab_Cap1.Left = .Lab_Cap1.Left + 3
        .Lab_Cap2.Left = .Lab_Cap2.Left - 3
        If .Lab_Cap1.Left > 200 Then
            .Lab_Cap1.Visible = False
            .Lab_Cap2.Visible = False
            Game_Mode = 1
        End If
    End With
    
End Sub


'敵キャラクターの出現管理プロシージャ

Sub Stage_Count()

    Dim TCMOD As Long
    
    Randomize
    
    TCMOD = Total_Count Mod 1000
    
    If Total_Count < 2000 Then
        Select Case TCMOD
            Case 100, 150, 600, 650, 700, 750
                Call Enemy_Begin(Int(Rnd * 120) + 40, -10, 1)
            Case 200, 350, 450, 500, 800, 950
                Call Enemy_Begin(Int(Rnd * 120) + 40, -10, 2)
            Case 250, 300, 400, 550, 850, 900
                Call Enemy_Begin(Int(Rnd * 120) + 40, -10, 3)
        End Select
    Else
        If Total_Count = 2000 Then
            With Boss_Data
                .X = 100
                .Y = -20
                .W = 8
                .H = 8
                .Lif = 50
                .Par = 0
                .Typ = 0
            End With
            Boss_Begin = True
            UserForm1.Boss.Visible = True
        End If
    End If
    
End Sub


'プレイヤーキャラクターを担当するプロシージャ

Sub Player_Action()

    Dim S As Single
    Dim SS As Single
    
    Randomize
    
    With Player_Data
        If .Lif > 0 Then
            If .Par > 0 Then
                If .Y > 180 Then
                    .Y = .Y - 1
                Else
                    .Par = 0
                End If
            Else
                If GetAsyncKeyState(Left_Key) < 0 Then .X = .X - 3
                If GetAsyncKeyState(Up_Key) < 0 Then .Y = .Y - 3
                If GetAsyncKeyState(Right_Key) < 0 Then .X = .X + 3
                If GetAsyncKeyState(Down_Key) < 0 Then .Y = .Y + 3

                If .X - Player_Size < 0 Then .X = Player_Size
                If .X + Player_Size > 200 Then .X = 200 - Player_Size
                If .Y - Player_Size < 0 Then .Y = Player_Size
                If .Y + Player_Size > 200 Then .Y = 200 - Player_Size

                If Shot_Interval = 0 Then
                    If GetAsyncKeyState(Shot_Key) < 0 Then
                        Call P_Shot_Begin(.X, .Y, 1)
                        Shot_Interval = 1
                    End If
                Else
                    Shot_Interval = Shot_Interval + 1
                    If Shot_Interval > 7 Then Shot_Interval = 0
                End If
            End If
        Else
            .Par = .Par + 1
            If .Par > 50 Then
                .X = 100
                .Y = 210
                .Lif = 1
                .Par = 1
                Player_Stock = Player_Stock - 1
                Select Case Player_Stock
                    Case Is < 0
                        Game_Mode = 2
                    Case 0
                        UserForm1.Stock1.Visible = False
                    Case 1
                        UserForm1.Stock2.Visible = False
                End Select
            Else
                If .Par Mod 9 = 1 Then
                    S = Int(Rnd * 20) - 9
                    SS = Int(Rnd * 20) - 9
                    Call Burst_Begin(.X + S, .Y + SS)
                End If
            End If
        End If
        With UserForm1.Player
            .Left = Player_Data.X - Player_Size
            .Top = Player_Data.Y - Player_Size
        End With
    End With
    
End Sub


'ショット生成プロシージャ

Sub P_Shot_Begin(X As Single, Y As Single, Typ As Long)

    Dim L As Long

    For L = 0 To 4
        With P_Shot_Data(L)
            If Not .Vis Then
                .X = X
                .Y = Y
                .Typ = Typ
                .Vis = True
                UserForm1.Controls("P_Shot" & L + 1).Visible = True
                Exit For
            End If
        End With
    Next

End Sub


'ショット移動管理プロシージャ

Sub P_Shot_Action()

    Dim L As Long
    Dim LL As Long

    For L = 0 To 4
        With P_Shot_Data(L)
            If .Vis Then
                .Y = .Y - 6
                If .Y < -5 Then .Vis = False
                For LL = 0 To 9
                    If Enemy_Data(LL).Lif > 0 Then
                        If .X - 2 < Enemy_Data(LL).X + Enemy_Data(LL).W Then
                            If .X + 2 > Enemy_Data(LL).X - Enemy_Data(LL).W Then
                                If .Y - 2 < Enemy_Data(LL).Y + Enemy_Data(LL).H Then
                                    If .Y + 2 > Enemy_Data(LL).Y - Enemy_Data(LL).H Then
                                        .Vis = False
                                        With Enemy_Data(LL)
                                            Call Burst_Begin(.X, .Y)
                                            .Lif = 0
                                        End With
                                        Score = Score + 100
                                        Exit For
                                    End If
                                End If
                            End If
                        End If
                    End If
                Next
                If Boss_Data.Lif > 0 Then
                    If .X - 2 < Boss_Data.X + Boss_Data.W Then
                        If .X + 2 > Boss_Data.X - Boss_Data.W Then
                            If .Y - 2 < Boss_Data.Y + Boss_Data.H Then
                                If .Y + 2 > Boss_Data.Y - Boss_Data.H Then
                                    .Vis = False
                                    With Boss_Data
                                        Call Burst_Begin(.X, .Y)
                                        .Lif = .Lif - 1
                                    End With
                                    Score = Score + 50
                                End If
                            End If
                        End If
                    End If
                End If
                With UserForm1.Controls("P_Shot" & L + 1)
                    If P_Shot_Data(L).Vis Then
                        .Left = P_Shot_Data(L).X - Shot_Size
                        .Top = P_Shot_Data(L).Y - Shot_Size
                    Else
                        .Visible = False
                    End If
                End With
            End If
        End With
    Next

End Sub


'敵キャラクター生成プロシージャ

Sub Enemy_Begin(X As Single, Y As Single, Typ As Long)

    Dim L As Long
    
    For L = 0 To 9
        With Enemy_Data(L)
            If .Lif = 0 Then
                .X = X
                .Y = Y
                .W = 5
                .H = 5
                .Typ = Typ
                .Lif = 1
                .Par = 0
                With UserForm1.Controls("Enemy" & L + 1)
                    .Visible = True
                    Select Case Typ
                        Case 1
                            .Picture = UserForm1.Enemy_s1.Picture
                        Case 2, 3
                            .Picture = UserForm1.Enemy_s2.Picture
                    End Select
                End With
                Exit For
            End If
        End With
    Next
    
End Sub


'敵キャラクターを担当するプロシージャ

Sub Enemy_Action()

    Dim L As Long
    Dim TCMOD
    
    TCMOD = Total_Count Mod 30
    
    For L = 0 To 9
        With Enemy_Data(L)
            If .Lif > 0 Then
                Select Case .Typ
                    Case 1
                        .Y = .Y + 1.5
                    Case 2
                        .X = .X + 0.5
                        .Y = .Y + 1
                    Case 3
                        .X = .X - 0.5
                        .Y = .Y + 1
                End Select
                If .X > 220 Then .Lif = 0
                If .Y > 220 Then .Lif = 0
                If .X < -20 Then .Lif = 0
                If .Y < -20 Then .Lif = 0
                If TCMOD = 0 Then
                    Select Case .Typ
                        Case 2
                            .Typ = 3
                        Case 3
                            .Typ = 2
                    End Select
                    Call E_Shot_Begin(.X, .Y + 2, .Typ)
                End If
            End If
        End With
        With UserForm1.Controls("Enemy" & L + 1)
            If Enemy_Data(L).Lif > 0 Then
                .Left = Enemy_Data(L).X - Enemy_Size
                .Top = Enemy_Data(L).Y - Enemy_Size
            Else
                .Visible = False
            End If
        End With
    Next
    
End Sub


'敵キャラクターショット生成プロシージャ

Sub E_Shot_Begin(X As Single, Y As Single, Typ As Long)
    
    Dim L As Long
    
    For L = 0 To 9
        With E_Shot_Data(L)
            If Not .Vis Then
                .X = X
                .Y = Y
                .Typ = Typ
                .Vis = True
                With UserForm1.Controls("E_Shot" & L + 1)
                    .Visible = True
                    Select Case Typ
                        Case 1, 2, 3
                            .Picture = UserForm1.E_Shot_s1.Picture
                        Case Else
                            .Picture = UserForm1.E_Shot_s2.Picture
                    End Select
                End With
                Exit For
            End If
        End With
    Next
    
End Sub


'敵キャラクターショット移動管理プロシージャ

Sub E_Shot_Action()

    Dim L As Long
    Dim LL As Long
    
    For L = 0 To 9
        With E_Shot_Data(L)
            If .Vis Then
                Select Case .Typ
                    Case 1
                        .Y = .Y + 4.5
                    Case 2
                        .X = .X + 0.5
                        .Y = .Y + 3.5
                    Case 3
                        .X = .X - 0.5
                        .Y = .Y + 3.5
                    Case 4
                        If .X < Player_Data.X Then
                            .X = .X + 1.5
                        Else
                            .X = .X - 1.5
                        End If
                        .Y = .Y + 2
                    Case 5
                        .Y = .Y + 6
                End Select
                If .X > 205 Then .Vis = 0
                If .Y > 205 Then .Vis = 0
                If .X < -5 Then .Vis = 0
                If .Y < -5 Then .Vis = 0
                If .X - 2 < Player_Data.X + Player_Data.W Then
                    If .X + 2 > Player_Data.X - Player_Data.W Then
                        If .Y - 2 < Player_Data.Y + Player_Data.H Then
                            If .Y + 2 > Player_Data.Y - Player_Data.H Then
                                .Vis = False
                                With Player_Data
                                    Call Burst_Begin(.X, .Y)
                                    .Lif = 0
                                End With
                            End If
                        End If
                    End If
                End If
                With UserForm1.Controls("E_Shot" & L + 1)
                    If E_Shot_Data(L).Vis Then
                        .Left = E_Shot_Data(L).X - Shot_Size
                        .Top = E_Shot_Data(L).Y - Shot_Size
                    Else
                        .Visible = False
                    End If
                End With
            End If
        End With
    Next
                
End Sub


'ボスキャラクターの移動管理プロシージャ

Sub Boss_Action()

    Dim S As Single
    Dim SS As Single
    
    Dim TCMOD
    
    Randomize
    
    TCMOD = Total_Count Mod 500
    
    With Boss_Data
        If .Lif > 0 Then
            If .Y < 30 Then
                .Y = .Y + 1
            Else
                If .Par > 0 Then
                    .X = .X + 2
                    If .X > 160 Then
                        .X = 160
                        .Par = 0
                    End If
                Else
                    .X = .X - 2
                    If .X < 40 Then
                        .X = 40
                        .Par = 1
                    End If
                End If
            End If
            Select Case TCMOD
                Case 50, 70, 90, 110, 130, 150
                    .Typ = 1
                Case 60, 80, 100, 140
                    .Typ = 2
                Case 80, 120, 160
                    .Typ = 3
                Case 200, 230, 260, 290, 320
                    .Typ = 4
                Case 350, 360, 370, 380, 390, 400, 410, 420, 430, 440, 450
                    .Typ = 5
                Case Else
                    .Typ = 0
            End Select
            If .Typ <> 0 Then Call E_Shot_Begin(.X, .Y + 5, .Typ)
        Else
            .Par = .Par + 1
            If .Par < 100 Then
                If .Par Mod 10 = 0 Then
                    S = Int(Rnd * 25) - 13
                    SS = Int(Rnd * 25) - 13
                    Call Burst_Begin(.X + S, .Y + SS)
                End If
            Else
                Game_Mode = 3
                Boss_Begin = False
            End If
        End If
    End With
    With UserForm1.Boss
        If Boss_Begin Then
            .Left = Boss_Data.X - Boss_size
            .Top = Boss_Data.Y - Boss_size
        Else
            .Visible = False
        End If
    End With

End Sub


'爆発エフェクト生成プロシージャ

Sub Burst_Begin(X As Single, Y As Single)

    Dim L As Long
    
    For L = 0 To 2
        With Burst_Data(L)
            If .Par = 0 Then
                .X = X
                .Y = Y
                .W = Burst_Size
                .H = Burst_Size
                .Par = 1
                UserForm1.Controls("Burst" & L + 1).Visible = True
                Exit For
            End If
        End With
    Next
    
End Sub


'爆発エフェクト管理プロシージャ

Sub Burst_Action()

    Dim L As Long
    Dim Pict As Long
    
    For L = 0 To 2
        With Burst_Data(L)
            If .Par > 0 Then
                Select Case .Par
                    Case 1
                        Pict = 1
                    Case 2, 3
                        Pict = 2
                    Case 4, 5
                        Pict = 3
                    Case 6, 7
                        Pict = 4
                    Case 8
                        Pict = 5
                    Case 9
                        .Par = -1
                End Select
                .Par = .Par + 1
                With UserForm1.Controls("Burst" & L + 1)
                    If Burst_Data(L).Par > 0 Then
                        .Left = Burst_Data(L).X - Burst_Size
                        .Top = Burst_Data(L).Y - Burst_Size
                        .Picture = UserForm1.Controls("Burst_s" & Pict).Picture
                    Else
                        .Visible = False
                    End If
                End With
            End If
        End With
    Next
                
End Sub


'標準モジュールはここまで
'ここから下はフォームモジュールに記述


'コマンドボタンのクリックイベント

Private Sub Com_Start_Click()
    Com_Start.Enabled = False
    Call Main
    Unload UserForm1
End Sub


'ユーザーフォームのクエリクロースイベント

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    End
End Sub


'ユーザーフォームのイニシャライズイベント
Private Sub UserForm_Initialize()
    UserForm1.Width = 220
End Sub


サンプルダウンロード　⇒　コチラよりダウンロードできます。（別館）


■格言

まずは完成させることが大切
あとは努力と工夫次第

ボスキャラクターの動きなど、サンプルと併用してみるとわかりやすいと思います。

FC2ブックマークに追加





Comment

Name
E-mail
URL
Comment
Pass  *
Secret？ （管理者にだけ表示）
このコメントは管理人のみ閲覧できます
  • #
  • 2008.03.25(Tue)
  • Edit

プログラミング関連検索



プログラミングや ExcelVBA に関連した検索にはこちらをどうぞ。

メールフォーム

影斬に物申すという方はこちら

名前　:
メール:
件名　:
本文　:

可能な限り要望には応えますが、必ず返信や回答ができることを、保障するものではありません。
ご了承ください。

Ｃｈａｐｔｅｒｓ

コンテンツ一覧


■Chapter 一覧■
    全てのChapterの一覧です。
    直接アクセスしたい方はこちらをご利用下さい。

    Ｃｈａｐｔｅｒ.１ [ 知っておくべき心得 ]
    Ｃｈａｐｔｅｒ.２ [ Ｅｘｃｅｌってなんだろう ]
    Ｃｈａｐｔｅｒ.３ [ Ｅｘｃｅｌの基本画面 ]
    Ｃｈａｐｔｅｒ.４ [ ＶＢＡとは？ ]
    Ｃｈａｐｔｅｒ.５ [ モジュールについて ]
    Ｃｈａｐｔｅｒ.６ [ 変数 ]
    Ｃｈａｐｔｅｒ.７ [ 変数の型と宣言 ]
    Ｃｈａｐｔｅｒ.８ [ プロシージャとスコープ ]
    Ｃｈａｐｔｅｒ.９ [ ゲームつくる様々な手法 ]
    Ｃｈａｐｔｅｒ.１０ [ ユーザーフォーム ]
    Ｃｈａｐｔｅｒ.１１ [ プロパティウィンドウ ]
    Ｃｈａｐｔｅｒ.１２ [ 乱数 ]
    Ｃｈａｐｔｅｒ.１３ [ 条件分岐 ]
    Ｃｈａｐｔｅｒ.１４ [ ゲーム画面のデザイン ]
    Ｃｈａｐｔｅｒ.１５ [ コード記述の基本作法 ]
    Ｃｈａｐｔｅｒ.１６ [ じゃんけんゲーム：１ 名前をつける ]
    Ｃｈａｐｔｅｒ.１７ [ じゃんけんゲーム：２ フォームの起動 ]
    Ｃｈａｐｔｅｒ.１８ [ じゃんけんゲーム：３ 乱数の種 ]
    Ｃｈａｐｔｅｒ.１９ [ じゃんけんゲーム：４ イベント ]
    Ｃｈａｐｔｅｒ.２０ [ じゃんけんゲーム：５ 引数 ]
    Ｃｈａｐｔｅｒ.２１ [ じゃんけんゲーム：６ 役判定 ]
    Ｃｈａｐｔｅｒ.２２ [ じゃんけんゲーム：７ 予測と制限 ]
    Ｃｈａｐｔｅｒ.２３ [ Withステートメント ]
    Ｃｈａｐｔｅｒ.２４ [ 画像を表示させる ]
    Ｃｈａｐｔｅｒ.２５ [ 画像表示の発展形 ]
    Ｃｈａｐｔｅｒ.２６ [ 繰り返し処理 For文 ]
    Ｃｈａｐｔｅｒ.２７ [ 繰り返し処理 Do〜Loop文 ]
    Ｃｈａｐｔｅｒ.２８ [ Exitステートメント ]
    Ｃｈａｐｔｅｒ.２９ [ フォーム上の位置情報 ]
    Ｃｈａｐｔｅｒ.３０ [ API基礎知識 ]
    Ｃｈａｐｔｅｒ.３１ [ API補足知識 ]
    Ｃｈａｐｔｅｒ.３２ [ メインループを考える ]
    Ｃｈａｐｔｅｒ.３３ [ 同期処理の概念 ]
    Ｃｈａｐｔｅｒ.３４ [ 移動処理その１：画面設定と考え方 ]
    Ｃｈａｐｔｅｒ.３５ [ 移動処理その２：DoEvents ]
    Ｃｈａｐｔｅｒ.３６ [ 移動処理その３：キー入力判定API ]
    Ｃｈａｐｔｅｒ.３７ [ 条件分岐のさらなる探求 Select Case ]
    Ｃｈａｐｔｅｒ.３８ [ アニメーション ]
    Ｃｈａｐｔｅｒ.３９ [ 配列変数 ]
    Ｃｈａｐｔｅｒ.４０ [ ゲームの初期化 ]
    Ｃｈａｐｔｅｒ.４１ [ シューティングゲーム１：ゲーム設計 ]
    Ｃｈａｐｔｅｒ.４２ [ シューティングゲーム２：メインプロセス ]
    Ｃｈａｐｔｅｒ.４３ [ シューティングゲーム３：構造体 ]
    Ｃｈａｐｔｅｒ.４４ [ シューティングゲーム４：定数 ]
    Ｃｈａｐｔｅｒ.４５ [ シューティングゲーム５：プレイヤーキャラクター ]
    Ｃｈａｐｔｅｒ.４６ [ シューティングゲーム６：ショットを撃つ�� ]
    Ｃｈａｐｔｅｒ.４７ [ シューティングゲーム７：ショットを撃つ�� ]
    Ｃｈａｐｔｅｒ.４８ [ シューティングゲーム８：Mod演算子の活用 ]
    Ｃｈａｐｔｅｒ.４９ [ シューティングゲーム９：敵キャラクター登場 ]
    Ｃｈａｐｔｅｒ.５０ [ シューティングゲーム１０：衝突判定 ]
    Ｃｈａｐｔｅｒ.５１ [ シューティングゲーム１１：衝突の実体 ]
    Ｃｈａｐｔｅｒ.５２ [ シューティングゲーム１２：敵の攻撃 ]
    Ｃｈａｐｔｅｒ.５３ [ シューティングゲーム１３：爆発エフェクト ]
    Ｃｈａｐｔｅｒ.５４ [ シューティングゲーム１４：残機数表示�� ]
    Ｃｈａｐｔｅｒ.５５ [ シューティングゲーム１５：残機数表示�� ]
    Ｃｈａｐｔｅｒ.５６ [ シューティングゲーム１６：スコアの表示 ]
    Ｃｈａｐｔｅｒ.５７ [ シューティングゲーム１７：タイトル画面 ]
    Ｃｈａｐｔｅｒ.５８ [ シューティングゲーム１８：ボスキャラクター ]
    Ｃｈａｐｔｅｒ.５９ [ シューティングゲーム１９：最後の仕上げへ ]
    Ｃｈａｐｔｅｒ.６０ [ シューティングゲーム２０：いよいよ完成STG ]
    Ｃｈａｐｔｅｒ.６１ [ カードゲームで使えるめくり効果 ]
    Ｃｈａｐｔｅｒ.６２ [ ラジアンと角度 ]
    Ｃｈａｐｔｅｒ.６３ [ ラジアンの活用：円運動 ]
    Ｃｈａｐｔｅｒ.６４ [ ラジアンの活用：任意の角度へ移動する ]
    Ｃｈａｐｔｅｒ.６５ [ APIによるサウンド再生：基礎 ]
    Ｃｈａｐｔｅｒ.６６ [ APIによるサウンド再生：MIDIと多重再生 ]
    Ｃｈａｐｔｅｒ.６７ [ APIによるサウンド再生：MCIコマンドとループ再生 ]
    Ｃｈａｐｔｅｒ.６８ [ Function プロシージャ ]
    Ｃｈａｐｔｅｒ.６９ [ 値渡しと参照渡し ]
    Ｃｈａｐｔｅｒ.７０ [ デバッグ１：イミディエイトウィンドウ ]
    Ｃｈａｐｔｅｒ.７１ [ デバッグ２：ローカルウィンドウ ]
    Ｃｈａｐｔｅｒ.７２ [ デバッグ３：コード実行の中断 ]
    Ｃｈａｐｔｅｒ.７３ [ オブジェクトってなんだ ]
    Ｃｈａｐｔｅｒ.７４ [ プロパティ・メソッド・イベント ]
    Ｃｈａｐｔｅｒ.７５ [ オブジェクト変数 ]
    Ｃｈａｐｔｅｒ.７６ [ オブジェクトとコレクション ]
    Ｃｈａｐｔｅｒ.７７ [ 特殊な繰り返し：For Each ]
    Ｃｈａｐｔｅｒ.７８ [ エラー処理 ]
    Ｃｈａｐｔｅｒ.７９ [ On Error と GoTo文 ]
    Ｃｈａｐｔｅｒ.８０ [ Resumeステートメント ]
    Ｃｈａｐｔｅｒ.８１ [ バイトとビット ]
    Ｃｈａｐｔｅｒ.８２ [ ウィンドウメッセージとイベント ]
    Ｃｈａｐｔｅｒ.８３ [ 文字列の基礎 ]
    Ｃｈａｐｔｅｒ.８４ [ 文字列操作�� ]
    Ｃｈａｐｔｅｒ.８５ [ 文字列操作�� ]
    Ｃｈａｐｔｅｒ.８６ [ タイピングゲーム１：仕様を決める ]
    Ｃｈａｐｔｅｒ.８７ [ タイピングゲーム２：キー入力検知 ]
    Ｃｈａｐｔｅｒ.８８ [ タイピングゲーム３：文字列照合 ]
    Ｃｈａｐｔｅｒ.８９ [ タイピングゲーム４：判定関数 ]


    コードやVBAに関する質問などはサポート掲示板（別館）までお気軽にどうぞ。




fc2 seotool Excel VBA ゲーム プログラミング 講座

RSSフィード

リンク

このブログをリンクに追加する

By FC2ブログ

今すぐブログを作ろう！

Powered By FC2ブログ

Counter

DigitalClock

プロフィール

Author:
影斬
Ｅｘｃｅｌをこよなく愛するひと。
２〜３年ほど前から、ＥｘｃｅｌＶＢＡによるゲームプログラミングに目覚める。
得意な開発分野はタイピングゲーム(自称)。

最近の記事

最近のコメント

最近のトラックバック

Ｓｈａｄｏｗ ＢＢＳ - 影掲示板

  • ブログランキング
    ranking
    △ランキング参加中
    もしよかったら押してやってください。

    • ITブログランキング

    IT関連のブログ専用ランキングです。 良かったらをクリックお願いします。

    edita


    edita.jp【エディタ】


    From Omoituki

    Sozaiyasan blog