ExcelVBAゲームプログラミング?

初心者でもきっとできる!
Excelさえ持っていれば特別なソフトは不要!
すぐにでも始められる簡単ゲームプログラミング!
今すぐ始めよう!

サンプルやゲームのダウンロードができる別館も好評運営中です。
ご意見やご質問、ゲームの感想等は掲示板までお気軽に。是非、皆さんの声を聞かせてください。運営、開発の励みになります。



各種ダウンロードはコチラ ↓ 意見・感想・質問はコチラ ↓
影倉庫 Shadow warehouse サポート掲示板
ブログの全体像はコチラ ↓ リンクのページはコチラ ↓
サイトマップ 自分本位なリンク


スポンサーサイト

上記の広告は1ヶ月以上更新のないブログに表示されています。
新しい記事を書く事で広告が消せます。






Chapter.112 [ ブロック崩しゲーム7:根幹処理とバーの処理 ]

■ベースとなる処理

前回は、ワークシートに作成したブロック配置図からデータを読み込む方法を解説しました。これにより、ステージを設計したり、あるいはそれを修正したりするのが簡単になりました。あとあとバージョンアップなどを行う際にも、こういった汎用的なプロシージャがひとつあると、なにかと楽になります。

さて、今回はブロック崩しゲームの根幹となる、メインループなどを作成していきましょう。今まで取り扱ってきたゲームでもそうでしたが、このメインループはゲームを開始したあと常に動き続けます。そして、メインループを通してあらゆる処理が呼び出され、結果的にひとつのゲームとして全ての処理が繋がっていきます。

今回のブロック崩しでは、メインループ内で次のような処理を呼び出します。

・ボールの移動などを行う処理
・バーの移動などを行う処理
・ブロックが全部消えているかどうかチェックする処理
・ボールを落としてしまっていないかチェックする処理

大まかにわけて、よっつの処理がメインループから呼び出されるわけですね。

今回は、メインループの雛形をまず作ります。
雛形が完成したら、バーの移動を行う処理まで盛り込んでみることにしましょう。


■メインループの構造

講座内でなんども使っているメインループですが、今回は以下のような感じになります。

Sub main()

    Dim F As Boolean
    Dim Time_Count As Long
    
    Do Until F
    
        Time_Count = GetTickCount 'ループ開始時の時間を取得
        
        If Ball.Vis Then 'ボールが表示されているときは
            'バーの移動処理
            'ボールの移動処理
            'クリアしているかチェックする処理
        Else 'ボールが表示されていない
            'ゲームオーバー処理
        End If
        
        DoEvents 'OS に制御を戻す
        
        Do
            Sleep 1 'スレッドを休憩させる
        Loop Until GetTickCount - Time_Count > 20 '最低20ミリ秒待つ
        
        If GetAsyncKeyState(27) Then F = True 'ESCキーで停止できるようにしておく
        
    Loop
    
End Sub

このプロシージャがメインループの役割を担います。
宣言されている変数は2種類ありますね。変数 F はメインループを抜けるかどうかを判断するのに使います。この変数に True が入ると、それを合図にループが止まるようになっています。

また、変数 Time_Count は、同期処理を行うために使う変数です。ループが始まった直後に GetTickCount で時間を取得しておき、一定の時間が経過するまでは Sleep を含んだループを空回しする、これにより、CPU に負荷をかけずに時間が調節できます。

もし、このような同期処理を行わないと、ゲームの進行が速くなりすぎて、なにがなんだかわからなくなりますので注意しましょう。

肝心のメインループの中身は、今はまだコメントだけが記述されていますね。
ここには、今後作成していくボールやバーの処理が入ってきます。それぞれの処理が完成したら、ここから呼び出していくようになります。


■バーの移動処理

今回は引き続き、バーの移動処理を実装してみましょう。
バーの処理では、ユーザーのキー入力を検知して処理していきます。 GetAsyncKeyState を使ってキーの状態を調べ、それに応じて処理していけばいいのですね。

早速、コードを見てみましょう。

Sub Bar_Move()

    Dim S As Single
    
    With Bar
        If GetAsyncKeyState(37) Then .X = .X - 7.5 ' ← キー
        S = W_Bar / 2 '①
        If .X < S Then .X = S
        If GetAsyncKeyState(39) Then .X = .X + 7.5 ' → キー
        S = W_Field - W_Bar / 2 '②
        If .X > S Then .X = S
    End With
    
    With UserForm1
        .Ima_bar.Left = Bar.X - W_Bar / 2
    End With
    
End Sub

GetAsyncKeyState は、引数にキーを表す数値を指定して呼び出すことで、現在のキー入力の状態を調べることができる API です。

矢印キーの状態を調べて、その結果に応じてバーを動かしているわけです。
若干わかりにくいのは、キーの入力を検知したあとの計算を行っている部分だと思います。ここはじっくり見ていきましょう。

①の部分は、左の矢印キーが押されていた場合の処理ですね。
ここでは、汎用変数である変数 S に、バーの横幅の半分を入れています。なぜこんなことをするのか、わかるでしょうか。
実はこれは、バーが左側の壁にめり込んでいくことを防止するための処理です。ポイントは、バーを管理する構造体である変数 Bar の各要素の役割をよく理解しておくことです。

バーを管理する構造体変数 Bar は、X と Y というふたつの要素を持っています。この X と Y は、バーの横位置と縦位置を管理するための要素ですね。X が横位置、Y が縦位置です。
そして、この要素 X と Y は、バーの中心部分の座標を管理するための要素です。図で表すと次のような感じですね。

640.gif

これを踏まえて考えると、左側の壁に目いっぱい寄せたときの X の座標は、バーの横幅のちょうど半分になるということがわかりますね。先ほどのように汎用変数 S にバーの幅の半分を入れておき、それをもとに現在の座標をチェックするようにすれば、バーが壁にめり込んでしまっているのかどうかを調べることができるわけです。

①の場合は、このようにして左側の壁と、バーの現在位置を比較しているのです。もし、バーが壁にめり込んでいるような座標にある場合は、これをその都度修正してやればバーは壁にめり込まないようにすることができます。

②の場合にも、①の場合とほとんど同じように処理しています。右側の壁に、バーがめり込んでしまっていないか調べながら処理しています。②ではフィールドの幅とバーの幅をうまく組み合わせて処理しています。ちょっと複雑に見えるかもしれませんが、落ち着いて考えてみてください。


■まとめ

バーの移動処理が完成したので、これをメインループから呼び出すようにしておきます。

Sub main()

    Dim F As Boolean
    Dim Time_Count As Long
    
    Do Until F
    
        Time_Count = GetTickCount 'ループ開始時の時間を取得
        
        If Ball.Vis Then 'ボールが表示されているときは
            Bar_Move 'バーの移動処理
            'ボールの移動処理
            'クリアしているかチェックする処理
        Else 'ボールが表示されていない
            'ゲームオーバー処理
        End If
        
        DoEvents 'OS に制御を戻す
        
        Do
            Sleep 1 'スレッドを休憩させる
        Loop Until GetTickCount - Time_Count > 20 '最低20ミリ秒待つ
        
        If GetAsyncKeyState(27) Then F = True 'ESCキーで停止できるようにしておく
        
    Loop
    
End Sub

これで、メインループからバーの移動処理が呼び出されるようになったので、キチンとゲームにメインループを実装させれば、バーがキーの入力に応じて移動するようになります。

前回の講座では、まだメインループができていなかったので、このメインループ自体が実装されていませんでした。ユーザーフォーム上に配置した、スタートボタンの役割を担うコマンドボタンがありましたね。このコマンドボタンのクリックイベントから、メインループが呼び出されるようにしておきましょう。

以前、このコマンドボタンを配置したときには、特に名前の変更などを行っていませんでした。今回はこれの名前もしっかり変更しておきます。スタートボタンの役割をするコマンドボタンですので、ここでは名前を Com_start としています。

Private Sub Com_start_Click()

    Com_start.Enabled = False
    
    Init
    
    Init_Block 1
    
    main
    
    Com_start.Enabled = True
    
End Sub

これでメインループの実装はOKです。

ここまで全て完了すれば、ユーザーフォームを起動して、バーが実際にキチンと動くかどうかテストしてみることができます。ユーザーフォームを起動して、コマンドボタンを押します。その後、矢印キーを押したときにバーが反応して移動するようになっていれば成功ですね。

今回もサンプルを用意してあります。
実際に動作するところを確認しながら、それを参考にがんばってみてください。



サンプルダウンロード ⇒ コチラよりダウンロードできます。(別館)



■格言

同期処理をしっかり実装する
構造体の要素の意味を考えて処理


バーが動くようになっただけでも、ぐっとゲームらしくなるから不思議ですね。


スポンサーサイト






Chapter.113 [ ブロック崩しゲーム8:線分と線分の交差を判定 ]

■衝突判定なのに交差判定?

以前に講座内でも書いたのですが、今回のブロック崩しでは、ボールとブロックなどとの間に発生する衝突を、線と線での交差判定によって判断します。

ブロックとボールの衝突を判定するのに、どうして線と線での判定を行うのか、わかるでしょうか。

ボールが進む軌道は必ず直線です。そして、ブロックの一辺も、直線ですよね。
このふたつの直線が交差しているかどうかを判定できれば、即ちそれは衝突を判定していることと同義になるのがわかると思います。

衝突判定というと、普通はシューティングゲームなどと同じ判定の方法を考えると思います。この方法の場合は、矩形と矩形に重なりがあるかどうかを判定して、それで衝突しているかどうかを判断しますね。

271.gif

ただ、この方法には実は弱点があります。
それは、一方が高速に動いている場合に、正しく衝突判定ができないことがあるということです。

考えてみてください。ブロック崩しの場合は、ブロックは動いていませんが、ボールは常に動いていますよね。ボールの速度がゆっくりの場合には、ブロックと重なる瞬間が必ず発生するので、衝突を判定することができるでしょう。しかし、ボールが高速で移動している場合はどうでしょうか。

ボールが一度に 1 ずつくらいしか移動しないのであれば、厚みが 5 あるブロックの上を全く重ならずにすり抜けることはできません。しかし、ボールが一度に 6 とか 7 とか移動できる場合には、ブロックの上に全く重なることなくすり抜けてしまう可能性が出てきます。こんなときは、重なりを判定するだけの衝突判定では、ボールとブロックの衝突は判断できないのです。

650.gif

また、矩形での衝突判定では、ボールを扱うのになにかと不便な点が出てきます。
例えば、次の図形を見るとわかりますが、ボールは実際にはブロックに触れていなくても、衝突したことになってしまう場面というのが出てきてしまいます。

651.gif

線と線で衝突を判定すると、上に書いたような問題点が全て解決できます。
たとえ、ボールが高速に移動していても、線と線での交差判定では関係ありませんし、実際にはボールが届いていないのに衝突したことになってしまうような不具合も起こりません。

プログラムは少し複雑で難しくなりますが、確実な衝突判定を行うのであれば、線と線での交差を判定する方法を用いたほうが、正しく衝突を判定できるのですね。


■線と線分

それでは、実際に線と線での衝突判定について考えてみることにします。

まず、始めに書いておきますが、数学では『 線 』と『 線分 』は異なるものです。線というのは、ある 2 点を通る直線のことを言います。始めと終わりはなく、線の長さは原則として無限大と解釈します。

652.gif

対して、線分というのは始点と終点を持つ線のことで、こちらは始まりと終わりが明確になっています。これは図を見ると簡単ですね。

653.gif

さて、ここで重要なのは、線と線の交差を判定するのか、それとも線分と線分の交差を判定するのか、どちらを用いるべきかということです。今回のブロック崩しでは、ボールの軌道とブロックの一辺の交差を判定するわけですから、いずれも線分です。長さが無限の線で交差を判定してしまうと、ボールが触れていないときにも交差が発生してしまいますので、今回は線分と線分による交差を判定することになります。

そして、線分と線分の交差を判定するには、ちょっと数学的な知識が必要になります。これを全て解説しているとすごく長くなってしまいますので、まずはコードを見てみることにします。

Function CrossLine(x1 As Single, y1 As Single, _
                   x2 As Single, y2 As Single, _
                   x3 As Single, y3 As Single, _
                   x4 As Single, y4 As Single) As Boolean

    Dim Deno As Single
    Dim Nume1 As Single
    Dim Nume2 As Single
    Dim F1 As Boolean
    Dim F2 As Boolean
    Dim F3 As Boolean
    
    Deno = (x3 - x1) * (y4 - y1) - (y3 - y1) * (x4 - x1)
    
    If Deno = 0 Then
        F1 = (x3 - x1) * (x4 - x1) + (y3 - y1) * (y4 - y1) <= 0
        F2 = (x3 - x2) * (x4 - x2) + (y3 - y2) * (y4 - y2) <= 0
        F3 = (x1 - x3) * (x2 - x3) + (y1 - y3) * (y2 - y3) <= 0
        CrossLine = F1 Or F2 Or F3
    Else
        Nume1 = (y4 - y1) * (x2 - x1) - (x4 - x1) * (y2 - y1)
        Nume2 = (x3 - x1) * (y2 - y1) - (y3 - y1) * (x2 - x1)
        F1 = ((Nume1 + Nume2) / Deno >= 1)
        If Deno < 0 Then
            F2 = (Nume1 <= 0)
            F3 = (Nume2 <= 0)
        Else
            F2 = (Nume1 >= 0)
            F3 = (Nume2 >= 0)
        End If
        CrossLine = F1 And F2 And F3
    End If
    
End Function

かなり複雑なことになっていますね。
中身がどういった理論で作られているかはともかく、ここではこのプロシージャの使い方をまず覚えてください。

名前のところを見るとわかりますが、このプロシージャは Function プロシージャです。そして引数を 8 つ受け取り、Boolean 型で結果を返してくれることがわかりますね。

8 つある引数は、いずれも X と Y が対になっています。これは、交差を判定する線分の、始点と終点がそれぞれ入るようになっています。

x1, y1 …… ひとつ目の線分の始点
x2, y2 …… ひとつ目の線分の終点
x3, x3 …… ふたつ目の線分の始点
x4, y4 …… ふたつ目の線分の終点

交差を判定したい線分の、それぞれの始点と終点をこの Function プロシージャに渡して処理すると、交差している場合は True を、交差していない場合は False を返してくるわけです。

このプロシージャに、ボールが移動した軌跡の始点と終点、さらにブロックの一辺を線分として考えた場合の始点と終点、この 4 つの情報を与えれば、それで交差判定ができます。

もし、この交差判定が True になるとすれば、ボールとブロックは衝突していることになるわけです。使い方さえわかれば、数学的なことはよくわからなくてもなんとかなります。


■まとめ

さて、線分と線分との交差判定はこれで実装できるようになりました。
数学的な知識が必要となりますので、中身の計算が何をやっているのかはなかなか理解するのが大変かもしれません。ただ、プログラミングにおいては計算の実証よりも、使い方を知ることのほうが大事だと思っています。もちろん、数学的なことをしっかり勉強して、どうしてそのような計算が導き出されるのかを知ることも大事です。ですが、とりあえずは動くようにする、ということがプログラミングを続ける上では大切です。プログラムがうまく動かないとそれがストレスになって、モチベーションが下がってしまいますからね。

端的にいうと、今回のプロシージャはベクトルを使ってふたつの線分の交差を判定しています。各点間のベクトルを元にして、線分と線分が交差しているのかどうか、段階的に処理しています。



■格言

線と線分は違うもの
使い方を理解し、まずは動かしてみることが大切


今回はちょっと難しい内容になってしまいましたね。
紹介した交差判定のプロシージャは、いずれ利用することになります。








メールフォーム

影斬に物申すという方はこちら

名前 :
メール:
件名 :
本文 :

可能な限り要望には応えますが、必ず返信や回答ができることを、保障するものではありません。
ご了承ください。

Chapters

コンテンツ一覧


■Chapter 一覧■
    全てのChapterの一覧です。
    直接アクセスしたい方はこちらをご利用下さい。

    Chapter.1 [ 知っておくべき心得 ]
    Chapter.2 [ Excelってなんだろう ]
    Chapter.3 [ Excelの基本画面 ]
    Chapter.4 [ VBAとは? ]
    Chapter.5 [ モジュールについて ]
    Chapter.6 [ 変数 ]
    Chapter.7 [ 変数の型と宣言 ]
    Chapter.8 [ プロシージャとスコープ ]
    Chapter.9 [ ゲームつくる様々な手法 ]
    Chapter.10 [ ユーザーフォーム ]
    Chapter.11 [ プロパティウィンドウ ]
    Chapter.12 [ 乱数 ]
    Chapter.13 [ 条件分岐 ]
    Chapter.14 [ ゲーム画面のデザイン ]
    Chapter.15 [ コード記述の基本作法 ]
    Chapter.16 [ じゃんけんゲーム:1 名前をつける ]
    Chapter.17 [ じゃんけんゲーム:2 フォームの起動 ]
    Chapter.18 [ じゃんけんゲーム:3 乱数の種 ]
    Chapter.19 [ じゃんけんゲーム:4 イベント ]
    Chapter.20 [ じゃんけんゲーム:5 引数 ]
    Chapter.21 [ じゃんけんゲーム:6 役判定 ]
    Chapter.22 [ じゃんけんゲーム:7 予測と制限 ]
    Chapter.23 [ Withステートメント ]
    Chapter.24 [ 画像を表示させる ]
    Chapter.25 [ 画像表示の発展形 ]
    Chapter.26 [ 繰り返し処理 For文 ]
    Chapter.27 [ 繰り返し処理 Do~Loop文 ]
    Chapter.28 [ Exitステートメント ]
    Chapter.29 [ フォーム上の位置情報 ]
    Chapter.30 [ API基礎知識 ]
    Chapter.31 [ API補足知識 ]
    Chapter.32 [ メインループを考える ]
    Chapter.33 [ 同期処理の概念 ]
    Chapter.34 [ 移動処理その1:画面設定と考え方 ]
    Chapter.35 [ 移動処理その2:DoEvents ]
    Chapter.36 [ 移動処理その3:キー入力判定API ]
    Chapter.37 [ 条件分岐のさらなる探求 Select Case ]
    Chapter.38 [ アニメーション ]
    Chapter.39 [ 配列変数 ]
    Chapter.40 [ ゲームの初期化 ]
    Chapter.41 [ シューティングゲーム1:ゲーム設計 ]
    Chapter.42 [ シューティングゲーム2:メインプロセス ]
    Chapter.43 [ シューティングゲーム3:構造体 ]
    Chapter.44 [ シューティングゲーム4:定数 ]
    Chapter.45 [ シューティングゲーム5:プレイヤーキャラクター ]
    Chapter.46 [ シューティングゲーム6:ショットを撃つ① ]
    Chapter.47 [ シューティングゲーム7:ショットを撃つ② ]
    Chapter.48 [ シューティングゲーム8:Mod演算子の活用 ]
    Chapter.49 [ シューティングゲーム9:敵キャラクター登場 ]
    Chapter.50 [ シューティングゲーム10:衝突判定 ]
    Chapter.51 [ シューティングゲーム11:衝突の実体 ]
    Chapter.52 [ シューティングゲーム12:敵の攻撃 ]
    Chapter.53 [ シューティングゲーム13:爆発エフェクト ]
    Chapter.54 [ シューティングゲーム14:残機数表示① ]
    Chapter.55 [ シューティングゲーム15:残機数表示② ]
    Chapter.56 [ シューティングゲーム16:スコアの表示 ]
    Chapter.57 [ シューティングゲーム17:タイトル画面 ]
    Chapter.58 [ シューティングゲーム18:ボスキャラクター ]
    Chapter.59 [ シューティングゲーム19:最後の仕上げへ ]
    Chapter.60 [ シューティングゲーム20:いよいよ完成STG ]
    Chapter.61 [ カードゲームで使えるめくり効果 ]
    Chapter.62 [ ラジアンと角度 ]
    Chapter.63 [ ラジアンの活用:円運動 ]
    Chapter.64 [ ラジアンの活用:任意の角度へ移動する ]
    Chapter.65 [ APIによるサウンド再生:基礎 ]
    Chapter.66 [ APIによるサウンド再生:MIDIと多重再生 ]
    Chapter.67 [ APIによるサウンド再生:MCIコマンドとループ再生 ]
    Chapter.68 [ Function プロシージャ ]
    Chapter.69 [ 値渡しと参照渡し ]
    Chapter.70 [ デバッグ1:イミディエイトウィンドウ ]
    Chapter.71 [ デバッグ2:ローカルウィンドウ ]
    Chapter.72 [ デバッグ3:コード実行の中断 ]
    Chapter.73 [ オブジェクトってなんだ ]
    Chapter.74 [ プロパティ・メソッド・イベント ]
    Chapter.75 [ オブジェクト変数 ]
    Chapter.76 [ オブジェクトとコレクション ]
    Chapter.77 [ 特殊な繰り返し:For Each ]
    Chapter.78 [ エラー処理 ]
    Chapter.79 [ On Error と GoTo文 ]
    Chapter.80 [ Resumeステートメント ]
    Chapter.81 [ バイトとビット ]
    Chapter.82 [ ウィンドウメッセージとイベント ]
    Chapter.83 [ 文字列の基礎 ]
    Chapter.84 [ 文字列操作① ]
    Chapter.85 [ 文字列操作② ]
    Chapter.86 [ タイピングゲーム1:仕様を決める ]
    Chapter.87 [ タイピングゲーム2:キー入力検知 ]
    Chapter.88 [ タイピングゲーム3:文字列照合 ]
    Chapter.89 [ タイピングゲーム4:判定関数 ]
    Chapter.90 [ タイピングゲーム5:ゲーム画面設計 ]
    Chapter.91 [ タイピングゲーム6:問題文のソート ]
    Chapter.92 [ タイピングゲーム7:動的配列 ]
    Chapter.93 [ タイピングゲーム8:キーダウンイベント ]
    Chapter.94 [ タイピングゲーム9:正打数の表示 ]
    Chapter.95 [ タイピングゲーム10:タイムの表示 ]
    Chapter.96 [ クリックゲーム1:イベントの種類 ]
    Chapter.97 [ クリックゲーム2:画面設計 ]
    Chapter.98 [ クリックゲーム3:クリック座標検知 ]
    Chapter.99 [ クリックゲーム4:キャラクター準備 ]
    Chapter.100 [ クリックゲーム5:キャラクターの配置 ]
    Chapter.101 [ クリックゲーム6:キャラクター移動とNot演算子 ]
    Chapter.102 [ クリックゲーム7:クリックのヒット判定 ]
    Chapter.103 [ クリックゲーム8:ヒットマークエフェクト ]
    Chapter.104 [ クリックゲーム9:サウンド処理の実装 ]
    Chapter.105 [ クリックゲーム10:マウスカーソルの変更 ]
    Chapter.106 [ ブロック崩しゲーム1:仕様と概要を決める ]
    Chapter.107 [ ブロック崩しゲーム2:基本概念の確認 ]
    Chapter.108 [ ブロック崩しゲーム3:ベクトルとは ]
    Chapter.109 [ ブロック崩しゲーム4:変数や定数の宣言 ]
    Chapter.110 [ ブロック崩しゲーム5:初期化処理の実装 ]
    Chapter.111 [ ブロック崩しゲーム6:ブロックの配置 ]
    Chapter.112 [ ブロック崩しゲーム7:根幹処理とバーの処理 ]
    Chapter.113 [ ブロック崩しゲーム8:線分と線分の交差を判定 ]
    Chapter.114 [ ブロック崩しゲーム9:線分同士の交点 ]
    Chapter.115 [ ブロック崩しゲーム10:ボールの処理 ]
    Chapter.116 [ ブロック崩しゲーム11:最終調整して完成へ ]
    Chapter.117 [ テキストファイル操作基礎 ]
    Chapter.118 [ テキストファイル操作:読み込み編 ]
    Chapter.119 [ テキストファイル操作:CSV読み込み編 ]
    Chapter.120 [ テキストファイル操作:様々な読込編 ]
    Chapter.121 [ テキストファイル操作:バイナリ編 ]
    Chapter.122 [ テキストファイル操作:暗号化編 ]
    Chapter.123 [ テキストファイル操作:復号化編 ]
    Chapter.124 [ クラスモジュールとは ]
    Chapter.125 [ クラスモジュール:メソッド編 ]
    Chapter.126 [ クラスモジュール:プロパティ編 ]
    Chapter.127 [ クラスモジュール:イベント拡張編 ]
    Chapter.128 [ クラスモジュール:イベント自作編 ]
    Chapter.129 [ APIによる描画処理1:ハンドル ]
    Chapter.130 [ APIによる描画処理2:デバイスコンテキスト ]
    Chapter.131 [ APIによる描画処理3:ペン オブジェクト ]
    Chapter.132 [ APIによる描画処理4:ブラシ オブジェクト ]
    Chapter.133 [ APIによる描画処理5:図形描画準備編 ]
    Chapter.134 [ APIによる描画処理6:図形描画実践編 ]
    Chapter.135 [ APIによる描画処理7:画像描画の仕組み編 ]
    Chapter.136 [ APIによる描画処理8:ビットブロック転送編 ]
    Chapter.137 [ APIによる描画処理9:ラスタオペレーション ]
    Chapter.138 [ APIによる描画処理10:マスク描画 概念編 ]
    Chapter.139 [ APIによる描画処理11:マスク描画 実践編 ]


    コードやVBAに関する質問などはサポート掲示板(別館)までお気軽にどうぞ。




fc2 seotool Excel VBA ゲーム プログラミング 講座

Counter

twitter


Shadow BBS - 影掲示板

VBA 関連書籍



上記広告は1ヶ月以上更新のないブログに表示されています。新しい記事を書くことで広告を消せます。