ExcelVBAゲームプログラミング?

初心者でもきっとできる!
Excelさえ持っていれば特別なソフトは不要!
すぐにでも始められる簡単ゲームプログラミング!
今すぐ始めよう!

サンプルやゲームのダウンロードができる別館も好評運営中です。
ご意見やご質問、ゲームの感想等は掲示板までお気軽に。是非、皆さんの声を聞かせてください。運営、開発の励みになります。



各種ダウンロードはコチラ ↓ 意見・感想・質問はコチラ ↓
影倉庫 Shadow warehouse サポート掲示板
ブログの全体像はコチラ ↓ リンクのページはコチラ ↓
サイトマップ 自分本位なリンク


スポンサーサイト

上記の広告は1ヶ月以上更新のないブログに表示されています。
新しい記事を書く事で広告が消せます。






Chapter.91 [ タイピングゲーム6:問題文のソート ]

■実装開始

前回の講座では、ゲームの画面を簡単に設計してみました。

問題文が表示されるラベルを配置して、その上に、透明な複製ラベルをぴたりと合わせることで、どの文字までタイピングできているのかがわかるような、そんな仕組みを実装させましたね。

タイピングゲームは、文字の入力を競ったり楽しんだりするゲームですから、極端な話、文字さえ表示できていれば最低限のことはできます。
ユーザーフォーム上のコントロールは今後適宜追加するとして、今回からは実際にゲームのコードを実装させていきましょう。

文字列とキーの入力が一致しているのかどうか調べるための関数は、以前の講座で既に作成しています。これにより、今回のタイピングゲームの核となる部分は出来あがっていると考えていいでしょう。

となると、今回からはゲームの全体像を意識しながら、ゲームの開始から終了までの、一連のプロセスを作っていくことになります。
難しく考えず、最初から地道に、しっかりとコードを書いていきましょう。


■問題の用意

さて、タイピングゲームにはいろいろな種類のものがありますが、今回のタイピングゲームは英単語を入力させるタイプのゲームにする予定でしたね。

実際にタイプする英単語は、プレイヤーが飽きてしまわないように、できる限りたくさん用意したほうがいいのですが、まずはテスト段階という事もあるので、私が無作為に選んだものを使っていくことにします。

ちなみに、英単語は以下の10種類を使うことにします。

問題文:英単語一覧

EXCEL
VBA
VISUAL
BASIC
APPLICATION
GAME
SHADOW
SLASH
MICROSOFT
OFFICE

さて、この問題文ですが、これはワークシートに記述しておくことにします。

ゲームを作っているExcelファイルの、一番最初のシートに問題文を記入しておきましょう。

520.gif

ゲームの処理の中では、このワークシートに記述された情報を取得して、タイピングゲームの問題文として処理します。問題文は、今回は10種類となっています。ただ、10種類よりも、問題文を増やしたくなることもあるかもしれません。それを踏まえて、問題文の処理についてもう少し見てみます。


■並び替える

さて、問題文を用意したのはいいですが、これをこのままゲームに取り込んでしまったら、問題の順番が毎回同じになってしまいます。これはいくらなんでもまずいですよね。
ゲームをやるたびに、問題文がランダムに並び変わっていないと意味がありません。

そこで、問題文をランダムに並び替える方法から見てみましょう。

まず、ランダムに並び替える、というところから『 Rnd 関数 』が思い浮かびます。しかし、これをどのようにして使えば問題文を並び替えることができるのでしょうか。

考え方としては、問題文のそれぞれに、まず Rnd 関数で生成した乱数をそのまま当て込みます。Rnd 関数は、0 ~ 1 未満の範囲でランダムに数字を返してくる関数です。これをそのまま各問題文に対して割り振っていきます。

Sub Problem_Sort()

    Dim L As Long
    
    Randomize
    
    For L = 1 To 10
        Cells(L, 2).Value = Rnd
    Next
    
End Sub

簡単ですね。

For 文を用いて、セルに順番に乱数をそのまま書き込んでいます。これを実行した結果が次のような画面になっているはずです。

521.gif

さぁ、問題文の隣に乱数を入れたら、次はどうすればいいのか想像がつくでしょうか。

次は、この乱数を元に問題文を並び替えます。Excel を普段からよく使う人なら、Excel に付属している並び替え機能を知っていると思います。もちろん、この並び替え機能はVBAから呼び出して使うことができます。

そこで、先ほど振られた乱数を基本にして、問題文の部分を並び替えてしまいます。このようにすればランダムに振られた乱数の値によって、毎回並び順がランダムに変わるというわけです。

Sub Problem_Sort()

    Dim L As Long
    
    Randomize
    
    For L = 1 To 10
        Cells(L, 2).Value = Rnd
    Next
    
    Range(Columns(1), Columns(2)).Sort key1:=Cells(1, 2), _
                                       order1:=xlAscending

    
End Sub

最後の緑色の文字で表示されている部分が、並び替えを行っている部分です。

Range(Columns(1), Columns(2)) 』という表記は、ちょっと紛らわしいですが、これは『 セルの1列目から2列目まで 』を表しています。そして、並び替えの命令を出しているのが『 Sort key1:=Cells(1, 2), order1:=xlAscending 』の部分です。 

Sort メソッドは、Excel が持っている並び替え機能を呼び出します。そして、並び替えの基準となる列、その並び替えの方法、を指定して使います。
今回の場合、乱数の振られた列を基準に並び替えを行うので、『 key1 』という引数に、2列目にあるセルを指定していますね。
そして、『 order1 』という引数には『 xlAscending 』が指定されていますね。これは、並び替えを『昇順』で行うことを示します。『昇順』の場合には『 1, 2, 3,…… 』という順番ですね。
もし、並び替えの順序を『降順』にしたい場合には『 xlDescending 』を使います。これを指定した場合には『 9, 8, 7,…… 』という順序で並び替えが行われます。

さて、正しく並び替えができると、次のような画面になります。キチンと乱数をもとに並び替えが行われ、問題文もランダムに並んでいますよね。

522.gif


■問題文の数に対応する

さて、問題文をランダムに並び替える方法はわかりましたね。

先ほども書きましたが、今回はあくまでも、問題文が10種類というふうに限定して書いています。これを、問題文が増えても大丈夫な仕様に変更しておきましょう。問題文が10種類しかないというのは少なすぎますので、余裕のあるときに随時追加すればいいようにしておきます。

Sub Problem_Sort()

    Dim L As Long
    Dim LastCell As Long
    
    Randomize
    
    LastCell = Cells(65536, 1).End(xlUp).Row
    
    For L = 1 To LastCell
        Cells(L, 2).Value = Rnd
    Next
    
    Range(Columns(1), Columns(2)).Sort key1:=Cells(1, 2), _
                                     order1:=xlAscending
    
End Sub

さて、色つきになっている部分をよく見てください。

まず、新しくひとつ変数を宣言していますね。プロシージャの開始と同時に、その新しい変数に何かを取得しています。

LastCell = Cells(65536, 1).End(xlUp).Row

ここでは、『 1列目、最下セルの行 』を取得しています。

ワークシートのセルは、Excel2003 までのバージョンでは 65536行までしかありません。『 Cells(65536,1) 』というのは、その一番下のセルを表しています。
そして、そこからさらに『 .End(xlUp).Row 』と続きます。

End プロパティを使うと、セルの領域の終端を取得することができます。
今回の場合は、『 Cells(65536,1) 』から、『 End(xlUp) 』方向に向かって終端セルを検索し、見つかった終端セルの『 Row 』を取得しています。

イメージとしては、ワークシートの一番下のセルから、ずーっと上方向に調べていき、何かが入力されているセルが見つかったら、そこの行数を取得する、という感じです。

問題文は、ワークシートの1列目に書かれています。今は10種類しかありませんから、変数 LastCell には 10 が取得されます。もしも今後、問題文を増強して20種類にした場合には、変数 LastCell には20が取得されます。

このように、どんな問題数でも同じように対応できるようにしておくことで、後から問題文をカスタマイズするのが簡単になりますね。


■まとめ

さて、どうでしたか。結構難しかったですね。

今回の仕様を実装できれば、問題文のランダムな並び替えと、問題文の数が何問でも対応できるという仕組みの両方を、一度に実装できたことになります。

以前から何度も書いていますが、汎用的に、将来性を考えてコードを記述することは非常に大事です。問題文が何個に増えても大丈夫なようにしておけば、問題文を増やすたびにコードの修正を行う必要はなく、効率的に開発作業が行えるはずです。



■格言

乱数を使ってランダム並び替え
Endプロパティで終端セルを取得
将来性を考えた設計を心がける


かなりいい形でまとまってきました。あと少しです。


スポンサーサイト






Chapter.92 [ タイピングゲーム7:動的配列 ]

■ゲームの骨組みを作る

タイピングゲームの作成も、そろそろ核心に迫りつつあります。

文字列の照合、ゲーム画面、問題文のソート、ここまでは前回までで完成しています。今回からはゲームの骨格を実際に作っていきます。
まずは、ゲームに使う変数や、それらの変数の初期化からはじめましょう。


まず、今回のタイピングゲームで使う、グローバル変数などの準備をしましょう。グローバル変数というのは、『 Public 』で宣言した変数のことで、どのモジュールからでも参照できる変数のことです。
今回のゲームでは、現段階で次のような変数を宣言しておきます。

Declare Function GetTickCount Lib "kernel32" () As Long
Declare Sub Sleep Lib "kernel32" (ByVal dwmilliseconds As Long)

Public Problem() As String
Public Problem_Count As Long
Public Problem_Number As Long
Public Problem_Str_Count As Long
Public Game_Flag As Boolean
Public Game_Time As Long

ゲームで使用するAPIの宣言と、グローバルな変数の宣言です。

GetTickCount は時間を計るために使います。
Sleep も時間に関する処理のために宣言しておきます。

Problem() は、問題文を格納するための配列。
Problem_Count は問題の総数。
Problem_Number は、現在何問目かを表す。
Problem_Str_Count は、現在の問題の何文字目かを表す。
Game_Flag は、ゲームを開始しているかどうか。
Game_Time は、ゲーム開始からどれくらい時間が経っているか。

現段階では、グローバルな変数はこれだけあれば十分です。
文字列の照合のところでも書いたように、タイピングゲームで正しくキーが押されているかどうか調べるためには、現在何問目か、そのなかの何文字目なのか、などがわからないと処理できません。それらの処理を実現するために、ここで宣言している変数を使うわけですね。


■初期化する

ゲームでは初期化がとても大事です。

前回のゲームの内容が残ってしまっていたりすると、動作がおかしくなったりすることが往々にしてあるからです。まずは、先ほど宣言したグローバル変数をしっかり初期化する関数を作っておきましょう。

ちなみに、この関数の中で、問題文のソートと、問題文の文字列の取得まで一気に行ってしまうようにしておきます。(問題文のソートに関しては以前の講座を参照⇒Chapter91)

Sub Game_Init()

    Dim L As Long
    
    Problem_Count = 10 '①
    ReDim Problem(1 To Problem_Count) '②
    Problem_Number = 1
    Problem_Str_Count = 1
    Game_Flag = False
    
    Problem_Sort
    
    For L = 1 To Problem_Count
        Problem(L) = Cells(L, 1).Value
    Next

End Sub

さて、現段階では問題数は10個にしていましたね。それを頭に置いて、順番に見ていきましょう。

まず、①の部分で、総問題数を設定しています。今回は10個でしたね。

そして、②の部分で、問題文を格納する配列を ReDim ステートメントを使って再度宣言しています。

先ほどの、グローバル変数の宣言を行っていたコードを思い出してみてください。そこには、こんな一文がありましたね。

Public Problem() As String

これを見て、おや? と思った人はなかなか優秀です。
今まで、何度か配列変数について解説してきましたが、このような配列を使うのは初めてです。変数名に続く括弧のなかに、何も数字が書かれていませんね。このような配列変数のことを、動的配列と言います。

普通、配列変数は、括弧の中に数字を入れて、要素の個数を指定します。

Dim Hairetu(3) As Integer

このようにした場合は、要素の数が4つある配列変数が宣言されますよね。インデックスが 0 、1 、2 、3 の4つですね。
しかし、今回のように、あらかじめ括弧の中になんの数字も指定しない場合には、配列のインデックスが未定のままになります。このような配列は、あとでもう一度要素数を指定して宣言し直す必要があります。

そして、この再度宣言し直すときに使われるのが、『 ReDim ステートメント 』なのです。要素の数が未定のままでは、配列変数を使うことはできません。そこで、ReDim ステートメントを使って要素数を指定し直すわけです。

あらかじめ、要素の数が不確定な場合などは、この動的配列を使うことが多いです。適当に大きな数字を指定して配列を宣言すれば、それだけ無駄が多くなりますし、逆に小さな数字を指定して配列を宣言したのでは、もしかしたら要素数が足りないかもしれません。
要素の数がハッキリした段階で、配列の要素数を指定することができれば、無駄なく、確実に配列変数を宣言できますよね。そんなときに動的配列が活躍するわけです。

今回の場合は、あとから問題を増やす可能性があります。製作する開発者が増やすかもしれませんし、もしかしたら、プレイヤーが自由に問題数を選択できるようにするかもしれませんよね。
そういったことを考慮して、ここでは動的配列を使っています。ゲームがどんどん完成していって、将来的にゲームの品質を向上したい場合には、問題数を選べる機能などを追加すればいいのです。そのときにスムーズに移行できるように、動的配列を使った処理を採用しています。


さて、ちょっと話が逸れました。初期化のコードをもう一度見てみましょう。

Sub Game_Init()

    Dim L As Long
    
    Problem_Count = 10
    ReDim Problem(1 To Problem_Count)
    Problem_Number = 1 '③
    Problem_Str_Count = 1 '④
    Game_Flag = False '⑤
    
    Problem_Sort '⑥
    
    For L = 1 To Problem_Count
        Problem(L) = Cells(L, 1).Value '⑦
    Next

End Sub

③~⑤までは、順次初期化を施しているだけですね。そして、⑥の部分で、以前作成した問題文のソートを行う関数を呼び出しています。
ここで、ワークシート上の問題文がランダムに並び替えされます。

そして最後に⑦の部分で、問題文を配列変数に格納しています。全部で10個ある問題文が、配列変数 Problem の各要素に格納されて、これで初期化が完了します。


■まとめ

さて、初期化についてはおおよそ理解できたでしょうか。
動的配列を採用した汎用的な処理について解説したので、少し難しい内容だったかもしれません。しかし、動的配列は様々な場面で役に立ちます。今はまだ実装していませんが、将来的にプレイヤーが問題数を決めることができるような仕様にするなら、当然動的配列による処理が最も適しています。

今回の初期化処理が終わったあと、実際にゲームの処理がスタートします。次回はいよいよゲームの実体を作成することになります。

初期化は非常に大事ですから、気を抜かずに、しっかりと実装させておくようにしましょう。



■格言

初期化は重要、しっかりと
動的配列は要素数が未確定な配列
動的配列を用いた汎用的な処理を実装する


次回はいよいよゲームの実体となる処理を作ります。








Chapter.93 [ タイピングゲーム8:キーダウンイベント ]

■ユーザーフォームの処理

今回はいよいよタイピングゲームの雛形が完成します。

今まで地道に作成したきた、問題文のソートを行う関数や、初期化の関数を使って、タイピングゲームの全体像をまとめていきます。
今回のタイピングゲームはユーザーフォームを使います。そして、使用するユーザーフォームの基本の部分は以前の講座で作成しましたね。覚えているでしょうか。(画面の設計については以前の講座を参照⇒Chapter90)

ユーザーフォームは、起動してから画面に表示されるまでの間に、Initialize イベントが発生します。ユーザーフォームが起動するときには、メモリ上にはすぐにユーザーフォームのデータが読み込まれるのですが、表示される直前にイベントが発生するのでしたね。

この Initialize イベントで、ユーザーフォームの表示などを初期化します。

Private Sub UserForm_Initialize()
    
    Lab_mondai.Caption = "PRESS ENTER"
    Lab_seikai.Caption = "PRESS ENTER"
    
End Sub

ユーザーフォームには、ラベルがふたつ配置されていました。それが『 Lab_mondai 』と、『 Lab_seikai 』です。
このふたつのラベルは、初期状態では『 Label1 』などの関係ない文字列が Caption プロパティに設定されているはずです。Initialize イベントをうまく利用して、ユーザーフォームが表示される直前に Caption プロパティを変更しておきます。


■タイピングゲームの処理

さて、ユーザーフォームを初期化して正しく表示することができれば、あとはゲームの処理を適切に呼び出すことで、ゲームができるようになります。

今回のタイピングゲームは、キーダウンイベント( KeyDown )を利用して、プレイヤーのキー入力を受け取ります。受け取ったキーの入力が正しいのかどうかを判断して、ユーザーフォーム上にあるラベルの表示を変更していきます。

大まかに、どのような手順でゲームが進むのか、それをまずはハッキリさせておきます。

ユーザーフォームの起動
    ▼
Initialize イベントを使って初期化
    ▼
エンターキーを押してもらう
    ▼
[ READY? ] ⇒ [ GO! ] という順番に文字を表示
    ▼
ゲームがスタート
    ▼
10問の問題をタイプ
    ▼
タイプが終わったら[ Clear ]を表示する
    ▼
少し間をおいて、かかった時間を表示する
    ▼
最初の状態に戻す

なんか、結構大変そうですね。でも、ひとつひとつやっていけば大丈夫。焦らず確実にこなしていきましょう。


ゲームの開始は、エンターキー( Enter )が合図になります。
キーが押される 』ということが合図になりますので、これはキーダウンイベントで検知します。

Private Sub UserForm_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, _
                             ByVal Shift As Integer)
    
    If KeyCode = vbKeyReturn Then
        Lab_seikai.Caption = ""
        Game_Init
        Lab_mondai.Caption = "READY?"
        DoEvents
        Sleep 2000
        Lab_mondai.Caption = "GO!"
        DoEvents
        Sleep 2000
        Game_Flag = True
        Game_Time = GetTickCount
    End If
    
End Sub

ユーザーフォームの KeyDown イベントの処理です。

KeyDown イベントは、ユーザーフォーム上でキーの入力がされた瞬間に発生します。そして、KeyCode に、なんのキーが押されたのかが整数で入っている状態で発生します。この KeyCode の中身を調べれば、なんのキーが押されたのかがわかるのですね。

そして、黄色い文字で表示されている部分が、押されたキーがエンターキーかどうかを判断している部分です。 vbKeyReturn は、VBAにあらかじめ含まれている定数で、エンターキーのキーコードを表しています。実態としては『 13 』という数字と同じ意味があります。ですから、次のように書いても意味としては同じですね。

If KeyCode = 13 Then

ただ、このようにしてしまうと、あとから見たときに意味がわかりにくいですよね。最初のように定数を使って書かれていれば、エンターキーの判定をしているのだな、ということがわかりやすいです。状況にもよりますが、定数を使ったほうが見た目は綺麗に仕上がりますね。


■その他のキー入力に対処する

さて、ここまでは案外簡単なんですが、問題はここからです。

ここの部分は、まずは全体のコードを掲載してしまいます。これを見ながら、実際にどのように動いているのかを解説していきます。結構長いコードですが、びびってはいけません。落ち着いてみていけば大丈夫です。

Private Sub UserForm_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, _
                             ByVal Shift As Integer)

    Dim Clear_Flag As Boolean
    
    Clear_Flag = False
    
    If Not Game_Flag Then
        If KeyCode = vbKeyReturn Then
            Lab_seikai.Caption = ""
            Game_Init
            Lab_mondai.Caption = "READY?"
            DoEvents
            Sleep 2000
            Lab_mondai.Caption = "GO!"
            DoEvents
            Sleep 2000
            Game_Flag = True
            Game_Time = GetTickCount
        End If

    Else
        If Str_Comparison(Problem(Problem_Number), _
                         Problem_Str_Count, _
                         Chr(KeyCode)) Then
            Problem_Str_Count = Problem_Str_Count + 1
            If Len(Problem(Problem_Number)) < Problem_Str_Count Then
                Problem_Number = Problem_Number + 1
                Problem_Str_Count = 1
                If Problem_Count < Problem_Number Then
                    Clear_Flag = True
                End If
            End If
        End If

    End If
    
    If Clear_Flag Then
        Game_Time = (GetTickCount - Game_Time) / 1000
        Lab_mondai.Caption = "!! Clear !!"
        Lab_seikai.Caption = "!! Clear !!"
        DoEvents
        Sleep 2000
        Lab_mondai.Caption = "Time:" & Game_Time & " Second"
        Lab_seikai.Caption = "Time:" & Game_Time & " Second"
        DoEvents
        Sleep 3000
        Lab_mondai.Caption = "PRESS ENTER"
        Lab_seikai.Caption = "PRESS ENTER"
        DoEvents
        Game_Flag = False
    Else
        Lab_mondai.Caption = Problem(Problem_Number)
        Lab_seikai.Caption = Left(Problem(Problem_Number), _
                                  Problem_Str_Count - 1)
    End If

    
    DoEvents
    
End Sub


さて、今回のコードは大分類で3つのフェイズに分かれています。それぞれ色を変えているので、それを参考に見てください。

まず、最初の黄色い文字の部分は、先ほどのエンターキーの判断をしている部分ですね。
ゲームがまだ開始されていないときに、エンターキーが押されていた場合にはここの部分が実行されます。

ここでは、Sleep を上手に使いながら、[ READY? ] ⇒ [ GO! ] という順番に文字を表示しています。それと同時に、ゲームの状態を表す Game_Flag True にして、ゲームの開始時刻を Game_Time に取得しています。
ここで Game_Flag True にしたので、以降は全て緑文字のところに処理が移るようになります。


さて、緑の文字のところはどのように処理されているのでしょうか。
まず、最初に出てくる Str_Comparison ですが、これは以前の講座で作成した、キーの入力が正しくできているのかをチェックする関数です。(文字列判定関数については以前の講座を参照⇒Chapter89)
この関数に、現在の問題文や、現在の文字位置、KeyCode から取得したキーの入力を渡すことで、正しくタイプできているかどうかをチェックできます。この関数が返してくる戻り値が、True なら正しくタイプできていたということであり、逆に False なら、全く違うキーが押されていたことになります。

Str_Comparison True を返してきたときの処理は、ちょっと紛らわしいですが落ちついて考えましょう。手順としては、次のようにしています。

正しくタイプしたので、文字数をカウントする
    ▼
問題文の文字数を超えているか調べる
(一文を全て打ち切ったかどうか調べる)
    ▼
文字数が超えていたら
    ▼
問題をカウントする
    ▼
現在の問題が、総問題数を超えているか調べる
    ▼
問題数が超えていたらゲームクリア

全部の問題をクリアしたら、ゲームのクリアを表す Clear_Flag True にします。こうしておくことで、次のフェイズでの処理が変わります。


さて、最後の水色文字の部分で、ユーザーフォーム上の処理を行っています。
先ほどの緑文字のところで、ゲームがクリアしているかどうかなどを調べましたね。その内容を継承しながら処理します。

ゲームをクリアしていた場合には、クリア処理を行います。クリアしていない場合は、ラベルの表示などを適宜更新しています。

水色の部分が終わったら、最後に DoEvents を呼び出していますね。こうしておくことで、確実にユーザーフォームの表示を更新しています。恐らく、構造上は DoEvents なしでも大丈夫だと思いますが、念には念をいれて、キチンと DoEvents を呼び出しておいたほうがいいでしょう。

これが、キーダウンイベントの全容です。


■まとめ

さて、かなり長い講座になりました。内容もかなり濃かったので、一発で完全に理解するのは難しいと思います。

ポイントとなるのは、ゲームの状況を正しく把握して、適切な処理を行うことです。
現在は、ゲームの開始前なのか、ゲームのプレイ中なのか。
問題は何問目で、何文字目なのか。
キーの入力は正しかったのか、間違っていたのかなど、それぞれに適切な判断が行われるようにうまく構造化しておくことが大事です。

サンプルを別館にアップしておきます。
実際に動作するサンプルを動かしてみましょう。そして、どうしてそのような結果が得られるのか、コードを紐解きながら解析してみましょう。そうやって繰り返し繰り返し分析をすることで、自分自身の実力も比例して上がっていきます。諦めずに根気よく挑戦することが大事です。


サンプルダウンロード ⇒ コチラよりダウンロードできます。(別館)



■格言

Initialize イベントの活用
KeyDown イベントを活用して処理
状況に応じて適切に処理する


次回からは拡張をやっていきます。
基本部分は今回のところで完成したことになりますね。








メールフォーム

影斬に物申すという方はこちら

名前 :
メール:
件名 :
本文 :

可能な限り要望には応えますが、必ず返信や回答ができることを、保障するものではありません。
ご了承ください。

Chapters

コンテンツ一覧


■Chapter 一覧■
    全てのChapterの一覧です。
    直接アクセスしたい方はこちらをご利用下さい。

    Chapter.1 [ 知っておくべき心得 ]
    Chapter.2 [ Excelってなんだろう ]
    Chapter.3 [ Excelの基本画面 ]
    Chapter.4 [ VBAとは? ]
    Chapter.5 [ モジュールについて ]
    Chapter.6 [ 変数 ]
    Chapter.7 [ 変数の型と宣言 ]
    Chapter.8 [ プロシージャとスコープ ]
    Chapter.9 [ ゲームつくる様々な手法 ]
    Chapter.10 [ ユーザーフォーム ]
    Chapter.11 [ プロパティウィンドウ ]
    Chapter.12 [ 乱数 ]
    Chapter.13 [ 条件分岐 ]
    Chapter.14 [ ゲーム画面のデザイン ]
    Chapter.15 [ コード記述の基本作法 ]
    Chapter.16 [ じゃんけんゲーム:1 名前をつける ]
    Chapter.17 [ じゃんけんゲーム:2 フォームの起動 ]
    Chapter.18 [ じゃんけんゲーム:3 乱数の種 ]
    Chapter.19 [ じゃんけんゲーム:4 イベント ]
    Chapter.20 [ じゃんけんゲーム:5 引数 ]
    Chapter.21 [ じゃんけんゲーム:6 役判定 ]
    Chapter.22 [ じゃんけんゲーム:7 予測と制限 ]
    Chapter.23 [ Withステートメント ]
    Chapter.24 [ 画像を表示させる ]
    Chapter.25 [ 画像表示の発展形 ]
    Chapter.26 [ 繰り返し処理 For文 ]
    Chapter.27 [ 繰り返し処理 Do~Loop文 ]
    Chapter.28 [ Exitステートメント ]
    Chapter.29 [ フォーム上の位置情報 ]
    Chapter.30 [ API基礎知識 ]
    Chapter.31 [ API補足知識 ]
    Chapter.32 [ メインループを考える ]
    Chapter.33 [ 同期処理の概念 ]
    Chapter.34 [ 移動処理その1:画面設定と考え方 ]
    Chapter.35 [ 移動処理その2:DoEvents ]
    Chapter.36 [ 移動処理その3:キー入力判定API ]
    Chapter.37 [ 条件分岐のさらなる探求 Select Case ]
    Chapter.38 [ アニメーション ]
    Chapter.39 [ 配列変数 ]
    Chapter.40 [ ゲームの初期化 ]
    Chapter.41 [ シューティングゲーム1:ゲーム設計 ]
    Chapter.42 [ シューティングゲーム2:メインプロセス ]
    Chapter.43 [ シューティングゲーム3:構造体 ]
    Chapter.44 [ シューティングゲーム4:定数 ]
    Chapter.45 [ シューティングゲーム5:プレイヤーキャラクター ]
    Chapter.46 [ シューティングゲーム6:ショットを撃つ① ]
    Chapter.47 [ シューティングゲーム7:ショットを撃つ② ]
    Chapter.48 [ シューティングゲーム8:Mod演算子の活用 ]
    Chapter.49 [ シューティングゲーム9:敵キャラクター登場 ]
    Chapter.50 [ シューティングゲーム10:衝突判定 ]
    Chapter.51 [ シューティングゲーム11:衝突の実体 ]
    Chapter.52 [ シューティングゲーム12:敵の攻撃 ]
    Chapter.53 [ シューティングゲーム13:爆発エフェクト ]
    Chapter.54 [ シューティングゲーム14:残機数表示① ]
    Chapter.55 [ シューティングゲーム15:残機数表示② ]
    Chapter.56 [ シューティングゲーム16:スコアの表示 ]
    Chapter.57 [ シューティングゲーム17:タイトル画面 ]
    Chapter.58 [ シューティングゲーム18:ボスキャラクター ]
    Chapter.59 [ シューティングゲーム19:最後の仕上げへ ]
    Chapter.60 [ シューティングゲーム20:いよいよ完成STG ]
    Chapter.61 [ カードゲームで使えるめくり効果 ]
    Chapter.62 [ ラジアンと角度 ]
    Chapter.63 [ ラジアンの活用:円運動 ]
    Chapter.64 [ ラジアンの活用:任意の角度へ移動する ]
    Chapter.65 [ APIによるサウンド再生:基礎 ]
    Chapter.66 [ APIによるサウンド再生:MIDIと多重再生 ]
    Chapter.67 [ APIによるサウンド再生:MCIコマンドとループ再生 ]
    Chapter.68 [ Function プロシージャ ]
    Chapter.69 [ 値渡しと参照渡し ]
    Chapter.70 [ デバッグ1:イミディエイトウィンドウ ]
    Chapter.71 [ デバッグ2:ローカルウィンドウ ]
    Chapter.72 [ デバッグ3:コード実行の中断 ]
    Chapter.73 [ オブジェクトってなんだ ]
    Chapter.74 [ プロパティ・メソッド・イベント ]
    Chapter.75 [ オブジェクト変数 ]
    Chapter.76 [ オブジェクトとコレクション ]
    Chapter.77 [ 特殊な繰り返し:For Each ]
    Chapter.78 [ エラー処理 ]
    Chapter.79 [ On Error と GoTo文 ]
    Chapter.80 [ Resumeステートメント ]
    Chapter.81 [ バイトとビット ]
    Chapter.82 [ ウィンドウメッセージとイベント ]
    Chapter.83 [ 文字列の基礎 ]
    Chapter.84 [ 文字列操作① ]
    Chapter.85 [ 文字列操作② ]
    Chapter.86 [ タイピングゲーム1:仕様を決める ]
    Chapter.87 [ タイピングゲーム2:キー入力検知 ]
    Chapter.88 [ タイピングゲーム3:文字列照合 ]
    Chapter.89 [ タイピングゲーム4:判定関数 ]
    Chapter.90 [ タイピングゲーム5:ゲーム画面設計 ]
    Chapter.91 [ タイピングゲーム6:問題文のソート ]
    Chapter.92 [ タイピングゲーム7:動的配列 ]
    Chapter.93 [ タイピングゲーム8:キーダウンイベント ]
    Chapter.94 [ タイピングゲーム9:正打数の表示 ]
    Chapter.95 [ タイピングゲーム10:タイムの表示 ]
    Chapter.96 [ クリックゲーム1:イベントの種類 ]
    Chapter.97 [ クリックゲーム2:画面設計 ]
    Chapter.98 [ クリックゲーム3:クリック座標検知 ]
    Chapter.99 [ クリックゲーム4:キャラクター準備 ]
    Chapter.100 [ クリックゲーム5:キャラクターの配置 ]
    Chapter.101 [ クリックゲーム6:キャラクター移動とNot演算子 ]
    Chapter.102 [ クリックゲーム7:クリックのヒット判定 ]
    Chapter.103 [ クリックゲーム8:ヒットマークエフェクト ]
    Chapter.104 [ クリックゲーム9:サウンド処理の実装 ]
    Chapter.105 [ クリックゲーム10:マウスカーソルの変更 ]
    Chapter.106 [ ブロック崩しゲーム1:仕様と概要を決める ]
    Chapter.107 [ ブロック崩しゲーム2:基本概念の確認 ]
    Chapter.108 [ ブロック崩しゲーム3:ベクトルとは ]
    Chapter.109 [ ブロック崩しゲーム4:変数や定数の宣言 ]
    Chapter.110 [ ブロック崩しゲーム5:初期化処理の実装 ]
    Chapter.111 [ ブロック崩しゲーム6:ブロックの配置 ]
    Chapter.112 [ ブロック崩しゲーム7:根幹処理とバーの処理 ]
    Chapter.113 [ ブロック崩しゲーム8:線分と線分の交差を判定 ]
    Chapter.114 [ ブロック崩しゲーム9:線分同士の交点 ]
    Chapter.115 [ ブロック崩しゲーム10:ボールの処理 ]
    Chapter.116 [ ブロック崩しゲーム11:最終調整して完成へ ]
    Chapter.117 [ テキストファイル操作基礎 ]
    Chapter.118 [ テキストファイル操作:読み込み編 ]
    Chapter.119 [ テキストファイル操作:CSV読み込み編 ]
    Chapter.120 [ テキストファイル操作:様々な読込編 ]
    Chapter.121 [ テキストファイル操作:バイナリ編 ]
    Chapter.122 [ テキストファイル操作:暗号化編 ]
    Chapter.123 [ テキストファイル操作:復号化編 ]
    Chapter.124 [ クラスモジュールとは ]
    Chapter.125 [ クラスモジュール:メソッド編 ]
    Chapter.126 [ クラスモジュール:プロパティ編 ]
    Chapter.127 [ クラスモジュール:イベント拡張編 ]
    Chapter.128 [ クラスモジュール:イベント自作編 ]
    Chapter.129 [ APIによる描画処理1:ハンドル ]
    Chapter.130 [ APIによる描画処理2:デバイスコンテキスト ]
    Chapter.131 [ APIによる描画処理3:ペン オブジェクト ]
    Chapter.132 [ APIによる描画処理4:ブラシ オブジェクト ]
    Chapter.133 [ APIによる描画処理5:図形描画準備編 ]
    Chapter.134 [ APIによる描画処理6:図形描画実践編 ]
    Chapter.135 [ APIによる描画処理7:画像描画の仕組み編 ]
    Chapter.136 [ APIによる描画処理8:ビットブロック転送編 ]
    Chapter.137 [ APIによる描画処理9:ラスタオペレーション ]
    Chapter.138 [ APIによる描画処理10:マスク描画 概念編 ]
    Chapter.139 [ APIによる描画処理11:マスク描画 実践編 ]


    コードやVBAに関する質問などはサポート掲示板(別館)までお気軽にどうぞ。




fc2 seotool Excel VBA ゲーム プログラミング 講座

Counter

twitter


Shadow BBS - 影掲示板

VBA 関連書籍



上記広告は1ヶ月以上更新のないブログに表示されています。新しい記事を書くことで広告を消せます。