ExcelVBAゲームプログラミング?

初心者でもきっとできる!
Excelさえ持っていれば特別なソフトは不要!
すぐにでも始められる簡単ゲームプログラミング!
今すぐ始めよう!

サンプルやゲームのダウンロードができる別館も好評運営中です。
ご意見やご質問、ゲームの感想等は掲示板までお気軽に。是非、皆さんの声を聞かせてください。運営、開発の励みになります。



各種ダウンロードはコチラ ↓ 意見・感想・質問はコチラ ↓
影倉庫 Shadow warehouse サポート掲示板
ブログの全体像はコチラ ↓ リンクのページはコチラ ↓
サイトマップ 自分本位なリンク


スポンサーサイト

上記の広告は1ヶ月以上更新のないブログに表示されています。
新しい記事を書く事で広告が消せます。






Chapter.104 [ クリックゲーム9:サウンド処理の実装 ]

■サウンド処理で演出効果を強化する

前回の講座では、クリックの際にヒットマークが表示されるようにしました。これにより、クリックゲームとしての完成度が随分と上がったように思います。

クリックゲームは、その名の通り、クリックするという行為自体がゲーム最大の面白さです。ハエをクリックした瞬間に、ヒットマークという視覚的な効果があることによって、演出面がとても強化されるわけです。

今回は、ここにサウンド処理を追加して、クリックに聴覚から来る効果を加えます。さらに演出面が強化されること間違い無しです。

ちなみに、サウンド関連の処理に関しては、以前に講座内で何度か取り上げています。今回の講座は、以前の講座の内容と重複する部分がほとんどです。もし、詳しくサウンド関連の処理について知りたい場合は、以前の講座をじっくり読むことをオススメします。




■サウンド処理のおさらい

さて、それではサウンド関連処理のおさらいから始めましょう。

サウンドを再生するのは、VBAの基本機能だけでは残念ながら無理です。サウンドの再生にはAPIを使います。

サウンドを再生する方法にもいろいろありますが、本講座では、mciSendString を使っています。なぜ mciSendString を使うのかといえば理由はみっつあります。

第一に、その性能です。多重再生を行ったり、任意のタイミングでサウンドを一時停止したりと、多彩な機能を持っています。
第二に、扱いやすさです。この mciSendString というAPIは、文字列を用いて命令を送ることができます。そのため、非常に直感的な処理を行うことが可能です。
第三に、奥の深さ。これは初心者にはなかなか難しいのですが、このAPIはとても奥が深くて、その気になればかなりいろいろなことができます。いつかは自在に操れるようになりたいものですね。

さて、ご託はこれくらいにして、実際の処理を見ていきます。

mciSendString はAPIですから、モジュールの先頭部分に、APIの宣言文を記述しておく必要があります。宣言文は次のようになっています。

Declare Function mciSendString Lib "winmm.dll" Alias "mciSendStringA" _
(ByVal lpstrCommand As String, _
 ByVal lpstrReturnString As String, _
 ByVal uReturnLength As Long, _
 ByVal hwndCallback As Long) As Long

これはそのままコピーしてしまえば大丈夫。むしろ、下手に書き換えたりしてしまうとうまくいきませんので、そのままコピーして使いましょう。

mciSendString で扱えるサウンドファイルの形式は、wav、mid(midi)、mp3、などがあります。いずれも、同様の手順で処理することで再生が可能です。
再生には、まずファイルをオープンする必要があります。これには、『 open 』というコマンド文字列を使います。

Sub MCI_Open(FileName As String, AliasName As String)

    Dim P As String
    
    P = """" & ActiveWorkbook.Path & "\" & FileName & """"
    
    Call mciSendString("open " & P & " alias " & AliasName, vbNullString, 0, 0)
    
End Sub

このサブプロシージャは、指定されたファイルを、指定されたエイリアスでオープンするプロシージャです。エイリアスというのは、言うなれば名札のようなもので、開いたファイルを再生するときなどに使います。
例えば、『 WAVE 』というエイリアスでファイルをオープンしたとします。もし、このサウンドを再生したいと思った場合には、開く際に指定した『 WAVE 』というエイリアスを指定して再生すればいいのですね。

ちなみに、上で紹介している MCI_Open というプロシージャは、アクティブなブックの保存されているパスを基点にして処理しています。もし、同じフォルダにサウンドファイルが置かれている場合は、ファイル名だけを指定すれば簡単に開くことができます。

さて、開いたファイルを再生する前に、終了処理について触れておきます。
mciSendString で開いたファイルは、プログラムが終了する前に必ずクローズしなくてはならないというお約束があります。これには『 close 』というコマンド文字列を使います。

Sub MCI_Close(AliasName As String)

    Call mciSendString("close " & AliasName, vbNullString, 0, 0)
    
End Sub

サウンドファイルのクローズを行う際には、ファイル名ではなく、オープンしたときに指定したエイリアスを使います。上記のプロシージャは、エイリアスを文字列型の引数として受け取り、mciSendString を使ってサウンドファイルをクローズします。閉じるのは簡単ですね。

サウンドファイルを閉じることを怠ると、メモリリークを引き起こし深刻なエラーが発生する可能性もあります。必ず、クローズ処理を行うようにしましょうね。


■再生処理を仕込む

さて、それでは実際の再生処理を見てみましょう。
再生には、エイリアスを使います。これは開いたときに指定したエイリアスですね。

Sub MCI_Play(AliasName As String)

    Call mciSendString("play " & AliasName & " from 0", vbNullString, 0, 0)
        
End Sub

コードは比較的すっきりしていますね。事前にファイルをキチンとオープンできていれば、たった1行のコードで再生処理を行うことができます。

サウンドファイルの再生には、『 play 』というコマンド文字列を使います。さらに、『 from 0 』というオプションコマンドを付加することで、サウンドを必ず先頭から再生されるようにしています。

さて、開く、再生する、閉じる、このみっつのステップが理解できれば、自由自在に再生を行うことができます。今回のクリックゲームでは、クリックが発生した場合に、サウンドがなるようにしてみます。

再生に使うサウンドファイルは、私が自作したサウンドファイルである『 hit.wav 』と『 flap.wav 』のふたつです。これを開いて再生するということを想定して、次のコードを見てくださいね。

Private Sub UserForm_Initialize()

    Dim fObj As MSForms.Control
    
    With UserForm1
        .Width = 316.5
        For Each fObj In .Controls
            If Left(fObj.Name, 3) Like "Ima" Then
                fObj.Visible = False
            End If
        Next
    End With
    
    MCI_Open "files\hit.wav", "hit"
    MCI_Open "files\flap.wav", "flap"

    
End Sub

'------------------------------

Private Sub Lab_trans_MouseDown(ByVal Button As Integer, _
                                ByVal Shift As Integer, _
                                ByVal X As Single, _
                                ByVal Y As Single)

    MCI_Play "flap"
    Flys_Hit X, Y
    
End Sub

'------------------------------

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)

    MCI_Close "hit"
    MCI_Close "flap"

    
    End
    
End Sub

前回までの講座内容に、サウンド関連処理を追加しました。ちなみに、上記のコードは全てフォームモジュールに記載される部分です。色が付いている部分が今回追加されたコードになります。

ユーザーフォームの起動( Initialize イベント)と同時にファイルを開き、クリックと同時にサウンドを鳴らしています。そして、ユーザーフォームが閉じる前( QueryClose イベント)にファイルを閉じるようにしていますね。

さらに、標準モジュールのコードにも、一箇所だけ追記します。

Sub Hit_Begin(hX As Single, hY As Single)

    With Hits
        .X = hX
        .Y = hY
        .Var = 0
        .Vis = True
    End With
        
    With UserForm1.Ima_hit
        .Left = Hits.X - Hits.W / 2
        .Top = Hits.Y - Hits.H / 2
        .Visible = True
    End With
    
    MCI_Play "hit"
    
End Sub

これは、ヒットマークを表示するプロシージャである Hit_Begin です。ヒットマークを表示するということは、確実にクリックがハエにヒットしているはずですよね。ですから、ここでサウンドを再生するようにしておけば、結果としてクリックがヒットした瞬間にサウンドが再生されているように感じます。


今回のクリックゲームの場合には、空振りした場合にもサウンドが鳴るようにしてあるので、クリックイベントのほうにもサウンド処理が記述されています。もしクリックがヒットしていた場合には、多重再生でふたつのサウンドがほとんど同時に再生されるわけですね。


■まとめ

さぁ、少し駆け足で見てきましたが、理解できたでしょうか。
サウンド関連の処理について初めて挑戦する場合は、以前の講座で詳しく解説しているので、そちらをきちんと読んでおいたほうがいいです。今回の講座ではある程度簡略化して説明しているので、ちょっとわかりにくい部分もあるかと思います。

基本的な使い方さえわかってしまえば、比較的簡単にサウンド処理は実現できます。難しそうに見えても、じっくり取り組んでいけば必ず実現させることができるはずです。諦めずにがんばってみてくださいね。

さて、サウンド処理も加わり、クリックゲームもいよいよ完成度が高くなってきましたね。次回は最後の仕上げとして、マウスカーソルの変更をやってみます。これが実装できれば、晴れてクリックゲームの完成となります。
今回のサウンド処理を実装させ、完成への準備をしっかり行っておきましょう。


今回もサンプルを用意しました。実際に音が再生される仕組みなどを観察するのに活用してください。



サンプルダウンロード ⇒ コチラよりダウンロードできます。(別館)



■格言

サウンド処理にはAPIを使う
開く、再生する、閉じる、のサイクルを理解して処理する


次回はいよいよクリックゲーム最終回です。もう一息、がんばりましょう。


スポンサーサイト






Chapter.105 [ クリックゲーム10:マウスカーソルの変更 ]

■いよいよ最終段階

クリックゲームの講座も、今回でいよいよ最後となります。
今回の修正を行えば、もう普通に遊べるクリックゲームが出来上がります。ここまで順を追って取り組んできた人も、もうひとふんばり、がんばりましょう。

さて、今回は掲題の通り、マウスカーソルに関する内容を扱ってみたいと思います。

マウスカーソルというと、真っ先に思いつくのは、見慣れた白い矢印ですよね。Windows なら既定では白矢印になっているはずです。
知っている人もいるかと思いますが、マウスカーソルは自由に変更することができます。コントロールパネルから、マウスの項目を開き、ポインタのタブを選択すると、マウスカーソルに関する設定を行うことができます。結構いろいろなマウスカーソルがデフォルトでインストールされていると思います。

580.gif

そして、マウスカーソルは、実態としては画像ファイルみたいなものなので、比較的簡単に自作することができます。インターネット上で検索すれば、フリーソフトでカーソルを作ることができるものも、結構あります。興味があるひとは探してみるといいでしょう。

さて、今回のクリックゲームの話に戻します。
マウスカーソルは Windows の設定で自由に変更することができますが、ユーザーフォームでも同様にカーソルを変更することができます。ユーザーフォームや、ユーザーフォーム上のコントロールの多くには、『 MouseIcon プロパティ 』と、『 MousePointer プロパティ 』が備わっています。これらのふたつのプロパティを変更することによって、マウスカーソルを自由に変更することが可能です。

■MouseIcon プロパティ

マウスカーソルに使用する、カーソルファイル(拡張子は.cur)を指定する。

この MouseIcon プロパティは、独自のマウスカーソルを使いたい場合には必須のプロパティになります。イメージコントロールに画像を表示するときには、 Picture プロパティに画像ファイルをロードしましたよね。あれと同じような感覚で、このプロパティにあらかじめカーソルファイルをロードしておくことで、自分の好きなカーソルを表示させることができます。

ただし、注意しなければならないことがあります。
実は、このプロパティにカーソルファイルをロードしただけでは、実際にはカーソルは変更されません。次に登場する MousePointer プロパティも、併せて変更しておかなくてはいけません。

■MousePointer プロパティ

どのマウスカーソルを使用するのかを指定する。例えば、砂時計やクエスチョンマーク、ウィンドウの大きさを変えるときに出る黒い矢印などは、プロパティの定数値を変更するだけで簡単に変更できる。
独自のカスタムカーソルを適用するには、このプロパティに『 fmMousePointerCustom 』を設定しておく必要がある。

オリジナルのカーソルを使いたい場合には、上記にもあるように、MousePointer プロパティに fmMousePointerCustom を設定しておかなくてはいけません。このような設定を行った場合だけ、MouseIcon プロパティで指定されたカーソルファイルが使われます。どちらか一方だけを設定してもうまくいかないので、注意してくださいね。


このように、マウスカーソルの変更は、全てがプロパティウィンドウからの設定だけで完了できます。簡単ですね。

きちんとカーソルが変更されているかどうかを確認する際には、実際にユーザーフォームを起動して確認するようにしましょう。デザイン画面のなかでは、カーソルが正しく設定されていたとしても、変更された状態で表示されることはありません。


■実際に変更してみる

それでは、実際にマウスカーソルを変更してみます。

今回のクリックゲームでは、以前解説したように、透明ラベルによるクリックの検知を行っています。ユーザーフォームに配置されたフレームの中に、ハエの画像を読み込んだイメージコントロールなどが置かれています。そしてその上にかぶさるようにして、透明なラベルが配置されていたのでしたね。

569.gif

今回は、この透明なラベルである『 Lab_trans 』に対してのみ、マウスカーソルの変更を行います。ユーザーフォーム上の全ての場所でマウスカーソルが変更されていると、逆にコマンドボタンなどをクリックしにくくなります。変更したマウスカーソルの種類にもよりますので一概には言えませんが、実質的なゲーム画面である透明ラベルの部分だけに限定したほうがいいでしょう。

今回のマウスカーソルは、次のようなものを使います。

582.gif

ハエたたきゲームだけに、ハエたたきカーソルです(笑)。
このカーソルは私が自作したものです。

このカーソルを Lab_trans MouseIcon プロパティに設定します。そして、カスタムカーソルを使えるようにするために、MousePonter プロパティも fmMousePointerCustom に変更しておきます。

これで、マウスカーソルの変更は完了です。あとは普通にゲームを起動すると、カーソルが変更されて表示されるはずです。

補足コラム:ホットスポット
マウスカーソルには、ホットスポットと呼ばれる設定があります。ホットスポットをわかりやすく言うと、カーソルのどの位置をクリック座標として認識するか、ということになります。
Windows の規定値では、ホットスポットは常にカーソル画像の左上の角です。通常の白い矢印カーソルなどは、左上にホットスポットが設定されていますよね。
今回のクリックゲームに使っているハエたたきカーソルは、左上にホットスポットがあると、どうにも違和感があります。ハエたたきの網の部分がクリックポイントになっていないとなんか変です。そこで、ホットスポットは網のほぼ中心部分に設定しています。カーソルを自作する際には、ホットスポットの設定にも気を配るようにしましょう。



■ちょっとだけ拡張

さて、めでたくカーソルの変更も完了しましたので、あと少しだけクリックゲームの拡張を行いましょう。

前回までのクリックゲームの仕様では、ハエを何匹駆除したのかや、逃がしてしまったハエが何匹いるのかなどが、情報として一切画面上に出ていません。これを画面上で確認できるようにしておきましょう。

用意するのは、ラベルコントロール。次のような感じで追加しておきましょう。

581.gif

名前などを適宜変更したら、ここに情報が逐一表示されるようにするために、ソースコードを修正します。

今回修正する部分はほんのちょっとしかありません。メインループが組まれている場所に、ラベルのキャプションを変更するコードを仕込んでおきます。たったこれだけです。

Sub Main()

    Dim L As Long
    
    Do
    
        Flys_Begin
        Flys_Move
        Hit_Action
        
        Level = Score \ 10
        
        L = 10 - Away '①
    
        With UserForm1
            .Lab_score.Caption = Format(Score, "000") '②
            .Lab_away.Caption = "あと" & Format(L, "00") & _
                                "匹逃がしたらゲームオーバー" '③
        End With

        
        DoEvents
        Sleep 20
    
    Loop Until Away > 9
    
    MsgBox "ゲームオーバー"
    
End Sub


色の付いているコード部分が、追加した部分です。
今回のクリックゲームの、ゲームオーバーに関するルールとして、10匹逃がしてしまったらゲームオーバーという仕様がありました。そこで、①で示すように、変数 L にあと何匹逃がしたらゲームオーバーとなってしまうのかを取得しています。変数 Away は、逃がしてしまったハエの数なので、10 から Away を引き算すると、あと何匹逃がしたらゲームオーバーなのかがわかるというわけです。

また、変数 Score は、ハエをクリックして駆除した数が入っている変数です。ですから、スコアを表示するためのラベルである Lab_score には、そのまま変数 Score を用いてキャプションを設定します。これが②の部分ですね。

そして③の部分では、①で取得した、あと何匹逃がしたらゲームオーバーか、という情報を使ってラベルのキャプションを設定しています。

修正を加えたのがメインループの中なので、今回修正したラベルに関する処理は、一回のループごとに毎回呼び出されます。ですから、ユーザーフォーム上のラベル表示は常に最新の情報に更新されるようになります。

583.gif


■まとめ

さぁ、いよいよクリックゲームの講座も終わりです。
透明ラベルを用いたクリック座標の検知や、マウスカーソルの変更、サウンド処理など、様々なテクニックが登場しましたね。

クリックというユーザーの動作に対して、ダイレクトに反応するゲームですから、気軽にさくっと遊ぶことができると思います。今のところ、この講座の内容そのままでは、ハエの動きなどに工夫がありません。ただまっすぐ直線的に移動するだけなので、そういった部分を自分なりに改造していくことで、さらに面白いクリックゲームに仕上がると思います。

また、サウンド処理やマウスカーソルの変更など、普段はあまり使うことのないテクニックもありましたね。自分でサウンドファイルやカーソルファイルを自作して、オリジナルなクリックゲームを作ってみるのも、また楽しいと思います。

ただ、一点注意しておいてほしいのですが、残念なことに、ユーザフォーム上でカスタムカーソルを使う場合、どうやっても白黒になってしまいます。通常のときはカラーで表示されているカーソルファイルでも、なぜかユーザーフォームなどに設定すると白黒でしか表示されません。
いろいろ解決策を探したのですが、今のところ、どうにも対処できる方法が無いようです。これは恐らくフォームの仕様なので、どうしようもなさそうです。残念。
ですから、今回のクリックゲームに使用したハエたたきカーソルも、あえて黒一色で作りました。最初はカラフルだったのですが、どっちにしても白黒になってしまうのなら、最初から黒一色に……と思って塗りつぶしちゃいました。

いずれにしても、今回のクリックゲームはかなり簡易なつくりになっています。画像やサウンド、カーソルなどを自作して、オリジナリティ溢れるクリックゲームを作ってみてくださいね。

完成版のサンプルゲームを別館に上げておきます。
参考にしながら、がんばってみてください。



サンプルダウンロード ⇒ コチラよりダウンロードできます。(別館)



■格言

マウスカーソルの変更にはふたつのプロパティを変更
素材を自作してオリジナリティを


クリックゲーム、ついに完成。お疲れ様でした。








「Excel VBA アクションゲーム作成入門」最強のVBA本が登場!

■■■ 最強のExcelVBA指南書 ■■■
!いよいよ発売!


books.jpg

↓ 詳細はコチラから ↓
Excel VBA アクションゲーム作成入門

特設サイトはコチラ >>> VBA本特設サイト

■■■ ただいま絶賛発売中! ■■■

DirectX を使う方法までを網羅した、まさに最強のExcelVBA本がいよいよ発売になります。
私も含めた、5人の精鋭が執筆に参加。ExcelVBAゲームの全てがわかるといっても過言ではない良書に仕上がったと思っています。

みんな買ってね!

ちなみに、本書で紹介されている X_Vader というサンプルゲームは、私のサイト内でダウンロードできます。ExcelVBA から DirectX を呼び出すという荒技が実際に体験できます。
興味のある方は以下のリンクからどうぞ。

>>> X_Vader ダウンロードページ

書籍詳細(Amazon)↓
>>> Excel VBA アクションゲーム作成入門

書籍の特設サイトはこちら
(5人の著者プロフィールなども見れます)↓
>>> VBA本特設サイト








メールフォーム

影斬に物申すという方はこちら

名前 :
メール:
件名 :
本文 :

可能な限り要望には応えますが、必ず返信や回答ができることを、保障するものではありません。
ご了承ください。

Chapters

コンテンツ一覧


■Chapter 一覧■
    全てのChapterの一覧です。
    直接アクセスしたい方はこちらをご利用下さい。

    Chapter.1 [ 知っておくべき心得 ]
    Chapter.2 [ Excelってなんだろう ]
    Chapter.3 [ Excelの基本画面 ]
    Chapter.4 [ VBAとは? ]
    Chapter.5 [ モジュールについて ]
    Chapter.6 [ 変数 ]
    Chapter.7 [ 変数の型と宣言 ]
    Chapter.8 [ プロシージャとスコープ ]
    Chapter.9 [ ゲームつくる様々な手法 ]
    Chapter.10 [ ユーザーフォーム ]
    Chapter.11 [ プロパティウィンドウ ]
    Chapter.12 [ 乱数 ]
    Chapter.13 [ 条件分岐 ]
    Chapter.14 [ ゲーム画面のデザイン ]
    Chapter.15 [ コード記述の基本作法 ]
    Chapter.16 [ じゃんけんゲーム:1 名前をつける ]
    Chapter.17 [ じゃんけんゲーム:2 フォームの起動 ]
    Chapter.18 [ じゃんけんゲーム:3 乱数の種 ]
    Chapter.19 [ じゃんけんゲーム:4 イベント ]
    Chapter.20 [ じゃんけんゲーム:5 引数 ]
    Chapter.21 [ じゃんけんゲーム:6 役判定 ]
    Chapter.22 [ じゃんけんゲーム:7 予測と制限 ]
    Chapter.23 [ Withステートメント ]
    Chapter.24 [ 画像を表示させる ]
    Chapter.25 [ 画像表示の発展形 ]
    Chapter.26 [ 繰り返し処理 For文 ]
    Chapter.27 [ 繰り返し処理 Do~Loop文 ]
    Chapter.28 [ Exitステートメント ]
    Chapter.29 [ フォーム上の位置情報 ]
    Chapter.30 [ API基礎知識 ]
    Chapter.31 [ API補足知識 ]
    Chapter.32 [ メインループを考える ]
    Chapter.33 [ 同期処理の概念 ]
    Chapter.34 [ 移動処理その1:画面設定と考え方 ]
    Chapter.35 [ 移動処理その2:DoEvents ]
    Chapter.36 [ 移動処理その3:キー入力判定API ]
    Chapter.37 [ 条件分岐のさらなる探求 Select Case ]
    Chapter.38 [ アニメーション ]
    Chapter.39 [ 配列変数 ]
    Chapter.40 [ ゲームの初期化 ]
    Chapter.41 [ シューティングゲーム1:ゲーム設計 ]
    Chapter.42 [ シューティングゲーム2:メインプロセス ]
    Chapter.43 [ シューティングゲーム3:構造体 ]
    Chapter.44 [ シューティングゲーム4:定数 ]
    Chapter.45 [ シューティングゲーム5:プレイヤーキャラクター ]
    Chapter.46 [ シューティングゲーム6:ショットを撃つ① ]
    Chapter.47 [ シューティングゲーム7:ショットを撃つ② ]
    Chapter.48 [ シューティングゲーム8:Mod演算子の活用 ]
    Chapter.49 [ シューティングゲーム9:敵キャラクター登場 ]
    Chapter.50 [ シューティングゲーム10:衝突判定 ]
    Chapter.51 [ シューティングゲーム11:衝突の実体 ]
    Chapter.52 [ シューティングゲーム12:敵の攻撃 ]
    Chapter.53 [ シューティングゲーム13:爆発エフェクト ]
    Chapter.54 [ シューティングゲーム14:残機数表示① ]
    Chapter.55 [ シューティングゲーム15:残機数表示② ]
    Chapter.56 [ シューティングゲーム16:スコアの表示 ]
    Chapter.57 [ シューティングゲーム17:タイトル画面 ]
    Chapter.58 [ シューティングゲーム18:ボスキャラクター ]
    Chapter.59 [ シューティングゲーム19:最後の仕上げへ ]
    Chapter.60 [ シューティングゲーム20:いよいよ完成STG ]
    Chapter.61 [ カードゲームで使えるめくり効果 ]
    Chapter.62 [ ラジアンと角度 ]
    Chapter.63 [ ラジアンの活用:円運動 ]
    Chapter.64 [ ラジアンの活用:任意の角度へ移動する ]
    Chapter.65 [ APIによるサウンド再生:基礎 ]
    Chapter.66 [ APIによるサウンド再生:MIDIと多重再生 ]
    Chapter.67 [ APIによるサウンド再生:MCIコマンドとループ再生 ]
    Chapter.68 [ Function プロシージャ ]
    Chapter.69 [ 値渡しと参照渡し ]
    Chapter.70 [ デバッグ1:イミディエイトウィンドウ ]
    Chapter.71 [ デバッグ2:ローカルウィンドウ ]
    Chapter.72 [ デバッグ3:コード実行の中断 ]
    Chapter.73 [ オブジェクトってなんだ ]
    Chapter.74 [ プロパティ・メソッド・イベント ]
    Chapter.75 [ オブジェクト変数 ]
    Chapter.76 [ オブジェクトとコレクション ]
    Chapter.77 [ 特殊な繰り返し:For Each ]
    Chapter.78 [ エラー処理 ]
    Chapter.79 [ On Error と GoTo文 ]
    Chapter.80 [ Resumeステートメント ]
    Chapter.81 [ バイトとビット ]
    Chapter.82 [ ウィンドウメッセージとイベント ]
    Chapter.83 [ 文字列の基礎 ]
    Chapter.84 [ 文字列操作① ]
    Chapter.85 [ 文字列操作② ]
    Chapter.86 [ タイピングゲーム1:仕様を決める ]
    Chapter.87 [ タイピングゲーム2:キー入力検知 ]
    Chapter.88 [ タイピングゲーム3:文字列照合 ]
    Chapter.89 [ タイピングゲーム4:判定関数 ]
    Chapter.90 [ タイピングゲーム5:ゲーム画面設計 ]
    Chapter.91 [ タイピングゲーム6:問題文のソート ]
    Chapter.92 [ タイピングゲーム7:動的配列 ]
    Chapter.93 [ タイピングゲーム8:キーダウンイベント ]
    Chapter.94 [ タイピングゲーム9:正打数の表示 ]
    Chapter.95 [ タイピングゲーム10:タイムの表示 ]
    Chapter.96 [ クリックゲーム1:イベントの種類 ]
    Chapter.97 [ クリックゲーム2:画面設計 ]
    Chapter.98 [ クリックゲーム3:クリック座標検知 ]
    Chapter.99 [ クリックゲーム4:キャラクター準備 ]
    Chapter.100 [ クリックゲーム5:キャラクターの配置 ]
    Chapter.101 [ クリックゲーム6:キャラクター移動とNot演算子 ]
    Chapter.102 [ クリックゲーム7:クリックのヒット判定 ]
    Chapter.103 [ クリックゲーム8:ヒットマークエフェクト ]
    Chapter.104 [ クリックゲーム9:サウンド処理の実装 ]
    Chapter.105 [ クリックゲーム10:マウスカーソルの変更 ]
    Chapter.106 [ ブロック崩しゲーム1:仕様と概要を決める ]
    Chapter.107 [ ブロック崩しゲーム2:基本概念の確認 ]
    Chapter.108 [ ブロック崩しゲーム3:ベクトルとは ]
    Chapter.109 [ ブロック崩しゲーム4:変数や定数の宣言 ]
    Chapter.110 [ ブロック崩しゲーム5:初期化処理の実装 ]
    Chapter.111 [ ブロック崩しゲーム6:ブロックの配置 ]
    Chapter.112 [ ブロック崩しゲーム7:根幹処理とバーの処理 ]
    Chapter.113 [ ブロック崩しゲーム8:線分と線分の交差を判定 ]
    Chapter.114 [ ブロック崩しゲーム9:線分同士の交点 ]
    Chapter.115 [ ブロック崩しゲーム10:ボールの処理 ]
    Chapter.116 [ ブロック崩しゲーム11:最終調整して完成へ ]
    Chapter.117 [ テキストファイル操作基礎 ]
    Chapter.118 [ テキストファイル操作:読み込み編 ]
    Chapter.119 [ テキストファイル操作:CSV読み込み編 ]
    Chapter.120 [ テキストファイル操作:様々な読込編 ]
    Chapter.121 [ テキストファイル操作:バイナリ編 ]
    Chapter.122 [ テキストファイル操作:暗号化編 ]
    Chapter.123 [ テキストファイル操作:復号化編 ]
    Chapter.124 [ クラスモジュールとは ]
    Chapter.125 [ クラスモジュール:メソッド編 ]
    Chapter.126 [ クラスモジュール:プロパティ編 ]
    Chapter.127 [ クラスモジュール:イベント拡張編 ]
    Chapter.128 [ クラスモジュール:イベント自作編 ]
    Chapter.129 [ APIによる描画処理1:ハンドル ]
    Chapter.130 [ APIによる描画処理2:デバイスコンテキスト ]
    Chapter.131 [ APIによる描画処理3:ペン オブジェクト ]
    Chapter.132 [ APIによる描画処理4:ブラシ オブジェクト ]
    Chapter.133 [ APIによる描画処理5:図形描画準備編 ]
    Chapter.134 [ APIによる描画処理6:図形描画実践編 ]
    Chapter.135 [ APIによる描画処理7:画像描画の仕組み編 ]
    Chapter.136 [ APIによる描画処理8:ビットブロック転送編 ]
    Chapter.137 [ APIによる描画処理9:ラスタオペレーション ]
    Chapter.138 [ APIによる描画処理10:マスク描画 概念編 ]
    Chapter.139 [ APIによる描画処理11:マスク描画 実践編 ]


    コードやVBAに関する質問などはサポート掲示板(別館)までお気軽にどうぞ。




fc2 seotool Excel VBA ゲーム プログラミング 講座

Counter

twitter


Shadow BBS - 影掲示板

VBA 関連書籍



上記広告は1ヶ月以上更新のないブログに表示されています。新しい記事を書くことで広告を消せます。