ExcelVBAゲームプログラミング?

初心者でもきっとできる!
Excelさえ持っていれば特別なソフトは不要!
すぐにでも始められる簡単ゲームプログラミング!
今すぐ始めよう!

サンプルやゲームのダウンロードができる別館も好評運営中です。
ご意見やご質問、ゲームの感想等は掲示板までお気軽に。是非、皆さんの声を聞かせてください。運営、開発の励みになります。



各種ダウンロードはコチラ ↓ 意見・感想・質問はコチラ ↓
影倉庫 Shadow warehouse サポート掲示板
ブログの全体像はコチラ ↓ リンクのページはコチラ ↓
サイトマップ 自分本位なリンク


スポンサーサイト

上記の広告は1ヶ月以上更新のないブログに表示されています。
新しい記事を書く事で広告が消せます。






Chapter.101 [ クリックゲーム6:キャラクター移動とNot演算子 ]

■動かしてみる

前回はキャラクターの配置ということで、ハエを画面上に配置する部分を解説しました。今回は配置したキャラクター(ハエ)を動かす部分を実装しましょう。

前回のキャラクターの配置のところでも触れましたが、今回のクリックゲームで登場するハエには4種類あります。上から登場するハエ、下から登場するハエ、そして同様に左からと右からの合計4種類です。このハエの種類を管理しているのが、ハエを管理する構造体変数の要素 Type です。

Type BUG
    X    As Single
    Y    As Single
    W    As Single
    H    As Single
    Type As Long
    Pict As Boolean
    Life As Boolean
End Type

構造体の中身はこんなふうになっていましたね。この中の要素 Type が、上下左右のどの方向から登場するかという、ハエのタイプを管理しています。

ハエを動かす処理では、このタイプに応じてきちんと処理しなければなりません。上から登場したハエが、そのまま上に向かって移動してしまっては意味がありません。ずーっと画面上に現れないことになってしまいますものね。
上から登場したなら下に向かって移動、下から登場したなら上に向かって移動、という具合に適切に処理が行われるようにしましょう。


■前回のコードを振り返る

さて、前回のキャラクターの配置を行っているプロシージャを、一部抜粋してみます。

LL = Int(Rnd * 4) '①
Select Case LL
    Case 0
        sX = Rnd * 250 + 25
        sY = -18
    Case 1
        sX = Rnd * 250 + 25
        sY = 218
    Case 2
        sX = -18
        sY = Rnd * 150 + 25
    Case 3
        sX = 318
        sY = Rnd * 150 + 25
End Select
.X = sX
.Y = sY
.Type = LL
.Pict = False
.Life = True

これは、キャラクターの配置を行っている部分のコードですが、ここで注目すべきなのは、変数 LL の働きです。

①の部分で、乱数を使って4種類の数値をランダムに取得していますね。そして、そこで得られた数値をもとに、Select Case で分岐処理しているのがわかります。このときの変数 LL がズバリ、キャラクターのタイプですね。

もし、タイプ 0 なら、配置される Y 座標が『 -18 』となっていますね。Y 座標というのは一般的に縦の座標を表します。ですから、タイプ 0 は上から登場するタイプであるということがわかりますね。
同様に、タイプ 1 は配置される Y 座標が『 218 』となっています。つまり、タイプ 1 は下から登場するタイプであるということがわかります。

同様に考えると、タイプ 2 は左から、タイプ 3 は右から登場するタイプであることがわかります。これをしっかりと把握した上で、キャラクターの移動処理を記述していきましょう。


■キャラクターの移動処理

さて、それでは実際にキャラクターを移動する処理を見てみましょう。

ここでポイントとなるのは、先ほどのタイプの判別をしっかりと行いながら処理することです。

Sub Flys_Move()

    Dim L As Long
    Dim Move_Point As Single
    
    Randomize
    
    Move_Point = (Level + 1) * 0.2 '①ハエの移動量を算出
    
    For L = 0 To 9
        With Fly(L)
            If .Life Then
                Select Case .Type
                    Case 0
                        .Y = .Y + Move_Point
                        If .Y > 218 Then '②一定の距離に達していたら……
                            Away = Away + 1 '③逃げたハエの数をカウント
                            .Life = False
                        End If
                    Case 1
                        .Y = .Y - Move_Point
                        If .Y < -18 Then
                            Away = Away + 1
                            .Life = False
                        End If
                    Case 2
                        .X = .X + Move_Point
                        If .X > 318 Then
                            Away = Away + 1
                            .Life = False
                        End If
                    Case 3
                        .X = .X - Move_Point
                        If .X < -18 Then
                            Away = Away + 1
                            .Life = False
                        End If
                End Select
                .Pict = Not .Pict '④画像の切り替えを行うために反転する
                With UserForm1.Controls("Ima_fly" & L)
                    .Left = Fly(L).X - Fly(L).W / 2
                    .Top = Fly(L).Y - Fly(L).H / 2
                    If Fly(L).Pict Then '⑤画像の切り替えを行う
                        .Picture = UserForm1.Ima_fly_pic1.Picture
                    Else
                        .Picture = UserForm1.Ima_fly_pic2.Picture
                    End If
                End With
            End If
        End With
    Next
    
End Sub

まずは①の部分。ここでは、レベルを元にしてキャラクターの移動量を算出しています。ハエの出現率と同様、移動するスピードもレベルが上がるほど速くなるようにするためです。

その後、タイプに応じて適切に移動させるように処理を記述していきます。
そして、②の部分で示すように、一定の距離に達した場合という条件を設けます。これは、今回のクリックゲームの仕様を思い出してみればよくわかりますね。
今回のクリックゲームでは、ハエを画面外に10匹逃がしてしまうとゲームオーバーです。ですから、画面の外にまで達してしまった場合はその数をカウントするようにしておくわけです。

もし、画面の外まで達してしまった場合には、③の部分に処理が移ります。ここでは、逃げたハエの数を管理する変数である Away をプラス 1 しています。あとあとこの数値をチェックして、ゲームオーバーになっていないかどうかを判定することになります。

さぁ続いては④の部分。
この部分は、一見して意味のわからない人もいるのではないでしょうか。④の部分には次のように書かれています。

.Pict = Not .Pict

Not を使って何かの処理を行っていますね。

Not は演算子です。そして意味としては『否定』となります。
④の部分で登場している .Pict Boolean 型の変数です。つまり True False のいずれかを保持している変数ですね。先ほどの④の部分が実行されると、もともと True だった場合には False が変数 .Pict に入ります。もともとが False だった場合には True が変数 .Pict に入ります。
つまり真偽が反転するようになるわけです。

最後にユーザーフォーム上のイメージコントロールに対して処理しますが、移動処理が完了したあと、⑤で示すように、画像を切り替える処理が入っています。こうしておくことで、ゲーム中に登場するハエが、まるで羽ばたいているように見せることができます。2枚の画像を交互に表示することで、あたかも飛んでいるように見えるわけですね。

補足コラム:Not演算子
VBAでは、様々なところで真偽の判定を行う場面が出てきます。
例えば皆さんも使い慣れているであろう If 文も真偽を判定して処理するステートメントですし、Boolean型の変数はそのものズバリ、保持できる値が真偽値です(TrueかFalse)。
例えば、次の式は真偽値で言うと、TrueでしょうかそれともFalseでしょうか。
10 = 10
簡単ですね。10と10は全く同じものですから、これは完全にTrueです。それでは、次のような処理を実行した場合にはどうなるでしょうか。メッセージボックスは表示されると思いますか?
Dim L As Long
L = 10
If L = 10 Then
    MsgBox "変数 L は 10 です"
End If
これは実行するとメッセージが出るはずですね。変数 L には 10 が入っていますから当たり前です。では次のような場合はどうなるでしょう。
Dim L As Long
L = 10
If Not L = 10 Then
    MsgBox "変数 L は 10 以外です"
End If
この場合はメッセージは表示されないはずです。なぜなら、Not演算子が使われているからですね。Not演算子は真偽値を否定するので、TrueだったものがFalseになり、FalseだったものがTrueになります。上記のコードでは『 L = 10 』の部分がTrueなので、Not演算子の効果によって最終的にはFalseになってしまっているわけです。ですからメッセージは表示されません。もし、一番最初に変数 L に値を代入している部分を 10 以外の数値に変えてしまった場合には、メッセージが表示されるようになるでしょう。
ちょっとややこしいですが、慣れてしまえば意外と簡単です。便利なケースも多いですから余裕のある人は是非覚えておきましょう。



■まとめ

少し横道に逸れましたが、どうでしょう、理解できたでしょうか。

今回の講座は、実はそれほど難しいことはしていません。キャラクターのタイプを適切に判断しながら処理すれば大丈夫です。当講座で何度も扱ってきた技術ばかりなので、最初の頃から地道に読み進めてきている人なら、何も問題なくいけると思います。

ただ、Not 演算子については今回初めて登場した概念です。しかも、ややこしくてわかりにくいと思います。
イコールを使って何かの比較を行う際や、If 文を使って判定を行う際など、VBA は常に True False かを内部的に判断しながら処理しています。そのことをイメージしてみると意外とわかりやすいと思います。最後に簡単な例を載せておきますので、参考にしてみてください。次の①と②は全く同じ意味です。これがわかれば、Not 演算子については理解できたと言っても過言ではないですよ。


If True Then


If Not False Then



■格言

タイプ別に適切に処理する
Not演算子を有効に活用する



ちなみに私は Not 演算子を使いまくります。
まぁ、わかりやすいように書ければ、無理に使う必要は無いですけどね。


関連記事






Comment

Name
E-mail
URL
Comment
Pass  *
Secret? (管理者にだけ表示)

メールフォーム

影斬に物申すという方はこちら

名前 :
メール:
件名 :
本文 :

可能な限り要望には応えますが、必ず返信や回答ができることを、保障するものではありません。
ご了承ください。

Chapters

コンテンツ一覧


■Chapter 一覧■
    全てのChapterの一覧です。
    直接アクセスしたい方はこちらをご利用下さい。

    Chapter.1 [ 知っておくべき心得 ]
    Chapter.2 [ Excelってなんだろう ]
    Chapter.3 [ Excelの基本画面 ]
    Chapter.4 [ VBAとは? ]
    Chapter.5 [ モジュールについて ]
    Chapter.6 [ 変数 ]
    Chapter.7 [ 変数の型と宣言 ]
    Chapter.8 [ プロシージャとスコープ ]
    Chapter.9 [ ゲームつくる様々な手法 ]
    Chapter.10 [ ユーザーフォーム ]
    Chapter.11 [ プロパティウィンドウ ]
    Chapter.12 [ 乱数 ]
    Chapter.13 [ 条件分岐 ]
    Chapter.14 [ ゲーム画面のデザイン ]
    Chapter.15 [ コード記述の基本作法 ]
    Chapter.16 [ じゃんけんゲーム:1 名前をつける ]
    Chapter.17 [ じゃんけんゲーム:2 フォームの起動 ]
    Chapter.18 [ じゃんけんゲーム:3 乱数の種 ]
    Chapter.19 [ じゃんけんゲーム:4 イベント ]
    Chapter.20 [ じゃんけんゲーム:5 引数 ]
    Chapter.21 [ じゃんけんゲーム:6 役判定 ]
    Chapter.22 [ じゃんけんゲーム:7 予測と制限 ]
    Chapter.23 [ Withステートメント ]
    Chapter.24 [ 画像を表示させる ]
    Chapter.25 [ 画像表示の発展形 ]
    Chapter.26 [ 繰り返し処理 For文 ]
    Chapter.27 [ 繰り返し処理 Do~Loop文 ]
    Chapter.28 [ Exitステートメント ]
    Chapter.29 [ フォーム上の位置情報 ]
    Chapter.30 [ API基礎知識 ]
    Chapter.31 [ API補足知識 ]
    Chapter.32 [ メインループを考える ]
    Chapter.33 [ 同期処理の概念 ]
    Chapter.34 [ 移動処理その1:画面設定と考え方 ]
    Chapter.35 [ 移動処理その2:DoEvents ]
    Chapter.36 [ 移動処理その3:キー入力判定API ]
    Chapter.37 [ 条件分岐のさらなる探求 Select Case ]
    Chapter.38 [ アニメーション ]
    Chapter.39 [ 配列変数 ]
    Chapter.40 [ ゲームの初期化 ]
    Chapter.41 [ シューティングゲーム1:ゲーム設計 ]
    Chapter.42 [ シューティングゲーム2:メインプロセス ]
    Chapter.43 [ シューティングゲーム3:構造体 ]
    Chapter.44 [ シューティングゲーム4:定数 ]
    Chapter.45 [ シューティングゲーム5:プレイヤーキャラクター ]
    Chapter.46 [ シューティングゲーム6:ショットを撃つ① ]
    Chapter.47 [ シューティングゲーム7:ショットを撃つ② ]
    Chapter.48 [ シューティングゲーム8:Mod演算子の活用 ]
    Chapter.49 [ シューティングゲーム9:敵キャラクター登場 ]
    Chapter.50 [ シューティングゲーム10:衝突判定 ]
    Chapter.51 [ シューティングゲーム11:衝突の実体 ]
    Chapter.52 [ シューティングゲーム12:敵の攻撃 ]
    Chapter.53 [ シューティングゲーム13:爆発エフェクト ]
    Chapter.54 [ シューティングゲーム14:残機数表示① ]
    Chapter.55 [ シューティングゲーム15:残機数表示② ]
    Chapter.56 [ シューティングゲーム16:スコアの表示 ]
    Chapter.57 [ シューティングゲーム17:タイトル画面 ]
    Chapter.58 [ シューティングゲーム18:ボスキャラクター ]
    Chapter.59 [ シューティングゲーム19:最後の仕上げへ ]
    Chapter.60 [ シューティングゲーム20:いよいよ完成STG ]
    Chapter.61 [ カードゲームで使えるめくり効果 ]
    Chapter.62 [ ラジアンと角度 ]
    Chapter.63 [ ラジアンの活用:円運動 ]
    Chapter.64 [ ラジアンの活用:任意の角度へ移動する ]
    Chapter.65 [ APIによるサウンド再生:基礎 ]
    Chapter.66 [ APIによるサウンド再生:MIDIと多重再生 ]
    Chapter.67 [ APIによるサウンド再生:MCIコマンドとループ再生 ]
    Chapter.68 [ Function プロシージャ ]
    Chapter.69 [ 値渡しと参照渡し ]
    Chapter.70 [ デバッグ1:イミディエイトウィンドウ ]
    Chapter.71 [ デバッグ2:ローカルウィンドウ ]
    Chapter.72 [ デバッグ3:コード実行の中断 ]
    Chapter.73 [ オブジェクトってなんだ ]
    Chapter.74 [ プロパティ・メソッド・イベント ]
    Chapter.75 [ オブジェクト変数 ]
    Chapter.76 [ オブジェクトとコレクション ]
    Chapter.77 [ 特殊な繰り返し:For Each ]
    Chapter.78 [ エラー処理 ]
    Chapter.79 [ On Error と GoTo文 ]
    Chapter.80 [ Resumeステートメント ]
    Chapter.81 [ バイトとビット ]
    Chapter.82 [ ウィンドウメッセージとイベント ]
    Chapter.83 [ 文字列の基礎 ]
    Chapter.84 [ 文字列操作① ]
    Chapter.85 [ 文字列操作② ]
    Chapter.86 [ タイピングゲーム1:仕様を決める ]
    Chapter.87 [ タイピングゲーム2:キー入力検知 ]
    Chapter.88 [ タイピングゲーム3:文字列照合 ]
    Chapter.89 [ タイピングゲーム4:判定関数 ]
    Chapter.90 [ タイピングゲーム5:ゲーム画面設計 ]
    Chapter.91 [ タイピングゲーム6:問題文のソート ]
    Chapter.92 [ タイピングゲーム7:動的配列 ]
    Chapter.93 [ タイピングゲーム8:キーダウンイベント ]
    Chapter.94 [ タイピングゲーム9:正打数の表示 ]
    Chapter.95 [ タイピングゲーム10:タイムの表示 ]
    Chapter.96 [ クリックゲーム1:イベントの種類 ]
    Chapter.97 [ クリックゲーム2:画面設計 ]
    Chapter.98 [ クリックゲーム3:クリック座標検知 ]
    Chapter.99 [ クリックゲーム4:キャラクター準備 ]
    Chapter.100 [ クリックゲーム5:キャラクターの配置 ]
    Chapter.101 [ クリックゲーム6:キャラクター移動とNot演算子 ]
    Chapter.102 [ クリックゲーム7:クリックのヒット判定 ]
    Chapter.103 [ クリックゲーム8:ヒットマークエフェクト ]
    Chapter.104 [ クリックゲーム9:サウンド処理の実装 ]
    Chapter.105 [ クリックゲーム10:マウスカーソルの変更 ]
    Chapter.106 [ ブロック崩しゲーム1:仕様と概要を決める ]
    Chapter.107 [ ブロック崩しゲーム2:基本概念の確認 ]
    Chapter.108 [ ブロック崩しゲーム3:ベクトルとは ]
    Chapter.109 [ ブロック崩しゲーム4:変数や定数の宣言 ]
    Chapter.110 [ ブロック崩しゲーム5:初期化処理の実装 ]
    Chapter.111 [ ブロック崩しゲーム6:ブロックの配置 ]
    Chapter.112 [ ブロック崩しゲーム7:根幹処理とバーの処理 ]
    Chapter.113 [ ブロック崩しゲーム8:線分と線分の交差を判定 ]
    Chapter.114 [ ブロック崩しゲーム9:線分同士の交点 ]
    Chapter.115 [ ブロック崩しゲーム10:ボールの処理 ]
    Chapter.116 [ ブロック崩しゲーム11:最終調整して完成へ ]
    Chapter.117 [ テキストファイル操作基礎 ]
    Chapter.118 [ テキストファイル操作:読み込み編 ]
    Chapter.119 [ テキストファイル操作:CSV読み込み編 ]
    Chapter.120 [ テキストファイル操作:様々な読込編 ]
    Chapter.121 [ テキストファイル操作:バイナリ編 ]
    Chapter.122 [ テキストファイル操作:暗号化編 ]
    Chapter.123 [ テキストファイル操作:復号化編 ]
    Chapter.124 [ クラスモジュールとは ]
    Chapter.125 [ クラスモジュール:メソッド編 ]
    Chapter.126 [ クラスモジュール:プロパティ編 ]
    Chapter.127 [ クラスモジュール:イベント拡張編 ]
    Chapter.128 [ クラスモジュール:イベント自作編 ]
    Chapter.129 [ APIによる描画処理1:ハンドル ]
    Chapter.130 [ APIによる描画処理2:デバイスコンテキスト ]
    Chapter.131 [ APIによる描画処理3:ペン オブジェクト ]
    Chapter.132 [ APIによる描画処理4:ブラシ オブジェクト ]
    Chapter.133 [ APIによる描画処理5:図形描画準備編 ]
    Chapter.134 [ APIによる描画処理6:図形描画実践編 ]
    Chapter.135 [ APIによる描画処理7:画像描画の仕組み編 ]
    Chapter.136 [ APIによる描画処理8:ビットブロック転送編 ]
    Chapter.137 [ APIによる描画処理9:ラスタオペレーション ]
    Chapter.138 [ APIによる描画処理10:マスク描画 概念編 ]
    Chapter.139 [ APIによる描画処理11:マスク描画 実践編 ]


    コードやVBAに関する質問などはサポート掲示板(別館)までお気軽にどうぞ。




fc2 seotool Excel VBA ゲーム プログラミング 講座

Counter

twitter


Shadow BBS - 影掲示板

VBA 関連書籍



上記広告は1ヶ月以上更新のないブログに表示されています。新しい記事を書くことで広告を消せます。