ExcelVBAゲームプログラミング？

初心者でもきっとできる！
Ｅｘｃｅｌさえ持っていれば特別なソフトは不要！
すぐにでも始められる簡単ゲームプログラミング！
今すぐ始めよう！

サンプルやゲームのダウンロードができる別館も好評運営中です。
ご意見やご質問、ゲームの感想等は掲示板までお気軽に。是非、皆さんの声を聞かせてください。運営、開発の励みになります。


各種ダウンロードはコチラ ↓ 意見・感想・質問はコチラ ↓
影倉庫 Shadow warehouse サポート掲示板
ブログの全体像はコチラ ↓ リンクのページはコチラ ↓
サイトマップ 自分本位なリンク


Ｃｈａｐｔｅｒ.５３ [ シューティングゲーム１３：爆発エフェクト ]

■エフェクト

エフェクトとひとくちに言っても、実際には色々なものがあります。シューティングゲームだけで考えても、ショットを撃った瞬間の閃光や、敵キャラクターを倒したときの爆風などが思い浮かびますね。
それ以外にも、アイテムを取った瞬間にキャラクターが光るようにしたりすれば、それも立派なエフェクトです。ゲームの開始時に、タイトルロゴがカットインしてくるようにすればこれもエフェクトですね。

今回は、シューティングゲームに、爆発のエフェクトを追加してみたいと思います。
これが実装できると、敵キャラクターが爆発しながら消えるので、ショットが当たった感触が強くなりますね。プレイヤーが被弾した際も、おもわず『しまった！』と言いたくなるでしょう。
爆発のエフェクトなんてほんの小さなことですが、あるとないとではゲームの完成度が違ってきます。見た目もかなり良くなります。

考え方としては、キャラクターをアニメーションさせたときのように、爆発のエフェクト用画像を切り替えながら連続して表示します。今回は以下の５枚の画像を使って、爆発のエフェクトを実装させてみることにしましょう。画像の大きさは40×40ピクセルです。

画像１画像2画像3画像4画像5
bom01.gif
bom02.gif
bom03.gif
bom04.gif
bom05.gif


これが連続して表示されると、まるで爆発しているように見えます。多分……。


■ユーザーフォームの準備

まずは、前回までに作成しているシューティングゲームに、爆発のエフェクト用画像をロードしましょう。
先ほどの５枚の画像をユーザーフォーム上のイメージコントロールにロードして、名前を変更します。

300.gif

画像をキチンとロードして、名前を変更します。Burst_s1〜Burst_s5までの連番にしておきましょう。はじめから順番に講座を進めてきている方ならわかると思いますが、ここで配置したイメージコントロールは『原画の役割』を担うコントロールです。ですから、エフェクトを表示するときに、このコントロールがそのまま表示されるわけではありません。

実際に画面上でエフェクトとして使われるイメージコントロールは、フレームの中に配置します。

301.gif

ここで配置した３つのイメージコントロールは名前をBurst1〜Burst3としておきます。実際に表示されることになるわけですから、透過処理が行われるように、キチンとBackStyleプロパティや、BorderStyleプロパティを設定しておきましょう。詳しくは過去の講座をご覧ください(Chapter25を参照)。
そして忘れてはならないのが、Visibleプロパティです。
ゲームを開始したときに、始めから爆発用のエフェクトが表示されていてはおかしいですから、必ずVisibleプロパティにはFalseを設定しておきましょう。

ここまでできたら、ユーザーフォームの準備はOKです。次はコードを記述していきます。


■爆発エフェクトの考え方

爆発のエフェクトは、ゲームのキャラクターというわけではありません。あくまでも演出のひとつに過ぎません。ですが、プログラムから見た場合にはキャラクターとの違いはほとんどありません。
例えば『敵キャラクター』は、画面の外から勝手に出てきて、放っておけば勝手に画面外へ消えていきます。爆発エフェクトだって同じです。ショットがヒットしたときに勝手に発生して、一定時間表示されたら勝手に消えます。ですから、敵キャラクターの処理と同じような感じでプログラムを組めば、それで爆発のエフェクトを作成することができます。

爆発エフェクト生成プロシージャをつくる
    ▼
爆発エフェクトの管理プロシージャがアニメーションさせる
    ▼
一定のコマ数アニメーションしたら消す

こんな流れでやればいいわけですね。

それではまず、爆発エフェクト用に、構造体と変数を準備します。
構造体の要素は、キャラクター用の構造体とかぶっている部分もありますが、先々を考えて一応別のものを用意しておきます。

'■汎用オブジェクト　構造体宣言
Type Obj
    X As Single '横位置
    Y As Single '縦位置
    W As Single '横幅
    H As Single '縦幅
    Par As Long 'パラメータ
End Type

'●汎用オブジェクト　変数宣言
Public Burst_Data(2) As Obj

爆発のエフェクトは同時にいくつも発生する可能性があります。そこで先ほどもフレーム内に３つのイメージコントロールを配置したわけです。同じように、爆発エフェクト用の配列変数も、『Burst_Data(2)』としておき、要素数が３つになるようにしておきます。

さらに、キャラクターなどと同じように定数を使って爆発エフェクトの大きさを先に定義しておきます。

Public Const Burst_Size As Single = 15

爆発エフェクトの元となる画像は、40×40ピクセルでしたね。ということは、ユーザーフォーム上に配置されているイメージコントロールの大きさは、30×30ポイントになります。これはポイントとピクセルという単位の違いから発生する大きさの差でしたね。
コードの中で扱いやすくするために30ポイントをあらかじめ半分にしておき、それを定数化したのが、このBurst_Sizeという定数になります。
画面上にエフェクトを配置する段階になると、この定数が非常に役に立ちます。あとで使いますので、定数の宣言だけはしっかりやっておいてくださいね。


■エフェクト生成、管理まで

それでは早速『爆発エフェクト生成プロシージャ』を作りましょう。
敵キャラクターやショットのときと同じように、エフェクトを生成する座標は、引数として受け取るようにしておきます。
こうすることで、どの場所でショットがヒットしても、任意の場所にエフェクトを生成することができるようになるからですね。

Sub Burst_Begin(X As Single, Y As Single)

    Dim L As Long
    
    For L = 0 To 2
        With Burst_Data(L)
            If .Par = 0 Then
                .X = X
                .Y = Y
                .W = Burst_Size
                .H = Burst_Size
                .Par = 1
                UserForm1.Controls("Burst" & L + 1).Visible = True
                Exit For
            End If
        End With
    Next
    
End Sub

ここまで順番に進めてきていれば、この内容は問題ないと思います。
やっていることは至極単純です。

爆発用のエフェクトの数だけ繰り返し処理しますので、まずはFor文での繰り返し処理から始まります。そしてまず、要素Par(パラメータ)の値を調べます。このパラメータという要素は、爆発のエフェクトが今現在どのような状態かを表しています。

要素Parの値とエフェクトの関係
    Par = 0　……　エフェクトは非表示
    Par = 1　……　1枚目の画像を表示中
    Par = 2　……　2枚目の画像を表示中
    Par = 3　……　以下同様に続く

最初に要素Parの値を調べて、０だったときだけその先に進みます。それ以外の場合は、既に表示されているということになるからです。

要素Parが０だったときは、引数として受け取った要素を、変数に格納していきます。ここで、先ほど定義した定数Burst_Sizeが出てきていますね。
さらに、ここで要素Parに１を代入しておきます。これで、非表示から表示中に切り替わるわけですね。
そして、ひとつの爆発エフェクトを生成したら、Exit Forで繰り返し処理を抜けておきます。こうしておかないと、非表示のエフェクトが全て一度に生成されてしまいますから変なことになっちゃいます。

さて、ここまではついてこれていますか？
次は、上のプロシージャで生成した爆発エフェクトを、管理するためのプロシージャを作りましょう。

Sub Burst_Action()

    Dim L As Long
    Dim Pict As Long '��
    
    For L = 0 To 2
        With Burst_Data(L)
            If .Par > 0 Then
                Select Case .Par '��
                    Case 1
                        Pict = 1
                    Case 2, 3
                        Pict = 2
                    Case 4, 5
                        Pict = 3
                    Case 6, 7
                        Pict = 4
                    Case 8
                        Pict = 5
                    Case 9
                        .Par = -1
                End Select
                .Par = .Par + 1 '��
                With UserForm1.Controls("Burst" & L + 1)
                    If Burst_Data(L).Par > 0 Then '��
                        .Left = Burst_Data(L).X - Burst_Size
                        .Top = Burst_Data(L).Y - Burst_Size
                        .Picture = UserForm1.Controls("Burst_s" & Pict).Picture
                    Else
                        .Visible = False
                    End If
                End With
            End If
        End With
    Next
                
End Sub

少し長いですが、ひとつひとつ見ていきましょう。

まずは�，任后�
今回はここで宣言している変数Pictが重要な役割を果たします。PictはPictureを短くしただけです。要するに、いまどの画像を表示するかをこの変数が管理します。

繰り返し処理で、表示されているエフェクト全てを処理していきます。
まずはIf文を使って要素Parの値を調べます。０よりも大きい(１以上)なら、エフェクトが表示されているということなので、その先の処理に進みます。
そして、�△納┐垢茲Δ法⇒彖�Parの現在の値に応じて、Select Case文で処理を分岐させます。

ここで、要素Parの値によって、最初に宣言した変数Pictに代入する数値を変化させます。ここで変数Pictに１を代入しているなら、最終的には１枚目のエフェクト画像が使われます。３を代入しているなら３枚目の画像が使われますね。
もしも、要素Parが９だった場合には、今度はエフェクトを消してしまうようにしますので、直接Parに『 -1 』を代入してしまいます。

Select Case文での分岐処理が完了したら、要素Parの値をプラス１します。これをやっておかないと、エフェクトがアニメーションされません。要素Parの値の応じて表示される画像を切り替えているので、ループするごとに毎回プラス１するわけですね。これが��です。

そして次に�ぁ�
ここではユーザーフォーム上のイメージコントロールの処理をしています。先ほどまではあくまでもデータ上での処理でしたが、ここで実際にコントロールの画像の切り替えなどをしているわけです。


■まとめ、全コード掲載

さて、前回までに作成しているコードに、上記のコードを追加します。
ただし、緑文字で表示されている部分をよく見てもらえればわかりますが、変数の初期化なども追加されていますので、注意してくださいね。

'標準モジュール先頭部分

'◆API　宣言
Declare Function GetTickCount Lib "kernel32" () As Long
Declare Function GetAsyncKeyState Lib "user32" (ByVal vKey As Long) As Integer
Declare Sub Sleep Lib "kernel32.dll" (ByVal dwMillsecounds As Long)

'■キャラクター　構造体宣言
Type Chara
    X As Single
    Y As Single
    W As Single
    H As Single
    Lif As Long
    Typ As Long
    Par As Long
End Type

'■ショット　構造体宣言
Type Shot
    X As Single
    Y As Single
    Vis As Boolean
    Typ As Long
End Type

'■汎用オブジェクト　構造体宣言
Type Obj
    X As Single
    Y As Single
    W As Single
    H As Single
    Par As Long
End Type

'●キャラクター　変数宣言
Public Player_Data As Chara
Public Enemy_Data(9) As Chara

'●ショット　変数宣言
Public P_Shot_Data(4) As Shot
Public E_Shot_Data(9) As Shot

'●汎用オブジェクト　変数宣言
Public Burst_Data(2) As Obj

'◎その他　変数宣言
Public Shot_Interval As Long
Public Total_Count As Long 'ゲーム中のカウンタ

'▲定数宣言
Public Const Left_Key As Long = 37 'カーソル左
Public Const Up_Key As Long = 38 'カーソル上
Public Const Right_Key As Long = 39 'カーソル右
Public Const Down_Key As Long = 40 'カーソル下
Public Const Esc_Key As Long = 27 'Ｅｓｃキー
Public Const Shot_Key As Long = 90 'Ｚキー
Public Const Player_Size As Single = 9
'プレイヤーキャラクターの実際の大きさ
Public Const Shot_Size As Single = 3
'弾各種の実際の大きさ
Public Const Enemy_Size As Single = 9
'敵キャラクターの実際の大きさ
Public Const Burst_Size As Single = 15
'爆発エフェクトの実際の大きさ


'初期化を担当するプロシージャ

Sub Init()
    With Player_Data
        .X = 100
        .Y = 180
        .W = 3
        .H = 3
        .Lif = 1
        .Typ = 0
        .Par = 0
    End With
    Erase P_Shot_Data
    Erase E_Shot_Data
    Erase Enemy_Data
    Erase Burst_Data
    Shot_Interval = 0
    Total_Count = 0
End Sub

'メインプロセスを担当するプロシージャ

Sub Main()

    Dim Flg As Boolean
    Dim Stm As Long
    
    Call Init
    
    Flg = False
    
    Do Until Flg
        Stm = GetTickCount
        Total_Count = Total_Count + 1
        Call Stage_Count
        Call Player_Action
        Call P_Shot_Action
        Call Enemy_Action
        Call E_Shot_Action
        Call Burst_Action
        DoEvents
        Do
            Call Sleep(1)
        Loop Until GetTickCount - Stm > 30
        If GetAsyncKeyState(Esc_Key) < 0 Then Flg = True
    Loop
    
End Sub


'敵キャラクターの出現管理プロシージャ

Sub Stage_Count()
    Randomize
    Select Case Total_Count Mod 200
        Case 0
            Call Enemy_Begin(Int(Rnd * 120) + 40, -10, 1)
        Case 50
            Call Enemy_Begin(Int(Rnd * 120) + 40, -10, 2)
        Case 100
            Call Enemy_Begin(Int(Rnd * 120) + 40, -10, 3)
    End Select
End Sub


'プレイヤーキャラクターを担当するプロシージャ

Sub Player_Action()

    With Player_Data

        'キー入力判定と移動処理　
        If GetAsyncKeyState(Left_Key) < 0 Then .X = .X - 3
        If GetAsyncKeyState(Up_Key) < 0 Then .Y = .Y - 3
        If GetAsyncKeyState(Right_Key) < 0 Then .X = .X + 3
        If GetAsyncKeyState(Down_Key) < 0 Then .Y = .Y + 3

        'はみだし防止処理　
        If .X - Player_Size < 0 Then .X = Player_Size
        If .X + Player_Size > 200 Then .X = 200 - Player_Size
        If .Y - Player_Size < 0 Then .Y = Player_Size
        If .Y + Player_Size > 200 Then .Y = 200 - Player_Size

        'ショット生成
        If Shot_Interval = 0 Then
            If GetAsyncKeyState(Shot_Key) < 0 Then
                Call P_Shot_Begin(.X, .Y, 0)
                Shot_Interval = 1
            End If
        Else
            Shot_Interval = Shot_Interval + 1
            If Shot_Interval > 7 Then Shot_Interval = 0
        End If

    End With

    'フォーム上の『Player』を実際に移動する処理　
    With UserForm1.Player
        .Left = Player_Data.X - Player_Size
        .Top = Player_Data.Y - Player_Size
    End With

End Sub


'ショット生成プロシージャ

Sub P_Shot_Begin(X As Single, Y As Single, Typ As Long)

    Dim L As Long

    For L = 0 To 4
        With P_Shot_Data(L)
            If Not .Vis Then
                .X = X
                .Y = Y
                .Typ = Typ
                .Vis = True
                UserForm1.Controls("P_Shot" & L + 1).Visible = True
                Exit For
            End If
        End With
    Next

End Sub


'ショット移動管理プロシージャ

Sub P_Shot_Action()

    Dim L As Long
    Dim LL As Long

    For L = 0 To 4
        With P_Shot_Data(L)
            If .Vis Then
                .Y = .Y - 6
                If .Y < -5 Then .Vis = False
                For LL = 0 To 9
                    If Enemy_Data(LL).Lif > 0 Then
                        If .X - 2 < Enemy_Data(LL).X + Enemy_Data(LL).W Then
                            If .X + 2 > Enemy_Data(LL).X - Enemy_Data(LL).W Then
                                If .Y - 2 < Enemy_Data(LL).Y + Enemy_Data(LL).H Then
                                    If .Y + 2 > Enemy_Data(LL).Y - Enemy_Data(LL).H Then
                                        .Vis = False
                                        With Enemy_Data(LL)
                                            Call Burst_Begin(.X, .Y)
                                            .Lif = 0
                                        End With
                                        Exit For
                                    End If
                                End If
                            End If
                        End If
                    End If
                Next
                With UserForm1.Controls("P_Shot" & L + 1)
                    If P_Shot_Data(L).Vis Then
                        .Left = P_Shot_Data(L).X - Shot_Size
                        .Top = P_Shot_Data(L).Y - Shot_Size
                    Else
                        .Visible = False
                    End If
                End With
            End If
        End With
    Next

End Sub


'敵キャラクター生成プロシージャ

Sub Enemy_Begin(X As Single, Y As Single, Typ As Long)

    Dim L As Long
    
    For L = 0 To 9
        With Enemy_Data(L)
            If .Lif = 0 Then
                .X = X
                .Y = Y
                .W = 5
                .H = 5
                .Typ = Typ
                .Lif = 1
                .Par = 0
                With UserForm1.Controls("Enemy" & L + 1)
                    .Visible = True
                    Select Case Typ
                        Case 1
                            .Picture = UserForm1.Enemy_s1.Picture
                        Case 2, 3
                            .Picture = UserForm1.Enemy_s2.Picture
                    End Select
                End With
                Exit For
            End If
        End With
    Next
    
End Sub


'敵キャラクターを担当するプロシージャ

Sub Enemy_Action()

    Dim L As Long
    Dim TCMOD
    
    TCMOD = Total_Count Mod 30
    
    For L = 0 To 9
        With Enemy_Data(L)
            If .Lif > 0 Then
                Select Case .Typ
                    Case 1
                        .Y = .Y + 1.5
                    Case 2
                        .X = .X + 0.5
                        .Y = .Y + 1
                    Case 3
                        .X = .X - 0.5
                        .Y = .Y + 1
                End Select
                If .X > 220 Then .Lif = 0
                If .Y > 220 Then .Lif = 0
                If .X < -20 Then .Lif = 0
                If .Y < -20 Then .Lif = 0
                If TCMOD = 0 Then
                    Select Case .Typ
                        Case 2
                            .Typ = 3
                        Case 3
                            .Typ = 2
                    End Select
                    Call E_Shot_Begin(.X, .Y + 2, .Typ)
                End If
            End If
        End With
        With UserForm1.Controls("Enemy" & L + 1)
            If Enemy_Data(L).Lif > 0 Then
                .Left = Enemy_Data(L).X - Enemy_Size
                .Top = Enemy_Data(L).Y - Enemy_Size
            Else
                .Visible = False
            End If
        End With
    Next
    
End Sub


'敵キャラクターショット生成プロシージャ

Sub E_Shot_Begin(X As Single, Y As Single, Typ As Long)
    
    Dim L As Long
    
    For L = 0 To 9
        With E_Shot_Data(L)
            If Not .Vis Then
                .X = X
                .Y = Y
                .Typ = Typ
                .Vis = True
                With UserForm1.Controls("E_Shot" & L + 1)
                    .Visible = True
                End With
                Exit For
            End If
        End With
    Next
    
End Sub


'敵キャラクターショット移動管理プロシージャ

Sub E_Shot_Action()

    Dim L As Long
    Dim LL As Long
    
    For L = 0 To 9
        With E_Shot_Data(L)
            If .Vis Then
                Select Case .Typ
                    Case 1
                        .Y = .Y + 4.5
                    Case 2
                        .X = .X + 0.5
                        .Y = .Y + 3.5
                    Case 3
                        .X = .X - 0.5
                        .Y = .Y + 3.5
                End Select
                If .X > 205 Then .Vis = 0
                If .Y > 205 Then .Vis = 0
                If .X < -5 Then .Vis = 0
                If .Y < -5 Then .Vis = 0
                If .X - 2 < Player_Data.X + Player_Data.W Then
                    If .X + 2 > Player_Data.X - Player_Data.W Then
                        If .Y - 2 < Player_Data.Y + Player_Data.H Then
                            If .Y + 2 > Player_Data.Y - Player_Data.H Then
                                .Vis = False
                                With Player_Data
                                    Call Burst_Begin(.X, .Y)
                                    .Lif = 0
                                End With
                            End If
                        End If
                    End If
                End If
                With UserForm1.Controls("E_Shot" & L + 1)
                    If E_Shot_Data(L).Vis Then
                        .Left = E_Shot_Data(L).X - Shot_Size
                        .Top = E_Shot_Data(L).Y - Shot_Size
                    Else
                        .Visible = False
                    End If
                End With
            End If
        End With
    Next
                
End Sub


'爆発エフェクト生成プロシージャ

Sub Burst_Begin(X As Single, Y As Single)

    Dim L As Long
    
    For L = 0 To 2
        With Burst_Data(L)
            If .Par = 0 Then
                .X = X
                .Y = Y
                .W = Burst_Size
                .H = Burst_Size
                .Par = 1
                UserForm1.Controls("Burst" & L + 1).Visible = True
                Exit For
            End If
        End With
    Next
    
End Sub


'爆発エフェクト管理プロシージャ

Sub Burst_Action()

    Dim L As Long
    Dim Pict As Long
    
    For L = 0 To 2
        With Burst_Data(L)
            If .Par > 0 Then
                Select Case .Par
                    Case 1
                        Pict = 1
                    Case 2, 3
                        Pict = 2
                    Case 4, 5
                        Pict = 3
                    Case 6, 7
                        Pict = 4
                    Case 8
                        Pict = 5
                    Case 9
                        .Par = -1
                End Select
                .Par = .Par + 1
                With UserForm1.Controls("Burst" & L + 1)
                    If Burst_Data(L).Par > 0 Then
                        .Left = Burst_Data(L).X - Burst_Size
                        .Top = Burst_Data(L).Y - Burst_Size
                        .Picture = UserForm1.Controls("Burst_s" & Pict).Picture
                    Else
                        .Visible = False
                    End If
                End With
            End If
        End With
    Next
                
End Sub


'標準モジュールはここまで
'ここから下はフォームモジュールに記述


'コマンドボタンのクリックイベント

Private Sub Com_Start_Click()
    Com_Start.Enabled = False
    Call Main
    Unload UserForm1
End Sub


'ユーザーフォームのクエリクロースイベント

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    End
End Sub


'ユーザーフォームのイニシャライズイベント
Private Sub UserForm_Initialize()
    UserForm1.Width = 220
End Sub

さて、今回のポイントとなるのは、黄色い文字で表示されている部分です。

今回作成した爆発エフェクトの生成プロシージャを、衝突判定の中から呼び出すようにします。
前回までは、プレイヤーキャラクターがショットに被弾したときにはメッセージを表示していました。今回は爆発のエフェクトを生成するように変更したので、敵のショットに当たってしまうと、そこに爆発のエフェクトが発生するようになったはずです。
敵キャラクターにプレイヤーのショットがヒットした場合も同様です。敵が死んだときに、そこに爆発のエフェクトが発生します。

これで、かなりリアルになったのではないでしょうか。
演出の大切さがわかると思います。

大切なのは、エフェクトであっても、その考え方はキャラクターと同じという点です。
キャラクターであれ、ショットであれ、また、エフェクトであっても、プロシージャを部品化して『生成』と『移動や管理』を別々に処理することには変わりありません。

こうして部品化された構造になっていれば、うまくいかなかったときに、どこが原因かわかりやすいです。だんだん全体の構造が複雑になってきてはいますが、細かく区切って考えればそれほど難しくはありません。考え方も似ていますしね。

諦めずに、がんばってみてください。


サンプルダウンロード　⇒　コチラよりダウンロードできます。（別館）


■格言

エフェクトもキャラクターも中身はほとんど同じ
パラメータをうまく使ってアニメーションさせる

かっこいいエフェクトを実装させましょう。
FC2ブックマークに追加





Comment

Name
E-mail
URL
Comment
Pass  *
Secret？ （管理者にだけ表示）

プログラミング関連検索



プログラミングや ExcelVBA に関連した検索にはこちらをどうぞ。

メールフォーム

影斬に物申すという方はこちら

名前　:
メール:
件名　:
本文　:

可能な限り要望には応えますが、必ず返信や回答ができることを、保障するものではありません。
ご了承ください。

Ｃｈａｐｔｅｒｓ

コンテンツ一覧


■Chapter 一覧■
    全てのChapterの一覧です。
    直接アクセスしたい方はこちらをご利用下さい。

    Ｃｈａｐｔｅｒ.１ [ 知っておくべき心得 ]
    Ｃｈａｐｔｅｒ.２ [ Ｅｘｃｅｌってなんだろう ]
    Ｃｈａｐｔｅｒ.３ [ Ｅｘｃｅｌの基本画面 ]
    Ｃｈａｐｔｅｒ.４ [ ＶＢＡとは？ ]
    Ｃｈａｐｔｅｒ.５ [ モジュールについて ]
    Ｃｈａｐｔｅｒ.６ [ 変数 ]
    Ｃｈａｐｔｅｒ.７ [ 変数の型と宣言 ]
    Ｃｈａｐｔｅｒ.８ [ プロシージャとスコープ ]
    Ｃｈａｐｔｅｒ.９ [ ゲームつくる様々な手法 ]
    Ｃｈａｐｔｅｒ.１０ [ ユーザーフォーム ]
    Ｃｈａｐｔｅｒ.１１ [ プロパティウィンドウ ]
    Ｃｈａｐｔｅｒ.１２ [ 乱数 ]
    Ｃｈａｐｔｅｒ.１３ [ 条件分岐 ]
    Ｃｈａｐｔｅｒ.１４ [ ゲーム画面のデザイン ]
    Ｃｈａｐｔｅｒ.１５ [ コード記述の基本作法 ]
    Ｃｈａｐｔｅｒ.１６ [ じゃんけんゲーム：１ 名前をつける ]
    Ｃｈａｐｔｅｒ.１７ [ じゃんけんゲーム：２ フォームの起動 ]
    Ｃｈａｐｔｅｒ.１８ [ じゃんけんゲーム：３ 乱数の種 ]
    Ｃｈａｐｔｅｒ.１９ [ じゃんけんゲーム：４ イベント ]
    Ｃｈａｐｔｅｒ.２０ [ じゃんけんゲーム：５ 引数 ]
    Ｃｈａｐｔｅｒ.２１ [ じゃんけんゲーム：６ 役判定 ]
    Ｃｈａｐｔｅｒ.２２ [ じゃんけんゲーム：７ 予測と制限 ]
    Ｃｈａｐｔｅｒ.２３ [ Withステートメント ]
    Ｃｈａｐｔｅｒ.２４ [ 画像を表示させる ]
    Ｃｈａｐｔｅｒ.２５ [ 画像表示の発展形 ]
    Ｃｈａｐｔｅｒ.２６ [ 繰り返し処理 For文 ]
    Ｃｈａｐｔｅｒ.２７ [ 繰り返し処理 Do〜Loop文 ]
    Ｃｈａｐｔｅｒ.２８ [ Exitステートメント ]
    Ｃｈａｐｔｅｒ.２９ [ フォーム上の位置情報 ]
    Ｃｈａｐｔｅｒ.３０ [ API基礎知識 ]
    Ｃｈａｐｔｅｒ.３１ [ API補足知識 ]
    Ｃｈａｐｔｅｒ.３２ [ メインループを考える ]
    Ｃｈａｐｔｅｒ.３３ [ 同期処理の概念 ]
    Ｃｈａｐｔｅｒ.３４ [ 移動処理その１：画面設定と考え方 ]
    Ｃｈａｐｔｅｒ.３５ [ 移動処理その２：DoEvents ]
    Ｃｈａｐｔｅｒ.３６ [ 移動処理その３：キー入力判定API ]
    Ｃｈａｐｔｅｒ.３７ [ 条件分岐のさらなる探求 Select Case ]
    Ｃｈａｐｔｅｒ.３８ [ アニメーション ]
    Ｃｈａｐｔｅｒ.３９ [ 配列変数 ]
    Ｃｈａｐｔｅｒ.４０ [ ゲームの初期化 ]
    Ｃｈａｐｔｅｒ.４１ [ シューティングゲーム１：ゲーム設計 ]
    Ｃｈａｐｔｅｒ.４２ [ シューティングゲーム２：メインプロセス ]
    Ｃｈａｐｔｅｒ.４３ [ シューティングゲーム３：構造体 ]
    Ｃｈａｐｔｅｒ.４４ [ シューティングゲーム４：定数 ]
    Ｃｈａｐｔｅｒ.４５ [ シューティングゲーム５：プレイヤーキャラクター ]
    Ｃｈａｐｔｅｒ.４６ [ シューティングゲーム６：ショットを撃つ�� ]
    Ｃｈａｐｔｅｒ.４７ [ シューティングゲーム７：ショットを撃つ�� ]
    Ｃｈａｐｔｅｒ.４８ [ シューティングゲーム８：Mod演算子の活用 ]
    Ｃｈａｐｔｅｒ.４９ [ シューティングゲーム９：敵キャラクター登場 ]
    Ｃｈａｐｔｅｒ.５０ [ シューティングゲーム１０：衝突判定 ]
    Ｃｈａｐｔｅｒ.５１ [ シューティングゲーム１１：衝突の実体 ]
    Ｃｈａｐｔｅｒ.５２ [ シューティングゲーム１２：敵の攻撃 ]
    Ｃｈａｐｔｅｒ.５３ [ シューティングゲーム１３：爆発エフェクト ]
    Ｃｈａｐｔｅｒ.５４ [ シューティングゲーム１４：残機数表示�� ]
    Ｃｈａｐｔｅｒ.５５ [ シューティングゲーム１５：残機数表示�� ]
    Ｃｈａｐｔｅｒ.５６ [ シューティングゲーム１６：スコアの表示 ]
    Ｃｈａｐｔｅｒ.５７ [ シューティングゲーム１７：タイトル画面 ]
    Ｃｈａｐｔｅｒ.５８ [ シューティングゲーム１８：ボスキャラクター ]
    Ｃｈａｐｔｅｒ.５９ [ シューティングゲーム１９：最後の仕上げへ ]
    Ｃｈａｐｔｅｒ.６０ [ シューティングゲーム２０：いよいよ完成STG ]
    Ｃｈａｐｔｅｒ.６１ [ カードゲームで使えるめくり効果 ]
    Ｃｈａｐｔｅｒ.６２ [ ラジアンと角度 ]
    Ｃｈａｐｔｅｒ.６３ [ ラジアンの活用：円運動 ]
    Ｃｈａｐｔｅｒ.６４ [ ラジアンの活用：任意の角度へ移動する ]
    Ｃｈａｐｔｅｒ.６５ [ APIによるサウンド再生：基礎 ]
    Ｃｈａｐｔｅｒ.６６ [ APIによるサウンド再生：MIDIと多重再生 ]
    Ｃｈａｐｔｅｒ.６７ [ APIによるサウンド再生：MCIコマンドとループ再生 ]
    Ｃｈａｐｔｅｒ.６８ [ Function プロシージャ ]
    Ｃｈａｐｔｅｒ.６９ [ 値渡しと参照渡し ]
    Ｃｈａｐｔｅｒ.７０ [ デバッグ１：イミディエイトウィンドウ ]
    Ｃｈａｐｔｅｒ.７１ [ デバッグ２：ローカルウィンドウ ]
    Ｃｈａｐｔｅｒ.７２ [ デバッグ３：コード実行の中断 ]
    Ｃｈａｐｔｅｒ.７３ [ オブジェクトってなんだ ]
    Ｃｈａｐｔｅｒ.７４ [ プロパティ・メソッド・イベント ]
    Ｃｈａｐｔｅｒ.７５ [ オブジェクト変数 ]
    Ｃｈａｐｔｅｒ.７６ [ オブジェクトとコレクション ]
    Ｃｈａｐｔｅｒ.７７ [ 特殊な繰り返し：For Each ]
    Ｃｈａｐｔｅｒ.７８ [ エラー処理 ]
    Ｃｈａｐｔｅｒ.７９ [ On Error と GoTo文 ]
    Ｃｈａｐｔｅｒ.８０ [ Resumeステートメント ]
    Ｃｈａｐｔｅｒ.８１ [ バイトとビット ]
    Ｃｈａｐｔｅｒ.８２ [ ウィンドウメッセージとイベント ]
    Ｃｈａｐｔｅｒ.８３ [ 文字列の基礎 ]
    Ｃｈａｐｔｅｒ.８４ [ 文字列操作�� ]
    Ｃｈａｐｔｅｒ.８５ [ 文字列操作�� ]
    Ｃｈａｐｔｅｒ.８６ [ タイピングゲーム１：仕様を決める ]
    Ｃｈａｐｔｅｒ.８７ [ タイピングゲーム２：キー入力検知 ]
    Ｃｈａｐｔｅｒ.８８ [ タイピングゲーム３：文字列照合 ]
    Ｃｈａｐｔｅｒ.８９ [ タイピングゲーム４：判定関数 ]


    コードやVBAに関する質問などはサポート掲示板（別館）までお気軽にどうぞ。




fc2 seotool Excel VBA ゲーム プログラミング 講座

RSSフィード

リンク

このブログをリンクに追加する

By FC2ブログ

今すぐブログを作ろう！

Powered By FC2ブログ

Counter

DigitalClock

プロフィール

Author:
影斬
Ｅｘｃｅｌをこよなく愛するひと。
２〜３年ほど前から、ＥｘｃｅｌＶＢＡによるゲームプログラミングに目覚める。
得意な開発分野はタイピングゲーム(自称)。

最近の記事

最近のコメント

最近のトラックバック

Ｓｈａｄｏｗ ＢＢＳ - 影掲示板

  • ブログランキング
    ranking
    △ランキング参加中
    もしよかったら押してやってください。

    • ITブログランキング

    IT関連のブログ専用ランキングです。 良かったらをクリックお願いします。

    edita


    edita.jp【エディタ】


    From Omoituki

    Sozaiyasan blog