ExcelVBAゲームプログラミング？

初心者でもきっとできる！
Ｅｘｃｅｌさえ持っていれば特別なソフトは不要！
すぐにでも始められる簡単ゲームプログラミング！
今すぐ始めよう！

サンプルやゲームのダウンロードができる別館も好評運営中です。
ご意見やご質問、ゲームの感想等は掲示板までお気軽に。是非、皆さんの声を聞かせてください。運営、開発の励みになります。


各種ダウンロードはコチラ ↓ 意見・感想・質問はコチラ ↓
影倉庫 Shadow warehouse サポート掲示板
ブログの全体像はコチラ ↓ リンクのページはコチラ ↓
サイトマップ 自分本位なリンク


Ｃｈａｐｔｅｒ.５５ [ シューティングゲーム１５：残機数表示�� ]

■つづきです

さて、今回は前回の続きです。
講座を通して作成しているシューティングゲームに、残機数を表示するべく準備をした前回。ここからは実際のコードを記述していきます。

まずは、コードをすんなり理解するためにも、前回の講座で載せた新しいプロシージャの構造をもう一度見てみましょう。

If 生きているか = 生きている Then
    If 演出中かどうか = 演出中 Then
        復活時の演出
    Else
        キー入力判定処理
        はみだし防止処理
        ショットを撃つかどうかの判断
    End If
Else
    死亡時の演出
End If
ユーザーフォーム上の処理

色の着いている部分を今回修正します。
重要なのは、キャラクターの生死の状態や、演出中かどうかによって、処理が分岐するという仕組みです。

上の構造図をよく見ながら、ゲーム中の実際の流れをイメージしてみてください。

プレイヤーキャラクターが、今現在、生きているのかいないのか、それによって赤い字で書かれたIf文の部分で処理が分かれます。
もし、プレイヤーキャラクターが生きているとすると、『復活時の演出』か『プレイヤーの処理』のいずれかが実行されます。逆に死んでいるとすると、『死亡時の演出』に処理が移りますね。

ただし、プレイヤーキャラクターが生きている場合には、さらにもう一段階の分岐があります。それが青い字のIf文で表されている部分にあたります。
ここでは、今現在、演出をしている最中かどうかによって処理が分岐します。もしも演出中であれば、それに応じた演出処理が行われますし、演出中でなければ、これは通常のプレイヤーキャラクターを操作できる状態ということになります。

ざっくりとした流れは、なんとなく理解できますか？
キャラクターが生きているのかどうか、そして、生きていたとしたら演出中なのかどうか。まずはそれを条件分岐によって判断します。カーソルキーでキャラクターを操作できるときは『生きていて演出していないとき』ということですね。この考え方をよく理解したうえで、実際のコードを見てみましょう。

Sub Player_Action()

    Dim S As Single
    Dim SS As Single
    
    Randomize
    
    With Player_Data
        If .Lif > 0 Then
            If .Par > 0 Then
                If .Y > 180 Then
                    .Y = .Y - 1
                Else
                    .Par = 0
                End If
            Else
                If GetAsyncKeyState(Left_Key) < 0 Then .X = .X - 3
                If GetAsyncKeyState(Up_Key) < 0 Then .Y = .Y - 3
                If GetAsyncKeyState(Right_Key) < 0 Then .X = .X + 3
                If GetAsyncKeyState(Down_Key) < 0 Then .Y = .Y + 3

                If .X - Player_Size < 0 Then .X = Player_Size
                If .X + Player_Size > 200 Then .X = 200 - Player_Size
                If .Y - Player_Size < 0 Then .Y = Player_Size
                If .Y + Player_Size > 200 Then .Y = 200 - Player_Size

                If Shot_Interval = 0 Then
                    If GetAsyncKeyState(Shot_Key) < 0 Then
                        Call P_Shot_Begin(.X, .Y, 1)
                        Shot_Interval = 1
                    End If
                Else
                    Shot_Interval = Shot_Interval + 1
                    If Shot_Interval > 7 Then Shot_Interval = 0
                End If
            End If
        Else
            .Par = .Par + 1
            If .Par > 50 Then
                .X = 100
                .Y = 210
                .Lif = 1
                .Par = 1
                Player_Stock = Player_Stock - 1
                Select Case Player_Stock
                    Case Is < 0
                        MsgBox "Game Over"
                    Case 0
                        UserForm1.Stock1.Visible = False
                    Case 1
                        UserForm1.Stock2.Visible = False
                End Select
            Else
                If .Par Mod 9 = 1 Then
                    S = Int(Rnd * 20) - 9
                    SS = Int(Rnd * 20) - 9
                    Call Burst_Begin(.X + S, .Y + SS)
                End If
            End If
        End If
        With UserForm1.Player
            .Left = Player_Data.X - Player_Size
            .Top = Player_Data.Y - Player_Size
        End With
    End With
    
End Sub

さて、なんだかカラフルなコードになっちゃいました。
色の着いている部分が今回変更になった部分です。先ほどの構造図と、同じ要領で色が着いていますので、よく見比べてみるとなんとなく構造がわかると思います。

まずは緑色の文字部分。ここは単純に追加された部分です。コードを追加するにあたり、新たに必要となる変数の宣言をしています。さらに、乱数を使用するのでRandomizeを使って、乱数ジェネレータを初期化しています。
Randomizeについては、以前の講座で詳しく解説していますので、わからない人はそちらも併せてどうぞ(Chapter12を参照)。

さて、その次は赤い字のIf文で、キャラクターが生きているか死んでいるかをチェックして処理を分岐します。
要素Lifがプレイヤーキャラクターの生存状態を表しており、この部分が０より大きければ、キャラクターは生きています。逆に０以下だった場合には、キャラクターは死んでいるということになりますね。

そして青い字で書かれているIf文では、演出を行っている最中かどうかを判定します。演出を行っているかどうかは、要素Parが管理します。この要素の値が０以外の時には、何かしらの演出を行っている最中として考えます。

上のほうで出てくる黄色い字の処理では、『復活時の演出』を行っています。ここでは、キャラクターが画面の下のほうから、ゆっくりと登場するように処理しています。
キャラクターの縦位置が、一定の座標に達するまで、すこしずつキャラクターを移動しているわけです。指定された座標まで到達したら、演出を終わらせるために要素Parに０を代入します。ここで０を代入したことによって、次回のループからはキャラクターを通常通りカーソルキーで操作できるようになります。

ここまでが、キャラクターが生きている場合の処理になります。
キャラクターが生きている場合には、復活時の演出か、あるいはカーソルキーで操作できる状態かのいずれかが実行されることになりますね。


■それじゃ死亡時の処理は？

さて次はキャラクターが死んでいる場合の処理です。
下のほうにある黄色い字の部分がこれにあたります。

ここは少し複雑なので、抜粋したコードを載せます。

.Par = .Par + 1 '��
If .Par > 50 Then '��
    .X = 100
    .Y = 210
    .Lif = 1
    .Par = 1
    Player_Stock = Player_Stock - 1
    Select Case Player_Stock
        Case Is < 0
            MsgBox "Game Over" '��
        Case 0
            UserForm1.Stock1.Visible = False '��
        Case 1
            UserForm1.Stock2.Visible = False '��
    End Select
Else
    If .Par Mod 9 = 1 Then '��
        S = Int(Rnd * 20) - 9
        SS = Int(Rnd * 20) - 9
        Call Burst_Begin(.X + S, .Y + SS)
    End If
End If

まず�，良�分です。
ここでは要素Parの値をプラス１していますね。これは何のためかといいますと、要素Parをカウンタの役割として使うためです。
ループするたびにプラス１ずつ増やしているわけですから、演出が始まってから、どのくらいの時間が経っているのかは、要素Parの値を調べることでわかります。たくさんカウントされたあとであれば、大きな値が入っているはずですし、逆にまだあまり時間が経っていなければ、小さな値が入っているはずです。

それを踏まえて�△良�分を見てください。
ここでは、要素Parが５０よりも大きな値になっているかどうかチェックしていますね。もしも５０よりも大きな数値になるまで時間が経っている場合には、ここで死亡時の演出を終わりにして、復活時の処理へ移行させます。
キャラクターの横位置や縦位置を設定して、さらに生きている状態に戻すため、要素Lifに１を代入しています。また、復活時の演出を行わせるために、要素Parにも１を代入しています。

そして、残機数を表す変数Player_Stockをひとつ減らします。これで残機数がひとつ少なくなるわけですね。

その後、変数Player_Stockの値に応じてSelect Case文で処理を分岐しています。これが��です。
変数Player_Stockの値は規定値で２が入っています。
変数Player_Stockの値が、１だったときは１回死んでしまったことになり、０だった場合には、すでに２回死んでいることになります。もしもここがマイナスだった場合には、３回死んだことになりますから、メッセージを表示して、ゲームオーバーの状態になったことを通知しています。

ゲームオーバーにならない場合には、残機数を表すイメージコントロール『 Stock1・Stock2 』を適宜非表示にしています。

続いて�い良�分。多分コードを見ただけで、これが何をしているコードなのかわかる人は少ないと思います。実際にはこんなことしなくてもいいんですが、『演出』という意味では結構重要な部分だと個人的には思います。

実はこの�い良�分は、被弾したプレイヤーキャラクターが爆発しているシーンを演出しています。
敵キャラクターならまだしも、プレイヤーキャラクターが被弾してしまったときに、単発の爆発で終わってしまうのはなんだか寂しい気がします。これはかなり個人的な意見ですが。

そこで、プレイヤーキャラクターの死亡時の演出として、復活するまでの間９ループごとに爆発のエフェクトを複数回表示するようにしています。Mod演算子を使って、要素Parの値が５０よりも大きくなるまでの間、何度か爆発のエフェクトが発生するようになっています。
爆発エフェクトの発生する座標もランダムに決めているので、キャラクターが崩れ落ちるように何度も爆発しているような感じになっていると思います。
多分これは実際に動くのを見てもらったほうがわかりやすいのではないかな。言葉で説明するのが難しい……。講座の最後に、サンプルへのリンクがありますので、よかったらそちらからサンプルを落として、実際に見てみてください。そのほうがわかりやすいと思います。

とりあえず、ここまでの全コードを掲載しますので、やる気のある方は自力で修正してみるといいでしょう。

'標準モジュール先頭部分

'◆API　宣言
Declare Function GetTickCount Lib "kernel32" () As Long
Declare Function GetAsyncKeyState Lib "user32" (ByVal vKey As Long) As Integer
Declare Sub Sleep Lib "kernel32.dll" (ByVal dwMillsecounds As Long)

'■キャラクター　構造体宣言
Type Chara
    X As Single
    Y As Single
    W As Single
    H As Single
    Lif As Long
    Typ As Long
    Par As Long
End Type

'■ショット　構造体宣言
Type Shot
    X As Single
    Y As Single
    Vis As Boolean
    Typ As Long
End Type

'■汎用オブジェクト　構造体宣言
Type Obj
    X As Single
    Y As Single
    W As Single
    H As Single
    Par As Long
End Type

'●キャラクター　変数宣言
Public Player_Data As Chara
Public Enemy_Data(9) As Chara

'●ショット　変数宣言
Public P_Shot_Data(4) As Shot
Public E_Shot_Data(9) As Shot

'●汎用オブジェクト　変数宣言
Public Burst_Data(2) As Obj

'◎その他　変数宣言
Public Shot_Interval As Long
Public Total_Count As Long 'ゲーム中のカウンタ
Public Player_Stock As Long 'プレイヤーの残機数

'▲定数宣言
Public Const Left_Key As Long = 37 'カーソル左
Public Const Up_Key As Long = 38 'カーソル上
Public Const Right_Key As Long = 39 'カーソル右
Public Const Down_Key As Long = 40 'カーソル下
Public Const Esc_Key As Long = 27 'Ｅｓｃキー
Public Const Shot_Key As Long = 90 'Ｚキー
Public Const Player_Size As Single = 9
'プレイヤーキャラクターの実際の大きさ
Public Const Shot_Size As Single = 3
'弾各種の実際の大きさ
Public Const Enemy_Size As Single = 9
'敵キャラクターの実際の大きさ
Public Const Burst_Size As Single = 15
'爆発エフェクトの実際の大きさ


'初期化を担当するプロシージャ

Sub Init()
    With Player_Data
        .X = 100
        .Y = 210
        .W = 3
        .H = 3
        .Lif = 1
        .Typ = 0
        .Par = 1
    End With
    Erase P_Shot_Data
    Erase E_Shot_Data
    Erase Enemy_Data
    Erase Burst_Data
    Shot_Interval = 0
    Total_Count = 0
    Player_Stock = 2
    With UserForm1.Player
        .Visible = True
        .Top = 200
    End With
End Sub

'メインプロセスを担当するプロシージャ

Sub Main()

    Dim Flg As Boolean
    Dim Stm As Long
    
    Call Init
    
    Flg = False
    
    Do Until Flg
        Stm = GetTickCount
        Total_Count = Total_Count + 1
        Call Stage_Count
        Call Player_Action
        Call P_Shot_Action
        Call Enemy_Action
        Call E_Shot_Action
        Call Burst_Action
        DoEvents
        Do
            Call Sleep(1)
        Loop Until GetTickCount - Stm > 30
        If GetAsyncKeyState(Esc_Key) < 0 Then Flg = True
    Loop
    
End Sub


'敵キャラクターの出現管理プロシージャ

Sub Stage_Count()
    Randomize
    Select Case Total_Count Mod 200
        Case 0
            Call Enemy_Begin(Int(Rnd * 120) + 40, -10, 1)
        Case 50
            Call Enemy_Begin(Int(Rnd * 120) + 40, -10, 2)
        Case 100
            Call Enemy_Begin(Int(Rnd * 120) + 40, -10, 3)
    End Select
End Sub


'プレイヤーキャラクターを担当するプロシージャ

Sub Player_Action()

    Dim S As Single
    Dim SS As Single
    
    Randomize
    
    With Player_Data
        If .Lif > 0 Then
            If .Par > 0 Then
                If .Y > 180 Then
                    .Y = .Y - 1
                Else
                    .Par = 0
                End If
            Else
                If GetAsyncKeyState(Left_Key) < 0 Then .X = .X - 3
                If GetAsyncKeyState(Up_Key) < 0 Then .Y = .Y - 3
                If GetAsyncKeyState(Right_Key) < 0 Then .X = .X + 3
                If GetAsyncKeyState(Down_Key) < 0 Then .Y = .Y + 3

                If .X - Player_Size < 0 Then .X = Player_Size
                If .X + Player_Size > 200 Then .X = 200 - Player_Size
                If .Y - Player_Size < 0 Then .Y = Player_Size
                If .Y + Player_Size > 200 Then .Y = 200 - Player_Size

                If Shot_Interval = 0 Then
                    If GetAsyncKeyState(Shot_Key) < 0 Then
                        Call P_Shot_Begin(.X, .Y, 1)
                        Shot_Interval = 1
                    End If
                Else
                    Shot_Interval = Shot_Interval + 1
                    If Shot_Interval > 7 Then Shot_Interval = 0
                End If
            End If
        Else
            .Par = .Par + 1
            If .Par > 50 Then
                .X = 100
                .Y = 210
                .Lif = 1
                .Par = 1
                Player_Stock = Player_Stock - 1
                Select Case Player_Stock
                    Case Is < 0
                        MsgBox "Game Over"
                    Case 0
                        UserForm1.Stock1.Visible = False
                    Case 1
                        UserForm1.Stock2.Visible = False
                End Select
            Else
                If .Par Mod 9 = 1 Then
                    S = Int(Rnd * 20) - 9
                    SS = Int(Rnd * 20) - 9
                    Call Burst_Begin(.X + S, .Y + SS)
                End If
            End If
        End If
        With UserForm1.Player
            .Left = Player_Data.X - Player_Size
            .Top = Player_Data.Y - Player_Size
        End With
    End With
    
End Sub


'ショット生成プロシージャ

Sub P_Shot_Begin(X As Single, Y As Single, Typ As Long)

    Dim L As Long

    For L = 0 To 4
        With P_Shot_Data(L)
            If Not .Vis Then
                .X = X
                .Y = Y
                .Typ = Typ
                .Vis = True
                UserForm1.Controls("P_Shot" & L + 1).Visible = True
                Exit For
            End If
        End With
    Next

End Sub


'ショット移動管理プロシージャ

Sub P_Shot_Action()

    Dim L As Long
    Dim LL As Long

    For L = 0 To 4
        With P_Shot_Data(L)
            If .Vis Then
                .Y = .Y - 6
                If .Y < -5 Then .Vis = False
                For LL = 0 To 9
                    If Enemy_Data(LL).Lif > 0 Then
                        If .X - 2 < Enemy_Data(LL).X + Enemy_Data(LL).W Then
                            If .X + 2 > Enemy_Data(LL).X - Enemy_Data(LL).W Then
                                If .Y - 2 < Enemy_Data(LL).Y + Enemy_Data(LL).H Then
                                    If .Y + 2 > Enemy_Data(LL).Y - Enemy_Data(LL).H Then
                                        .Vis = False
                                        With Enemy_Data(LL)
                                            Call Burst_Begin(.X, .Y)
                                            .Lif = 0
                                        End With
                                        Exit For
                                    End If
                                End If
                            End If
                        End If
                    End If
                Next
                With UserForm1.Controls("P_Shot" & L + 1)
                    If P_Shot_Data(L).Vis Then
                        .Left = P_Shot_Data(L).X - Shot_Size
                        .Top = P_Shot_Data(L).Y - Shot_Size
                    Else
                        .Visible = False
                    End If
                End With
            End If
        End With
    Next

End Sub


'敵キャラクター生成プロシージャ

Sub Enemy_Begin(X As Single, Y As Single, Typ As Long)

    Dim L As Long
    
    For L = 0 To 9
        With Enemy_Data(L)
            If .Lif = 0 Then
                .X = X
                .Y = Y
                .W = 5
                .H = 5
                .Typ = Typ
                .Lif = 1
                .Par = 0
                With UserForm1.Controls("Enemy" & L + 1)
                    .Visible = True
                    Select Case Typ
                        Case 1
                            .Picture = UserForm1.Enemy_s1.Picture
                        Case 2, 3
                            .Picture = UserForm1.Enemy_s2.Picture
                    End Select
                End With
                Exit For
            End If
        End With
    Next
    
End Sub


'敵キャラクターを担当するプロシージャ

Sub Enemy_Action()

    Dim L As Long
    Dim TCMOD
    
    TCMOD = Total_Count Mod 30
    
    For L = 0 To 9
        With Enemy_Data(L)
            If .Lif > 0 Then
                Select Case .Typ
                    Case 1
                        .Y = .Y + 1.5
                    Case 2
                        .X = .X + 0.5
                        .Y = .Y + 1
                    Case 3
                        .X = .X - 0.5
                        .Y = .Y + 1
                End Select
                If .X > 220 Then .Lif = 0
                If .Y > 220 Then .Lif = 0
                If .X < -20 Then .Lif = 0
                If .Y < -20 Then .Lif = 0
                If TCMOD = 0 Then
                    Select Case .Typ
                        Case 2
                            .Typ = 3
                        Case 3
                            .Typ = 2
                    End Select
                    Call E_Shot_Begin(.X, .Y + 2, .Typ)
                End If
            End If
        End With
        With UserForm1.Controls("Enemy" & L + 1)
            If Enemy_Data(L).Lif > 0 Then
                .Left = Enemy_Data(L).X - Enemy_Size
                .Top = Enemy_Data(L).Y - Enemy_Size
            Else
                .Visible = False
            End If
        End With
    Next
    
End Sub


'敵キャラクターショット生成プロシージャ

Sub E_Shot_Begin(X As Single, Y As Single, Typ As Long)
    
    Dim L As Long
    
    For L = 0 To 9
        With E_Shot_Data(L)
            If Not .Vis Then
                .X = X
                .Y = Y
                .Typ = Typ
                .Vis = True
                With UserForm1.Controls("E_Shot" & L + 1)
                    .Visible = True
                End With
                Exit For
            End If
        End With
    Next
    
End Sub


'敵キャラクターショット移動管理プロシージャ

Sub E_Shot_Action()

    Dim L As Long
    Dim LL As Long
    
    For L = 0 To 9
        With E_Shot_Data(L)
            If .Vis Then
                Select Case .Typ
                    Case 1
                        .Y = .Y + 4.5
                    Case 2
                        .X = .X + 0.5
                        .Y = .Y + 3.5
                    Case 3
                        .X = .X - 0.5
                        .Y = .Y + 3.5
                End Select
                If .X > 205 Then .Vis = 0
                If .Y > 205 Then .Vis = 0
                If .X < -5 Then .Vis = 0
                If .Y < -5 Then .Vis = 0
                If .X - 2 < Player_Data.X + Player_Data.W Then
                    If .X + 2 > Player_Data.X - Player_Data.W Then
                        If .Y - 2 < Player_Data.Y + Player_Data.H Then
                            If .Y + 2 > Player_Data.Y - Player_Data.H Then
                                .Vis = False
                                With Player_Data
                                    Call Burst_Begin(.X, .Y)
                                    .Lif = 0
                                End With
                            End If
                        End If
                    End If
                End If
                With UserForm1.Controls("E_Shot" & L + 1)
                    If E_Shot_Data(L).Vis Then
                        .Left = E_Shot_Data(L).X - Shot_Size
                        .Top = E_Shot_Data(L).Y - Shot_Size
                    Else
                        .Visible = False
                    End If
                End With
            End If
        End With
    Next
                
End Sub


'爆発エフェクト生成プロシージャ

Sub Burst_Begin(X As Single, Y As Single)

    Dim L As Long
    
    For L = 0 To 2
        With Burst_Data(L)
            If .Par = 0 Then
                .X = X
                .Y = Y
                .W = Burst_Size
                .H = Burst_Size
                .Par = 1
                UserForm1.Controls("Burst" & L + 1).Visible = True
                Exit For
            End If
        End With
    Next
    
End Sub


'爆発エフェクト管理プロシージャ

Sub Burst_Action()

    Dim L As Long
    Dim Pict As Long
    
    For L = 0 To 2
        With Burst_Data(L)
            If .Par > 0 Then
                Select Case .Par
                    Case 1
                        Pict = 1
                    Case 2, 3
                        Pict = 2
                    Case 4, 5
                        Pict = 3
                    Case 6, 7
                        Pict = 4
                    Case 8
                        Pict = 5
                    Case 9
                        .Par = -1
                End Select
                .Par = .Par + 1
                With UserForm1.Controls("Burst" & L + 1)
                    If Burst_Data(L).Par > 0 Then
                        .Left = Burst_Data(L).X - Burst_Size
                        .Top = Burst_Data(L).Y - Burst_Size
                        .Picture = UserForm1.Controls("Burst_s" & Pict).Picture
                    Else
                        .Visible = False
                    End If
                End With
            End If
        End With
    Next
                
End Sub


'標準モジュールはここまで
'ここから下はフォームモジュールに記述


'コマンドボタンのクリックイベント

Private Sub Com_Start_Click()
    Com_Start.Enabled = False
    Call Main
    Unload UserForm1
End Sub


'ユーザーフォームのクエリクロースイベント

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    End
End Sub


'ユーザーフォームのイニシャライズイベント
Private Sub UserForm_Initialize()
    UserForm1.Width = 220
End Sub



ちなみに、ここまでの状態だと、一度ゲームオーバーになってしまっても、おかまいなしでキャラクターが登場し続けます。つまり、まだ未完成ということです。
将来的には、ゲームオーバーになったらゲームが終わってしまうようにしなければなりませんが、それはまた次回以降、がんばってみることにしましょう。

まずは、サンプルをご覧頂くなり、コードを自力で調整するなりしていただいて、今回までの内容を実装させてみてください。



サンプルダウンロード　⇒　コチラよりダウンロードできます。（別館）


■格言

順番に条件に沿って考える
全体の構図をよく理解する

やや複雑ですが、ひとつひとつ順番に理解することが大切です。
FC2ブックマークに追加






Comment

Name
E-mail
URL
Comment
Pass  *
Secret？ （管理者にだけ表示）

プログラミング関連検索



プログラミングや ExcelVBA に関連した検索にはこちらをどうぞ。

メールフォーム

影斬に物申すという方はこちら

名前　:
メール:
件名　:
本文　:

可能な限り要望には応えますが、必ず返信や回答ができることを、保障するものではありません。
ご了承ください。

Ｃｈａｐｔｅｒｓ

コンテンツ一覧


■Chapter 一覧■
    全てのChapterの一覧です。
    直接アクセスしたい方はこちらをご利用下さい。

    Ｃｈａｐｔｅｒ.１ [ 知っておくべき心得 ]
    Ｃｈａｐｔｅｒ.２ [ Ｅｘｃｅｌってなんだろう ]
    Ｃｈａｐｔｅｒ.３ [ Ｅｘｃｅｌの基本画面 ]
    Ｃｈａｐｔｅｒ.４ [ ＶＢＡとは？ ]
    Ｃｈａｐｔｅｒ.５ [ モジュールについて ]
    Ｃｈａｐｔｅｒ.６ [ 変数 ]
    Ｃｈａｐｔｅｒ.７ [ 変数の型と宣言 ]
    Ｃｈａｐｔｅｒ.８ [ プロシージャとスコープ ]
    Ｃｈａｐｔｅｒ.９ [ ゲームつくる様々な手法 ]
    Ｃｈａｐｔｅｒ.１０ [ ユーザーフォーム ]
    Ｃｈａｐｔｅｒ.１１ [ プロパティウィンドウ ]
    Ｃｈａｐｔｅｒ.１２ [ 乱数 ]
    Ｃｈａｐｔｅｒ.１３ [ 条件分岐 ]
    Ｃｈａｐｔｅｒ.１４ [ ゲーム画面のデザイン ]
    Ｃｈａｐｔｅｒ.１５ [ コード記述の基本作法 ]
    Ｃｈａｐｔｅｒ.１６ [ じゃんけんゲーム：１ 名前をつける ]
    Ｃｈａｐｔｅｒ.１７ [ じゃんけんゲーム：２ フォームの起動 ]
    Ｃｈａｐｔｅｒ.１８ [ じゃんけんゲーム：３ 乱数の種 ]
    Ｃｈａｐｔｅｒ.１９ [ じゃんけんゲーム：４ イベント ]
    Ｃｈａｐｔｅｒ.２０ [ じゃんけんゲーム：５ 引数 ]
    Ｃｈａｐｔｅｒ.２１ [ じゃんけんゲーム：６ 役判定 ]
    Ｃｈａｐｔｅｒ.２２ [ じゃんけんゲーム：７ 予測と制限 ]
    Ｃｈａｐｔｅｒ.２３ [ Withステートメント ]
    Ｃｈａｐｔｅｒ.２４ [ 画像を表示させる ]
    Ｃｈａｐｔｅｒ.２５ [ 画像表示の発展形 ]
    Ｃｈａｐｔｅｒ.２６ [ 繰り返し処理 For文 ]
    Ｃｈａｐｔｅｒ.２７ [ 繰り返し処理 Do〜Loop文 ]
    Ｃｈａｐｔｅｒ.２８ [ Exitステートメント ]
    Ｃｈａｐｔｅｒ.２９ [ フォーム上の位置情報 ]
    Ｃｈａｐｔｅｒ.３０ [ API基礎知識 ]
    Ｃｈａｐｔｅｒ.３１ [ API補足知識 ]
    Ｃｈａｐｔｅｒ.３２ [ メインループを考える ]
    Ｃｈａｐｔｅｒ.３３ [ 同期処理の概念 ]
    Ｃｈａｐｔｅｒ.３４ [ 移動処理その１：画面設定と考え方 ]
    Ｃｈａｐｔｅｒ.３５ [ 移動処理その２：DoEvents ]
    Ｃｈａｐｔｅｒ.３６ [ 移動処理その３：キー入力判定API ]
    Ｃｈａｐｔｅｒ.３７ [ 条件分岐のさらなる探求 Select Case ]
    Ｃｈａｐｔｅｒ.３８ [ アニメーション ]
    Ｃｈａｐｔｅｒ.３９ [ 配列変数 ]
    Ｃｈａｐｔｅｒ.４０ [ ゲームの初期化 ]
    Ｃｈａｐｔｅｒ.４１ [ シューティングゲーム１：ゲーム設計 ]
    Ｃｈａｐｔｅｒ.４２ [ シューティングゲーム２：メインプロセス ]
    Ｃｈａｐｔｅｒ.４３ [ シューティングゲーム３：構造体 ]
    Ｃｈａｐｔｅｒ.４４ [ シューティングゲーム４：定数 ]
    Ｃｈａｐｔｅｒ.４５ [ シューティングゲーム５：プレイヤーキャラクター ]
    Ｃｈａｐｔｅｒ.４６ [ シューティングゲーム６：ショットを撃つ�� ]
    Ｃｈａｐｔｅｒ.４７ [ シューティングゲーム７：ショットを撃つ�� ]
    Ｃｈａｐｔｅｒ.４８ [ シューティングゲーム８：Mod演算子の活用 ]
    Ｃｈａｐｔｅｒ.４９ [ シューティングゲーム９：敵キャラクター登場 ]
    Ｃｈａｐｔｅｒ.５０ [ シューティングゲーム１０：衝突判定 ]
    Ｃｈａｐｔｅｒ.５１ [ シューティングゲーム１１：衝突の実体 ]
    Ｃｈａｐｔｅｒ.５２ [ シューティングゲーム１２：敵の攻撃 ]
    Ｃｈａｐｔｅｒ.５３ [ シューティングゲーム１３：爆発エフェクト ]
    Ｃｈａｐｔｅｒ.５４ [ シューティングゲーム１４：残機数表示�� ]
    Ｃｈａｐｔｅｒ.５５ [ シューティングゲーム１５：残機数表示�� ]
    Ｃｈａｐｔｅｒ.５６ [ シューティングゲーム１６：スコアの表示 ]
    Ｃｈａｐｔｅｒ.５７ [ シューティングゲーム１７：タイトル画面 ]
    Ｃｈａｐｔｅｒ.５８ [ シューティングゲーム１８：ボスキャラクター ]
    Ｃｈａｐｔｅｒ.５９ [ シューティングゲーム１９：最後の仕上げへ ]
    Ｃｈａｐｔｅｒ.６０ [ シューティングゲーム２０：いよいよ完成STG ]
    Ｃｈａｐｔｅｒ.６１ [ カードゲームで使えるめくり効果 ]
    Ｃｈａｐｔｅｒ.６２ [ ラジアンと角度 ]
    Ｃｈａｐｔｅｒ.６３ [ ラジアンの活用：円運動 ]
    Ｃｈａｐｔｅｒ.６４ [ ラジアンの活用：任意の角度へ移動する ]
    Ｃｈａｐｔｅｒ.６５ [ APIによるサウンド再生：基礎 ]
    Ｃｈａｐｔｅｒ.６６ [ APIによるサウンド再生：MIDIと多重再生 ]
    Ｃｈａｐｔｅｒ.６７ [ APIによるサウンド再生：MCIコマンドとループ再生 ]
    Ｃｈａｐｔｅｒ.６８ [ Function プロシージャ ]
    Ｃｈａｐｔｅｒ.６９ [ 値渡しと参照渡し ]
    Ｃｈａｐｔｅｒ.７０ [ デバッグ１：イミディエイトウィンドウ ]
    Ｃｈａｐｔｅｒ.７１ [ デバッグ２：ローカルウィンドウ ]
    Ｃｈａｐｔｅｒ.７２ [ デバッグ３：コード実行の中断 ]
    Ｃｈａｐｔｅｒ.７３ [ オブジェクトってなんだ ]
    Ｃｈａｐｔｅｒ.７４ [ プロパティ・メソッド・イベント ]
    Ｃｈａｐｔｅｒ.７５ [ オブジェクト変数 ]
    Ｃｈａｐｔｅｒ.７６ [ オブジェクトとコレクション ]
    Ｃｈａｐｔｅｒ.７７ [ 特殊な繰り返し：For Each ]
    Ｃｈａｐｔｅｒ.７８ [ エラー処理 ]
    Ｃｈａｐｔｅｒ.７９ [ On Error と GoTo文 ]
    Ｃｈａｐｔｅｒ.８０ [ Resumeステートメント ]
    Ｃｈａｐｔｅｒ.８１ [ バイトとビット ]
    Ｃｈａｐｔｅｒ.８２ [ ウィンドウメッセージとイベント ]
    Ｃｈａｐｔｅｒ.８３ [ 文字列の基礎 ]
    Ｃｈａｐｔｅｒ.８４ [ 文字列操作�� ]
    Ｃｈａｐｔｅｒ.８５ [ 文字列操作�� ]
    Ｃｈａｐｔｅｒ.８６ [ タイピングゲーム１：仕様を決める ]
    Ｃｈａｐｔｅｒ.８７ [ タイピングゲーム２：キー入力検知 ]
    Ｃｈａｐｔｅｒ.８８ [ タイピングゲーム３：文字列照合 ]
    Ｃｈａｐｔｅｒ.８９ [ タイピングゲーム４：判定関数 ]
    Ｃｈａｐｔｅｒ.９０ [ タイピングゲーム５：ゲーム画面設計 ]
    Ｃｈａｐｔｅｒ.９１ [ タイピングゲーム６：問題文のソート ]
    Ｃｈａｐｔｅｒ.９２ [ タイピングゲーム７：動的配列 ]
    Ｃｈａｐｔｅｒ.９３ [ タイピングゲーム８：キーダウンイベント ]
    Ｃｈａｐｔｅｒ.９４ [ タイピングゲーム９：正打数の表示 ]
    Ｃｈａｐｔｅｒ.９５ [ タイピングゲーム１０：タイムの表示 ]
    Ｃｈａｐｔｅｒ.９６ [ クリックゲーム１：イベントの種類 ]
    Ｃｈａｐｔｅｒ.９７ [ クリックゲーム２：画面設計 ]
    Ｃｈａｐｔｅｒ.９８ [ クリックゲーム３：クリック座標検知 ]
    Ｃｈａｐｔｅｒ.９９ [ クリックゲーム４：キャラクター準備 ]
    Ｃｈａｐｔｅｒ.１００ [ クリックゲーム５：キャラクターの配置 ]
    Ｃｈａｐｔｅｒ.１０１ [ クリックゲーム６：キャラクター移動とNot演算子 ]
    Ｃｈａｐｔｅｒ.１０２ [ クリックゲーム７：クリックのヒット判定 ]
    Ｃｈａｐｔｅｒ.１０３ [ クリックゲーム８：ヒットマークエフェクト ]
    Ｃｈａｐｔｅｒ.１０４ [ クリックゲーム９：サウンド処理の実装 ]
    Ｃｈａｐｔｅｒ.１０５ [ クリックゲーム１０：マウスカーソルの変更 ]
    Ｃｈａｐｔｅｒ.１０６ [ ブロック崩しゲーム１：仕様と概要を決める ]
    Ｃｈａｐｔｅｒ.１０７ [ ブロック崩しゲーム２：基本概念の確認 ]
    Ｃｈａｐｔｅｒ.１０８ [ ブロック崩しゲーム３：ベクトルとは ]
    Ｃｈａｐｔｅｒ.１０９ [ ブロック崩しゲーム４：変数や定数の宣言 ]
    Ｃｈａｐｔｅｒ.１１０ [ ブロック崩しゲーム５：初期化処理の実装 ]
    Ｃｈａｐｔｅｒ.１１１ [ ブロック崩しゲーム６：ブロックの配置 ]
    Ｃｈａｐｔｅｒ.１１２ [ ブロック崩しゲーム７：根幹処理とバーの処理 ]
    Ｃｈａｐｔｅｒ.１１３ [ ブロック崩しゲーム８：線分と線分の交差を判定 ]
    Ｃｈａｐｔｅｒ.１１４ [ ブロック崩しゲーム９：線分同士の交点 ]


    コードやVBAに関する質問などはサポート掲示板（別館）までお気軽にどうぞ。




fc2 seotool Excel VBA ゲーム プログラミング 講座

RSSフィード

リンク

このブログをリンクに追加する

By FC2ブログ

今すぐブログを作ろう！

Powered By FC2ブログ

Counter

DigitalClock

プロフィール

Author:
影斬
Excelをこよなく愛する。
DirectXを本格的に使用したVBAゲームの開発に成功。VBAゲーム界の発展を願い、日々活動中。

最近の記事

最近のコメント

最近のトラックバック

Ｓｈａｄｏｗ ＢＢＳ - 影掲示板

  • ブログランキング
    ranking
    △ランキング参加中
    もしよかったら押してやってください。

    • edita


    edita.jp【エディタ】


    From Omoituki

    VBA 関連書籍


    Sozaiyasan blog